[TzK]

Hello!
I have set zp_delay 10 and mp_freezetime 9, so all players start to run about 1sec before infection. But how to make that the first zombie have freezetime not 9, but for example 14sec. So players have a little bit handicap to run away? Like it is in CSO zombie escape mod. When there is freezetime for zombie, nobody can hurt him.

[aLy_zm]

mp_freezetime 0

[TzK]

And? Zombie won`t be freezed.. I need that zombie is freezed and humans can run a little bit away from him.

[gogicaa]

Which version of ZP are you running ?

[TzK]

zp 5.0.8

[gogicaa]

Soo you want that 1st zombie is frozen for few seconds ?

[TzK]

Yes, for about 5 sec.

[H.RED.ZONE]

Try.

Spoiler

PHP Code:

#include < amxmodx >
#include < fun >
#include < fakemeta >
#include < hamsandwich >

#include < zp50_core >
#include < zp50_grenade_frost >
#include < zp50_colorchat >

#define _PLUGIN "[ZP50] Addon: Escape Servers"
#define _VERSION "1.0"
#define _AUTHOR "H.RED.ZONE"

// Bits.
#define flag_get(%1,%2)            ( %1 & (1 << (%2 & 31)))
#define flag_get_boolean(%1,%2)    (flag_get(%1,%2) ? true : false)
#define flag_set(%1,%2)            ( %1 |= (1 << (%2 & 31)))
#define flag_unset(%1,%2)          ( %1 &= ~(1 << (%2 & 31)))

// Bit.
new _bitPlayerBlocked

// Cvars.
new _pCvarTimeFrozen

// Call When Map Loads.
public plugin_init( ) {
    
    // Register Plugin.
    register_plugin( _PLUGIN, _VERSION, _AUTHOR)    
    
    // Register Ham.
    RegisterHam( Ham_Weapon_PrimaryAttack, "weapon_knife", "FW__KnifeAttack" )
    
    // Register Cvar.
    _pCvarTimeFrozen = register_cvar( "zp_escape_freeze", "5.0" )
}

// Call When Player is Infected.
public zp_fw_core_infect( id, attacker ) {
    
    // If User is First Zombie.
    if( zp_core_is_first_zombie(id) ) {
        
        // Print Message.
        zp_colored_print(id, "You are frozen.")
        
        // Mark Him As Blocked.
        flag_set( _bitPlayerBlocked, id )
        
        // Set User Frozen.
        zp_grenade_frost_set( id, true )
        
        // Set User God Mode.
        set_user_godmode( id, true )
        
        // Set task.
        set_task( get_pcvar_float(_pCvarTimeFrozen), "RemoveFreeze", id )
    }
}

// Are Task.
public RemoveFreeze( id ) {
    
    // Remove Frost.
    zp_grenade_frost_set( id, false )
    
    // Print Message.
    zp_colored_print(id, "Infect humans now.")
    
    // Clear Player As Blocked.
    flag_unset( _bitPlayerBlocked, id )
    
    // Remove God Mode.
    set_user_godmode( id, false )
}

// For Blocking Attack.
public FW__KnifeAttack( Ent ) {
    
    // Get Owner.
    new id = pev( Ent, pev_owner )
    
    // Return So he Can't Attack.
    if( flag_get(_bitPlayerBlocked, id) )
        return HAM_SUPERCEDE
    
    // Ham Ignored.
    return HAM_IGNORED
}

// If Client Disconnects.
public client_disconnect( id ) {
    
    // UnMark Him.
    flag_unset( _bitPlayerBlocked, id )
} 


[gogicaa]

You can just freeze him through zp frostnades natives.

[TzK]

Thanks, works great, but has little bug. It don`t work on first round and it work only for 3 seconds, not that, how much i set the cvar. I think he get the cvar from frostgrenade plugin.
So, i set the cvar 5.0 seconds. But player is unfreezed after 3 seconds and if somebody throw a frostnade to zombie when thoose 5.0 seconds are, then frostnade don`t froze player.