[Sreaper]

Would someone kindly edit that plugin to be sm_alpha_wep <target> <amount>? And remove the convar.

[ddhoward]

When posting error messages, please post the ENTIRE message. The line # is especially important.

I had a friend compile this for me, as I cannot do so at my current location.

The first issue is on line 12. The version string needs to be enclosed in quotation marks. That one was my fault.

The second issue is on line 18, or rather, the command it links to.

public Action:Command_SetWepAlpha(client)

needs to be

public Action:Command_SetWepAlpha(client, args)

The final issue is on line 45. Someone put a return in SetWeaponInvis for no apparent reason, when it should have gone in Command_SetWepAlpha.

PHP Code:

#include <sourcemod>
#include <tf2_stocks> 

new Handle:hcvar_alpha_wep = INVALID_HANDLE;
new _:cvar_alpha_wep;
 
public Plugin:myinfo =
{
    name = "WepAlphanator",
    author = "Assyrian/Nergal",
    description = "makes weapons transparent",
    version = "1.0.0.2",
    url = "http://www.sourcemod.net/"
} 
 
public OnPluginStart()   
{
    RegAdminCmd("sm_alphawep", Command_SetWepAlpha, ADMFLAG_GENERIC);
    hcvar_alpha_wep = CreateConVar("sm_alphawep", "128", "Default alpha");
    HookConVarChange(hcvar_alpha_wep, cvarChange);
}

public OnConfigsExecuted()
{
    cvarChange(INVALID_HANDLE, "0", "0");
}

public Action:Command_SetWepAlpha(client, args)
{
    SetWeaponInvis(client);
    return Plugin_Continue;
}

stock SetWeaponInvis(client, bool:set = true)
{ 
    for (new i = 0; i < 5; i++)
    { 
        new entity = GetPlayerWeaponSlot(client, i); 
        if (entity != -1)
        { 
            SetEntityRenderMode(entity, RENDER_TRANSCOLOR); 
            SetEntityRenderColor(entity, _, _, _, set ? cvar_alpha_wep : 255); 
        } 
    }
    
}

public cvarChange(Handle:hHandle, const String:strOldValue[], const String:strNewValue[])
{
    if (hHandle == hcvar_alpha_wep || hHandle == INVALID_HANDLE)
    {
        cvar_alpha_wep = GetConVarInt(hcvar_alpha_wep);
        if (cvar_alpha_wep > 255 || cvar_alpha_wep < 0)
        {
            cvar_alpha_wep = 128;
            LogError("Value of sm_alphawep is invalid. Plugin will behave as if value was 128.");
        }
    }
} 


[ddhoward]

Originally Posted by Sreaper Would someone kindly edit that plugin to be sm_alpha_wep <target> <amount>? And remove the convar.

This should work (untested):

Spoiler

PHP Code:

#include <sourcemod>
#include <tf2_stocks> 

public Plugin:myinfo = {
    name = "WepAlphanator",
    author = "Assyrian/Nergal & Derek Howard",
    description = "makes weapons transparent",
    version = "1.0.0.3",
    url = "http://www.sourcemod.net/"
} 
 
public OnPluginStart() {
    RegAdminCmd("sm_alpha_wep", Command_SetWepAlpha, ADMFLAG_GENERIC);
}

public Action:Command_SetWepAlpha(client, args) {
    new numargs = GetCmdArgs();
    if (numargs != 2) {
        ReplyToCommand(client, "Usage: \"sm_alpha_wep [target] [value]\"");
        return Plugin_Handled;
    }
    new target[MAXPLAYERS];
    decl String:target_name[MAX_TARGET_LENGTH]; target_name[0] = '\0';
    new numtargets;
    decl String:arg1[64]; arg1[0] = '\0';
    new bool:tn_is_ml;
    GetCmdArg(1, arg1, sizeof(arg1));
    if ((numtargets = ProcessTargetString(arg1, client, target, sizeof(target), 0, target_name, sizeof(target_name), tn_is_ml)) <= 0) {
        ReplyToTargetError(client, numtargets);
        return Plugin_Handled;
    }
    decl String:arg2[4]; arg2[0] = '\0';
    GetCmdArg(2, arg2, sizeof(arg2));
    new alpha = StringToInt(arg2);
    if (alpha > 255 || alpha < 0) {
        ReplyToCommand(client, "[SM] Second argument must be between 0 and 255.");
        return Plugin_Handled;
    }
    for (new currenttarget = 0; currenttarget < numtargets; currenttarget++) {
        for (new wep = 0; wep < 5; wep++) { 
            new entity = GetPlayerWeaponSlot(target[currenttarget], wep); 
            if (entity != -1) { 
                SetEntityRenderMode(entity, RENDER_TRANSCOLOR); 
                SetEntityRenderColor(entity, _, _, _, alpha); 
            }
        }
    }
    LogAction(client, -1, "\"%L\" set weapon transparency to %i on %s.", client, alpha, target_name);
    ShowActivity2(client, "[SM] ", "Set weapon transparency to %i on %s.", alpha, target_name);
    return Plugin_Handled;
} 


[Sreaper]

Thank you all for your help. :)

[Arkarr]

Like someone said before, it doesn't work for stock weapons in slot 0 (primary) .

[nergal]

Originally Posted by Arkarr Like someone said before, it doesn't work for stock weapons in slot 0 (primary) .

yea, why is that? on every other weapon it's invis, but with the sm_alpha from funcommandsx, it turns the stock weapons transparent.

[friagram]

Set the render color to like 120 120 120 255. This will mmic 120 alpha, yu proportion the values. Just setting alha wont work. Messing with rendermode isnt what you want to do here. Note that setting the color and transparency on these weapons will also alter the viewmodel.

[ddhoward]

The method I posted works fine, at least in my Friendly Mode plugin. No one has complained about it not affecting stock primaries. It is functioning fine how it is, and unless I can duplicate the error, I cannot fix it.

[nergal]

Originally Posted by ddhoward The method I posted works fine, at least in my Friendly Mode plugin. No one has complained about it not affecting stock primaries. It is functioning fine how it is, and unless I can duplicate the error, I cannot fix it.

eh it's not a big deal

[friagram]

Dunno, been using this for some 2+ years, works on clients as well.
Is also good to note that some rendermodes/colors will have to be reset at later times (clients?) though weapons and hats will probably get refredhed kn cabinet touch/respawn.