[Ludak]

Hello everyone.
Is it possible to disable spectating for certain players?
For example, I want for VIP's to have an ability that they can not be spectated by other players without admin kick flag.
Can it be done with solid black ScreenFade?
Thank you.

[E1_531G]

Yes, you can try to hook SpecHealth2 message (to get target id) and set permanent black ScreenFade until next round or spawn event begins.

[Relaxing]

Originally Posted by E1_531G Yes, you can try to hook SpecHealth2 message (to get target id) and set permanent black ScreenFade until next round or spawn event begins.

This makes no sense.
All players will disconnect from your server.
Message for OP: Please don't overkill VIP features. Noone would sit watching a black screen for 3 minutes, over and over. Close this thread, barely trashing. Don't suggest bad ideas either examples/solutions.

[Bugsy]

You don't need to set to a black screen, just set to another player who is not a VIP. If only VIP's are playing, then set to black screen, or something.

[Ludak]

Originally Posted by Relaxing This makes no sense. All players will disconnect from your server. Message for OP: Please don't overkill VIP features. Noone would sit watching a black screen for 3 minutes, over and over. Close this thread, barely trashing. Don't suggest bad ideas either examples/solutions.

I have a custom game mode where VIP needs to be protected, and no one should leak the information about his position.

Originally Posted by Bugsy You don't need to set to a black screen, just set to another player who is not a VIP. If only VIP's are playing, then set to black screen, or something.

I do not know how to do it, I have searched but failed to found the answer.
Can you give me the code?
Thank you

[OciXCrom]

Not sure if it will work, but try using set_pev(id, pev_iuser2, target_id). It makes sense do to this because pev_iuser2 holds the id of the spectated player, but I'm not sure if modifying it will actually change anything.

[Bugsy]

Players with ADMIN_KICK can spectate all.
Players without ADMIN_KICK cannot spectate players with ADMIN_KICK.

May want to add a HUD or something explaining why they are getting a black screen if no spectate-able players are available.

Hardly tested.

PHP Code:


#include <amxmodx>
#include <engine>
#include <fakemeta>

new const Version[] = "0.1";

const No_Spectate_Flag = ADMIN_KICK;
const Float:fRefreshInterval = 0.15;

new g_MsgFade;

public plugin_init() 
{
    register_plugin( "No Spec Player" , Version , "bugsy" );
    
    new iEntity = create_entity( "info_target" );
    entity_set_string( iEntity , EV_SZ_classname , "SpecEntity" );
    register_think( "SpecEntity" , "SpecThink" );
    entity_set_float( iEntity , EV_FL_nextthink , get_gametime() + fRefreshInterval );
    
    g_MsgFade = get_user_msgid( "ScreenFade" ); 
}

public SpecThink( iEntity )
{
    new iPlayers[ 32 ] , iNum , iPlayer , iSpectating;
    new iCanBeSpectated[ 32 ] , iCanBeSpectatedCount;
    new iNoSpectate , szName[ 32 ];
    
    //Get alive players who can and cannot be spectated.
    get_players( iPlayers , iNum , "a" );
    
    if ( iNum )
    {
        for ( new i = 0 ; i < iNum ; i++ )
        {
            iPlayer = iPlayers[ i ];
            
            if ( get_user_flags( iPlayer ) & No_Spectate_Flag )
            {
                iNoSpectate |= ( 1 << iPlayer );
            }
            else
            {
                iCanBeSpectated[ iCanBeSpectatedCount++ ] = iPlayer;
            }
        }    
    }
    
    //Cycle through all spectating players. Check who they are spectating and if the spectated has the no-spectate flag
    //set spectated to a player who does not have the no-spectate flag.
    
    get_players( iPlayers , iNum , "bch" );
    
    if ( iNum )
    {
        for ( new i = 0 ; i < iNum ; i++ )
        {
            iPlayer = iPlayers[ i ];
            
            iSpectating = pev( iPlayer , pev_iuser2 );
    
            //Spectating player does not have flag and player being spectated does.
            if ( !( get_user_flags( iPlayer ) & No_Spectate_Flag ) && ( iNoSpectate & ( 1 << iSpectating ) ) )
            {
                if ( iCanBeSpectatedCount )
                {    
                    get_user_name( iSpectating , szName , charsmax( szName ) );
                    client_print( iPlayer , print_chat , "* %s cannot be spectated!" , szName );
                    
                    set_pev( iPlayer , pev_iuser2 , iCanBeSpectated[ random( iCanBeSpectatedCount ) ] );
                }
                else
                {
                    BlackScreen( iPlayer );
                }
            }
        }
    }
    
    entity_set_float( iEntity , EV_FL_nextthink , get_gametime() + fRefreshInterval );
}

BlackScreen( id ) 
{ 
    message_begin( MSG_ONE , g_MsgFade , {0,0,0} , id ); 
    write_short( 4096 ); 
    write_short( 4096 ); 
    write_short( 4096 ); 
    write_byte( 0 ); 
    write_byte( 0 ); 
    write_byte( 0 ); 
    write_byte( 255 ); 
    message_end(); 
} 


[fvRate]

This will do the job :

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <fakemeta>

#pragma semicolon         1

#define ADMIN_ACCES     ADMIN_KICK
#define ADMIN_VIP       ADMIN_LEVEL_H
#define FFADE_STAYOUT   0x0004

new msg_ScreenFade;

public plugin_init( ) 
{
    register_plugin
    ( 
        .plugin_name    = "Plugin",
        .version         = "1.0",
        .author         = "fvRate"
    );
    
    register_event( "SpecHealth2", "event_Spec", "bd" );
    
    msg_ScreenFade = get_user_msgid( "ScreenFade" );
}

public event_Spec( index )
{   
    new specIndex = read_data(2);
    
    if( specIndex == index && !( get_user_flags( specIndex ) & ADMIN_VIP ) )
        return;
    
    ( get_user_flags( specIndex ) & ADMIN_ACCES  ) ?
        set_Fade( index, false  ) : 
        set_Fade( index, true ) ;
}

stock set_Fade( index, bool:fadeState )
{
    message_begin( MSG_ONE_UNRELIABLE, msg_ScreenFade, _, index );
    {
        write_short( 0 );
        write_short( 0 );
        write_short( fadeState ? FFADE_STAYOUT : ~FFADE_STAYOUT );
        write_byte( 0 );
        write_byte( 0 );
        write_byte( 0 );
        write_byte( 255 );
    }
    message_end( );
}

[Bugsy]

So you set to black if the player doesn't have the admin flag ? And I dont think your code does what he wants.

and this ?

PHP Code:

    ( get_user_flags( specIndex ) & ADMIN_ACCES ) ?
        set_Fade( index, true  ) : 
        set_Fade( index, false ) ; 


Why?? lol

[fvRate]

I've tested the code and it worked.

I need to reset the fade to normal by reversing the bit set at the first place.

I'm not giving him a good solution, I'm just following his idea.

"So you set to black if the player doesn't have the admin flag ?" what's wrong with that?