[Sharing memory 4 fun]

Mathias. · **Author**

core.sp

Spoiler

PHP Code:


			
#include <sourcemod>
#include <mycore>

new Handle:array_Data;


public APLRes:AskPluginLoad2(Handle:myself, bool:late, String:error[], err_max)
{
    array_Data = CreateArray(struct_data);

    CreateNative("AddDataStruct", Native_AddDataStruct);
    CreateNative("GetDataStructByName", Native_GetDataStructByName);
    CreateNative("GetRawDataStructByName", Native_GetRawDataStructByName);
}

public Native_AddDataStruct(Handle:plugin, numParams)
{
    new data[struct_data];
    GetNativeArray(1, data, struct_data);
    data[m_plugin] = plugin;
    
    PushArrayArray(array_Data, data);
    PrintToServer("[DEBUG] core: key '%s' by plugin ID '%d'", data[m_key], plugin);
}

public Native_GetDataStructByName(Handle:plugin, numParams)
{
    new String:key[32];
    GetNativeString(1, key, 32);
    PrintToServer("[DEBUG] core: Looking for a data from '%s'...", key);
    
    new data[struct_data];

    for (new i; i < GetArraySize(array_Data); i++)
    {
        GetArrayArray(array_Data, i, data);
        
        PrintToServer("[DEBUG] core: is key '%s' equal to '%s' and plugin ID %d equal to  '%d'?", data[m_key], key, plugin, data[m_plugin]);
        
        if (data[m_plugin] == plugin && StrEqual(data[m_key], key, true))
        {
            PrintToServer("[DEBUG] core: key '%s' was found!", key);
            SetNativeArray(2, data, struct_data);
            return true;
        }
        continue;
    }
    PrintToServer("[DEBUG] core: raw data was not found!");
    return false;
}

public Native_GetRawDataStructByName(Handle:plugin, numParams)
{
    new String:key[32];
    GetNativeString(1, key, 32);
    
    PrintToServer("[DEBUG] core: Looking for a raw data from '%s'...", key);
    
    new data[struct_data];

    for (new i; i < GetArraySize(array_Data); i++)
    {
        GetArrayArray(array_Data, i, data);
        
        PrintToServer("[DEBUG] core: is key '%s' equal to '%s'?", data[m_key], key);
        
        if (StrEqual(data[m_key], key, true))
        {
            PrintToServer("[DEBUG] core: key '%s' was found from plugin ID '%d'!", key, data[m_plugin]);
            SetNativeArray(2, data, struct_data);
            return true;
        }
    }
    PrintToServer("[DEBUG] core: raw data was not found!");
    return false;
}

mycore.inc

Spoiler

plugin1.sp

Spoiler

PHP Code:


			
#include <sourcemod>
#include <mycore>

public OnPluginStart()
{
    new data[struct_data];
    
    Format(data[m_key], 32, "first");
    data[m_value] = 1;
    AddDataStruct(data);
    
    Format(data[m_key], 32, "second");
    data[m_value] = 2;
    AddDataStruct(data);
    
    Format(data[m_key], 32, "third");
    data[m_value] = 3;
    AddDataStruct(data);
    
    Format(data[m_key], 32, "plugin1");
    data[m_value] = 1337;
    AddDataStruct(data);
    
    RegConsoleCmd("plugin1", mycallback);
    RegConsoleCmd("plugin1_raw", mycallback2);
}

public Action:mycallback(client, argc)
{
    if (argc != 1)
    {
        PrintToServer("wrong arguments for 'plugin1'!");
        return Plugin_Handled;
    }
    
    new String:buffer[32];
    GetCmdArg(1, buffer, 32);
    
    new data[struct_data];
    if (GetDataStructByName(buffer, data))
    {
        PrintToServer("[DEBUG] plugin1: key '%s' value '%d'.", data[m_key], data[m_value]);
    }
    else
    {
        PrintToServer("[DEBUG] plugin1: key '%s' do not exist from plugin ID '%d'", buffer, GetMyHandle());
    }
    
    return Plugin_Handled;
}

public Action:mycallback2(client, argc)
{
    if (argc != 1)
    {
        PrintToServer("wrong arguments for 'plugin1_raw'!");
        return Plugin_Handled;
    }
    
    new String:buffer[32];
    GetCmdArg(1, buffer, 32);

    new data[struct_data];
    if (GetRawDataStructByName(buffer, data))
    {
        PrintToServer("[DEBUG] plugin1: key '%s' value %d from plugin ID '%d'.", data[m_key], data[m_value], data[m_plugin]);
    }
    else
    {
        PrintToServer("[DEBUG] plugin1: key '%s' do not exist at all!", buffer);
    }
    
    return Plugin_Handled;
}

plugin2.sp

Spoiler

PHP Code:


			
#include <sourcemod>
#include <mycore>

public OnPluginStart()
{
    new data[struct_data];
    
    Format(data[m_key], 32, "first");
    data[m_value] = 3;
    AddDataStruct(data);
    
    Format(data[m_key], 32, "second");
    data[m_value] = 2;
    AddDataStruct(data);
    
    Format(data[m_key], 32, "third");
    data[m_value] = 1;
    AddDataStruct(data);
    
    Format(data[m_key], 32, "plugin2");
    data[m_value] = 7331;
    AddDataStruct(data);
    
    RegConsoleCmd("plugin2", mycallback);
    RegConsoleCmd("plugin2_raw", mycallback2);
}

public Action:mycallback(client, argc)
{
    if (argc != 1)
    {
        PrintToServer("wrong arguments for 'plugin2'!");
        return Plugin_Handled;
    }
    
    new String:buffer[32];
    GetCmdArg(1, buffer, 32);

    new data[struct_data];
    if (GetDataStructByName(buffer, data))
    {
        PrintToServer("[DEBUG] plugin2: key '%s' value '%d'.", data[m_key], data[m_value]);
    }
    else
    {
        PrintToServer("[DEBUG] plugin2: key '%s' do not exist from plugin ID '%d'", buffer, GetMyHandle());
    }
    
    return Plugin_Handled;
}

public Action:mycallback2(client, argc)
{
    if (argc != 1)
    {
        PrintToServer("wrong arguments for 'plugin2_raw'!");
        return Plugin_Handled;
    }
    
    new String:buffer[32];
    GetCmdArg(1, buffer, 32);

    new data[struct_data];
    if (GetRawDataStructByName(buffer, data))
    {
        PrintToServer("[DEBUG] plugin2: key '%s' value '%d' from plugin ID '%d'.", data[m_key], data[m_value], data[m_plugin]);
    }
    else
    {
        PrintToServer("[DEBUG] plugin2: key '%s' do not exist at all!", buffer);
    }
    
    return Plugin_Handled;
}

I did not put all the checks and memory cleanup when one of the plugin unload but I will do it later and also GetRawDataStructByName only return the first one found. I will edit it later.

striker07 · 01-21-2014 , 18:39 Re: [Sharing memory 4 fun]

Thanks

Mitchell · 01-21-2014 , 18:59 Re: [Sharing memory 4 fun]

Very cool. Seems like an easy alternative that making a bunch of natives.

Mathias. · 01-21-2014 , 19:02 Re: [Sharing memory 4 fun]

It can be useful if you want to create run time libraries for plugins. (in sourcepawn)

nergal · 01-03-2015 , 11:03 Re: [Sharing memory 4 fun]

I have no fucking idea what this does but I converted it to the new syntax for no reason lol.

I prob converted it wrong but here it is

PHP Code:


			
#include <sourcemod>
#include <mycore>

ArrayList array_Data = null;

public APLRes AskPluginLoad2(Handle myself, bool late, char[] error, int err_max)
{
    array_Data = new ArrayList(struct_data);
    CreateNative("AddDataStruct", Native_AddDataStruct);
    CreateNative("GetDataStructByName", Native_GetDataStructByName);
    CreateNative("GetRawDataStructByName", Native_GetRawDataStructByName);
}

public int Native_AddDataStruct(Handle plugin, int numParams)
{
    int data[struct_data];
    GetNativeArray(1, data, struct_data);
    data[m_plugin] = plugin;

    array_Data.PushArray(data); //PushArrayArray(array_Data, data);
    PrintToServer("[DEBUG] core: key '%s' by plugin ID '%d'", data[m_key], plugin);
}

public int Native_GetDataStructByName(Handle plugin, int numParams)
{
    char key[32];
    GetNativeString(1, key, 32);
    PrintToServer("[DEBUG] core: Looking for a data from '%s'...", key);

    int data[struct_data];

    for (int i; i < array_Data.Length; i++) //GetArraySize(array_Data); i++)
    {
        array_Data.GetArray(i, data); //GetArrayArray(array_Data, i, data);

        PrintToServer("[DEBUG] core: is key '%s' equal to '%s' and plugin ID %d equal to  '%d'?", data[m_key], key, plugin, data[m_plugin]);

        if (data[m_plugin] == plugin && StrEqual(data[m_key], key, true))
        {
            PrintToServer("[DEBUG] core: key '%s' was found!", key);
            SetNativeArray(2, data, struct_data);
            return view_as<int>(true);
        }
        continue;
    }
    PrintToServer("[DEBUG] core: raw data was not found!");
    return view_as<int>(false);
}

public int Native_GetRawDataStructByName(Handle plugin, int numParams)
{
    char key[32];
    GetNativeString(1, key, 32);

    PrintToServer("[DEBUG] core: Looking for a raw data from '%s'...", key);

    int data[struct_data];

    for (int i; i < array_Data.Length; i++) //(new i; i < GetArraySize(array_Data); i++)
    {
        array_Data.GetArray(i, data); //GetArrayArray(array_Data, i, data);
        PrintToServer("[DEBUG] core: is key '%s' equal to '%s'?", data[m_key], key);

        if (StrEqual(data[m_key], key, true))
        {
            PrintToServer("[DEBUG] core: key '%s' was found from plugin ID '%d'!", key, data[m_plugin]);
            SetNativeArray(2, data, struct_data);
            return view_as<int>(true);
        }
    }
    PrintToServer("[DEBUG] core: raw data was not found!");
    return view_as<int>(false);
}







#if defined _mycore_included
 #endinput
#endif
#define _mycore_included

// ignore m_plugin this is used by core

enum struct_data
{
    Handle m_plugin,
    char m_key[32],
    int m_value
};

// Add structure
native void AddDataStruct(int data[struct_data]);

// Find structure declared only by my plugin
native bool GetDataStructByName(const char key[32], int data[struct_data]);

// Find any structures by any plugin
native bool GetRawDataStructByName(const char key[32], int data[struct_data]);

__int128 · 01-05-2015 , 15:41 Re: [Sharing memory 4 fun]

does it even compile? I though we could not use the new declaration type into enums