[Michael Shoe Maker]

Hello, just a little problem i have. I need to strip a large amount of players and using

PHP Code:

ServerCommand("sm_disarm %s", sBuffer) 


would just spam the chat and I don't have the source for the command.

I cant figure out how to do it, any pointers?

[KissLick]

smlib

EDIT: Or search - IT COST ME LIKE 30sec TO GOOGLE THAT...

[Farbror Godis]

Something like this:

PHP Code:

#include <sdkhooks>
#include <sdktools>

...

int weapon;
for(int i = 0; i < 4; i++) {
    if((weapon = GetPlayerWeaponSlot(client, i)) != -1) {
        SDKHook_DropWeapon(client, weapon, NULL_VECTOR, NULL_VECTOR);
        AcceptEntityInput(weapon, "Kill");
    }
} 


You will have to adjust how many slots to iterate over depending on what game it is.

[Dkmuniz]

PHP Code:

stock StripAllWeapons(client)
{
    new iEnt;
    for (new i = 0; i <= 4; i++)
    {
        while ((iEnt = GetPlayerWeaponSlot(client, i)) != -1)
        {
            RemovePlayerItem(client, iEnt);
            AcceptEntityInput(iEnt, "Kill");
        }
    }
} 


[Bacardi]

if game is csgo, avoid using removeplayeritem function, this have halt server on round end.
@Farbor example much better

[shanapu]

Originally Posted by Bacardi if game is csgo, avoid using removeplayeritem function, this have halt server on round end. @Farbor example much better

thanks, good to know

[SM9]

For a safer method similar to Farbor Godi's example, use the following:

PHP Code:

#include <csgoitems> 


- Added CSGOItems_RemoveAllWeapons This function will safely remove all the weapons a client has got equipped, with an option to skip a certain slot. Example 1, Remove all clients weapons. CSGOItems_RemoveAllWeapons(iClient); Example 2, Remove all clients weapons but leave the knife slot. CSGOItems_RemoveAllWeapons(iClient, CS_SLOT_KNIFE); Return: Number of weapons sucessfully removed from client.

This method is crash free and will also make sure that no errors occur if you are trying to strip a weapon that does not belong to the player.

Download CSGO Items here

[Bacardi]

...well depends, do people need more extensions just simply for strip weapon ?

Spoiler

counter strike

PHP Code:

#include <cstrike>
#include <sdktools>

public OnPluginStart()
{
    RegConsoleCmd("sm_test", test);
}

public Action test(int client, int args)
{
    int array_size = GetEntPropArraySize(client, Prop_Send, "m_hMyWeapons");
    int entity;

    for(new i = 0; i < array_size; i++)
    {
        entity = GetEntPropEnt(client, Prop_Send, "m_hMyWeapons", i);

        if(entity != -1 && GetEntSendPropOffs(entity, "m_bStartedArming") == -1)
        {
            CS_DropWeapon(client, entity, false, true);
            AcceptEntityInput(entity, "Kill");
        }
    }
    return Plugin_Handled;
} 


[Farbror Godis]

If the game is TF2, there's TF2_RemoveAllWeapons, so there's no need to write your own function in that case.

[SM9]

Updated my example, And I have implemented your looping method Bacardi, very nice!