[Bchewy]

Hi all. I am looking for the plugins with the following requirements/specifications to be developed privately. Please contact me on AM forums with a private message.. or add me on steam here (otherwise.. reply to this thread and i'll add you instead.)

More details on the plugin will be revealed if you decide to work on it.
Payment will be followed up upon completion of a working plugin (Paypal payment)

1. Plugin that hooks my store plugin, and gives credits on round-end
2. Plugin to exchange money to store credits
3. Simple and usable commander plugin selection etc (Zombie escape).

Thank you.

[Franc1sco]

Originally Posted by Bchewy Simple and usable commander plugin selection etc (Zombie escape).

https://forums.alliedmods.net/showthread.php?p=2368827

Probably someday I will finish it, but nobody seems to care currently.

[Bchewy]

Originally Posted by Franc1sco https://forums.alliedmods.net/showthread.php?p=2368827 Probably someday I will finish it, but nobody seems to care currently.

Great alternative. I am still looking for developers for the 2,3 and an extra plugin
https://pastebin.com/bxV64Vts

[shanapu]

Originally Posted by Bchewy Great alternative. I am still looking for developers for the 2,3 and an extra plugin https://pastebin.com/bxV64Vts

not tested. but should work.

PHP Code:

// Includes
#include <sourcemod>
#include <sdktools>
#include <sdkhooks>
#include <cstrike>
#include <mystocks>

// Compiler Options
#pragma semicolon 1
#pragma newdecls required

// Console Variables
ConVar gc_bPlugin;
ConVar gc_fMultiply;
ConVar gc_iTeam;


public Plugin myinfo =
{
    name = "KnifeDMG",
    author = "shanapu",
    description = "Multiply knife dmg for a team",
    version = "1.0",
    url = "https://github.com/shanapu"
};

// Start
public void OnPluginStart()
{
    // AutoExecConfig
    gc_bPlugin = CreateConVar("sm_knifedmg", "1", "0 - disabled, 1 - enable knife damage plugin", _, true, 0.0, true, 1.0);
    gc_fMultiply = CreateConVar("sm_knifedmg_multi", "2", "Knife damage multiplyer", _, true, 0.1);
    gc_iTeam = CreateConVar("sm_knifedmg_team", "1", "Which team should get the extra dmg? 1 - CT only / 2- T only / 3 - both", _, true, 1.0, true, 3.0);
    
    AutoExecConfig(true, "KnifeDMG");
}

/******************************************************************************
                   EVENTS
******************************************************************************/


public Action OnTakedamage(int victim, int &attacker, int &inflictor, float &damage, int &damagetype, int &weapon, float damageForce[3], float damagePosition[3], int damagecustom)
{
    if (!gc_bPlugin.BoolValue)
        return Plugin_Continue;

    if (!IsValidClient(victim, true, false) || attacker == victim || !IsValidClient(attacker, true, false)) 
        return Plugin_Continue;

    char sWeapon[32];
    if (IsValidEntity(weapon)) GetEntityClassname(weapon, sWeapon, sizeof(sWeapon));

    if ((GetClientTeam(attacker) == CS_TEAM_CT && gc_iTeam.IntValue == 1) || (GetClientTeam(attacker) == CS_TEAM_T && gc_iTeam.IntValue == 2) || gc_iTeam.IntValue == 3)
    {
        if ((StrEqual(sWeapon, "weapon_knife", false)))
        {
            damage = damage*gc_fMultiply.FloatValue;
            return Plugin_Changed;
        }
    }

    return Plugin_Continue;
}

/******************************************************************************
                   FORWARDS LISTEN
******************************************************************************/

public void OnClientPutInServer(int client)
{
    SDKHook(client, SDKHook_OnTakeDamage, OnTakedamage);
} 


[Bchewy]

Originally Posted by shanapu not tested. but should work. PHP Code: // Includes #include <sourcemod> #include <sdktools> #include <sdkhooks> #include <cstrike> #include <mystocks> // Compiler Options #pragma semicolon 1 #pragma newdecls required // Console Variables ConVar gc_bPlugin; ConVar gc_fMultiply; ConVar gc_iTeam; public Plugin myinfo = {     name = "KnifeDMG",     author = "shanapu",     description = "Multiply knife dmg for a team",     version = "1.0",     url = "https://github.com/shanapu" }; // Start public void OnPluginStart() {     // AutoExecConfig     gc_bPlugin = CreateConVar("sm_knifedmg", "1", "0 - disabled, 1 - enable knife damage plugin", _, true, 0.0, true, 1.0);     gc_fMultiply = CreateConVar("sm_knifedmg_multi", "2", "Knife damage multiplyer", _, true, 0.1);     gc_iTeam = CreateConVar("sm_knifedmg_team", "1", "Which team should get the extra dmg? 1 - CT only / 2- T only / 3 - both", _, true, 1.0, true, 3.0);          AutoExecConfig(true, "KnifeDMG"); } /******************************************************************************                    EVENTS ******************************************************************************/ public Action OnTakedamage(int victim, int &attacker, int &inflictor, float &damage, int &damagetype, int &weapon, float damageForce[3], float damagePosition[3], int damagecustom) {     if (!gc_bPlugin.BoolValue)         return Plugin_Continue;     if (!IsValidClient(victim, true, false) || attacker == victim || !IsValidClient(attacker, true, false))          return Plugin_Continue;     char sWeapon[32];     if (IsValidEntity(weapon)) GetEntityClassname(weapon, sWeapon, sizeof(sWeapon));     if ((GetClientTeam(attacker) == CS_TEAM_CT && gc_iTeam.IntValue == 1) || (GetClientTeam(attacker) == CS_TEAM_T && gc_iTeam.IntValue == 2) || gc_iTeam.IntValue == 3)     {         if ((StrEqual(sWeapon, "weapon_knife", false)))         {             damage = damage*gc_fMultiply.FloatValue;             return Plugin_Changed;         }     }     return Plugin_Continue; } /******************************************************************************                    FORWARDS LISTEN ******************************************************************************/ public void OnClientPutInServer(int client) {     SDKHook(client, SDKHook_OnTakeDamage, OnTakedamage); }

+9999999, Thanks shana!

I am looking for three plugins to be developed.
https://pastebin.com/SEW0mVgL

AND

Originally Posted by Bchewy Plugin to exchange csgo money to store credits Simple and usable commander plugin selection etc (Zombie escape).

[shanapu]

Originally Posted by Bchewy Plugin to exchange money to store credits

bored at work.
no way to test it from here, but should work...

Use: sm_exchange [amount]

sm_exchange_rate - 1 game dollar are x store credits - default 0.5
sm_exchange_limit - how many credits can be get in exchange per map

PHP Code:

#include <sourcemod> 
#include <sdktools> 
#include <cstrike> 
#include <store> 

ConVar gc_fRate; 
ConVar gc_iMaxExchange; 
int g_iAmount[MAXPLAYERS+1] = 0;

public Plugin myinfo =  
{ 
    name = "Money Exchange", 
    author = "shanapu", 
    description = "exchange game money to store credits", 
    version = "1.1", 
    url = "https://github.com/shanapu/" 
}; 

public void OnPluginStart() 
{ 
    RegConsoleCmd("sm_exchange", Command_Exchange) 
    gc_fRate = CreateConVar("sm_exchange_rate", "0.5", "1 game dollar are x store credits");
    gc_iMaxExchange = CreateConVar("sm_exchange_limit", "5000", "how many credits can be get in exchange per map", _, true, 1.0); 
} 

public Action Command_Exchange(int client, int args) 
{ 
    if (client == 0) 
    { 
        ReplyToCommand(client, "%t", "Command is in-game only"); 
        return Plugin_Handled; 
    } 

    if (args < 1) 
    { 
        ReplyToCommand(client, "Use: sm_exchange [amount]"); 
        return Plugin_Handled; 
    }

    char arg[10]; 
    GetCmdArg(1, arg, sizeof(arg)); 
    int amount = StringToInt(arg); 
    int money = GetEntProp(client, Prop_Send, "m_iAccount") 

    if (amount > money) 
    { 
        ReplyToCommand(client, "Not enough money"); 
        return Plugin_Handled; 
    }
    
    float fAmount = float(amount) * gc_fRate.FloatValue; 
    int newamount = RoundToZero(fAmount); 
    
    if(g_iAmount[client] + newamount >= gc_iMaxExchange.IntValue)
    {
        ReplyToCommand(client, "Reached the exchange limit of %i credits. Try smaller value", gc_iMaxExchange.IntValue); 
        return Plugin_Handled; 
    }
     
    SetEntProp(client, Prop_Send, "m_iAccount", money - amount); 


    g_iAmount[client] = g_iAmount[client] + newamount;
    Store_SetClientCredits(client, Store_GetClientCredits(client)+newamount); 
     
    PrintToChat(client, "Exchange: you got %d store credits for %d dollar", newamount, amount); 

    return Plugin_Handled; 
} 


[shanapu]

i fixed the compile errors in the code above.
the warning

// moneyexchange.sp(6) : warning 203: symbol is never used: "g_cvarChatTag"

is harmless & comes from a bad store.inc

[B3none]

If you need any help just give me a shout, I'm always up for spending an hour or two writing some code for you