[REQ] Brass Knuckles by default

Curryking · **Author**

Code:

#include <amxmodx>
#include <fakemeta>
#include <engine>
#include <cstrike>

new PLUGIN_NAME[] = "Brass Knuckles"
new PLUGIN_VERSION[] =  "1.0"
new PLUGIN_AUTHOR[] =   "Cheap_Suit"

new bool:g_bknuckles[33]
public plugin_init() 
{
    register_plugin(PLUGIN_NAME, PLUGIN_VERSION, PLUGIN_AUTHOR)
    register_event("CurWeapon", "Event_CurWeapon", "be", "1=1")
    register_event("Damage", "Event_Damage", "be", "2!0")
    register_event("DeathMsg", "Event_Death", "a")
    register_forward(FM_EmitSound, "EmitSound")
    register_clcmd("say /buybk", "cmdBuy")
}

public plugin_precache()
{
    precache_model("models/p_bknuckles.mdl")
    precache_model("models/v_bknuckles.mdl")
    precache_sound("bknuckles/knife_hit1.wav")
    precache_sound("bknuckles/knife_hit2.wav")
    precache_sound("bknuckles/knife_hit3.wav")
    precache_sound("bknuckles/knife_hit4.wav")
    precache_sound("bknuckles/knife_stab.wav")
}

public client_connect(id) g_bknuckles[id] = false
public Event_Death() g_bknuckles[read_data(2)] = false

public cmdBuy(id)
{
    new Cost = 5000, Money = cs_get_user_money(id)
    if(!is_user_alive(id))
        client_print(id, print_chat, "Sorry, You need to be alive")
    else if(Money < Cost)
        client_print(id, print_chat, "Sorry, You need %d to buy", Cost)
    else if(g_bknuckles[id])
        client_print(id, print_chat, "Sorry, You already bought a pair of brass knuckles")
    else
    {
        g_bknuckles[id] = true
        cs_set_user_money(id, Money - Cost)
        client_print(id, print_chat, "You bought a pair of brass knuckles")
    }
    return PLUGIN_HANDLED
}

public Event_Damage(id)
{
    if(!is_user_alive(id) || !is_user_connected(id)) 
        return PLUGIN_CONTINUE
        
    new AttakerWeapon, AttakerPartHit
    new Attacker = get_user_attacker(id, AttakerWeapon, AttakerPartHit)
    
    if(AttakerWeapon != CSW_KNIFE)
        return PLUGIN_CONTINUE
    
    if(!g_bknuckles[Attacker])
        return PLUGIN_CONTINUE
    
    new Float:Random_Float[3]
    for(new i = 0; i < 3; i++) Random_Float[i] = random_float(100.0, 150.0)
    Punch_View(id, Random_Float)

    return PLUGIN_CONTINUE
}

public Event_CurWeapon(id)
{
    if(!is_user_alive(id) || !is_user_connected(id)) 
        return PLUGIN_CONTINUE
        
    new temp[2], weapon = get_user_weapon(id, temp[0], temp[1])
    if(weapon == CSW_KNIFE)
    {
        if(g_bknuckles[id])
        {
            entity_set_string(id, EV_SZ_viewmodel, "models/v_bknuckles.mdl")
            entity_set_string(id, EV_SZ_weaponmodel, "models/p_bknuckles.mdl")
        }
    }
    return PLUGIN_CONTINUE
}

public EmitSound(id, channel, sample[])
{
    if(!is_user_alive(id) || !is_user_connected(id)) 
        return FMRES_IGNORED

    new temp[2], weapon = get_user_weapon(id, temp[0], temp[1])
    if(weapon == CSW_KNIFE)
    {
        if(g_bknuckles[id])
        {
            if(equal(sample,"weapons/knife_hit1.wav")) 
            {
                emit_sound(id, CHAN_WEAPON, "bknuckles/knife_hit1.wav", 1.0, ATTN_NORM, 0, PITCH_NORM)
                return FMRES_SUPERCEDE
            }
            else if(equal(sample,"weapons/knife_hit2.wav")) 
            {
                emit_sound(id, CHAN_WEAPON, "bknuckles/knife_hit2.wav", 1.0, ATTN_NORM, 0, PITCH_NORM)  
                return FMRES_SUPERCEDE
            }
            else if(equal(sample,"weapons/knife_hit3.wav")) 
            {
                emit_sound(id, CHAN_WEAPON, "bknuckles/knife_hit3.wav", 1.0, ATTN_NORM, 0, PITCH_NORM)  
                return FMRES_SUPERCEDE
            }
            else if(equal(sample,"weapons/knife_hit4.wav")) 
            {
                emit_sound(id, CHAN_WEAPON, "bknuckles/knife_hit4.wav", 1.0, ATTN_NORM, 0, PITCH_NORM)
                return FMRES_SUPERCEDE
            }
            else if(equal(sample,"weapons/knife_stab.wav")) 
            {
                emit_sound(id, CHAN_WEAPON, "bknuckles/knife_stab.wav", 1.0, ATTN_NORM, 0, PITCH_NORM)  
                return FMRES_SUPERCEDE
            }
        }
    }
    return FMRES_IGNORED
}

stock Punch_View(id, Float:ViewAngle[3])
{
    entity_set_vector(id, EV_VEC_punchangle, ViewAngle)
}

Can somebody please help me and change this plugin so, that the brass knuckels replaces the knife by default. (Remove the buy-part)

Thanks in advance!

Curry

FatalisDK · 05-01-2006 , 14:18

Something like this I suppose.

Code:

#include <amxmodx>
#include <fakemeta>
#include <engine>
#include <cstrike>

new PLUGIN_NAME[] =    "Brass Knuckles"
new PLUGIN_VERSION[] =     "1.0"
new PLUGIN_AUTHOR[] =    "Cheap_Suit"

public plugin_init() 
{
    register_plugin(PLUGIN_NAME, PLUGIN_VERSION, PLUGIN_AUTHOR)
    register_event("CurWeapon", "Event_CurWeapon", "be", "1=1")
    register_event("Damage", "Event_Damage", "be", "2!0")
    register_forward(FM_EmitSound, "EmitSound")
}

public plugin_precache()
{
    precache_model("models/p_bknuckles.mdl")
    precache_model("models/v_bknuckles.mdl")
    precache_sound("bknuckles/knife_hit1.wav")
    precache_sound("bknuckles/knife_hit2.wav")
    precache_sound("bknuckles/knife_hit3.wav")
    precache_sound("bknuckles/knife_hit4.wav")
    precache_sound("bknuckles/knife_stab.wav")
}

public Event_Damage(id)
{
    if(!is_user_alive(id) || !is_user_connected(id)) 
        return PLUGIN_CONTINUE
    
    new AttakerWeapon, AttakerPartHit
    get_user_attacker(id, AttakerWeapon, AttakerPartHit)
    
    if(AttakerWeapon != CSW_KNIFE)
        return PLUGIN_CONTINUE
    
    new Float:Random_Float[3]
    for(new i = 0; i < 3; i++) Random_Float[i] = random_float(100.0, 150.0)
    Punch_View(id, Random_Float)
    
    return PLUGIN_CONTINUE
}

public Event_CurWeapon(id)
{
    if(!is_user_alive(id) || !is_user_connected(id)) 
        return PLUGIN_CONTINUE
    
    new temp[2], weapon = get_user_weapon(id, temp[0], temp[1])
    if(weapon == CSW_KNIFE)
    {
        entity_set_string(id, EV_SZ_viewmodel, "models/v_bknuckles.mdl")
        entity_set_string(id, EV_SZ_weaponmodel, "models/p_bknuckles.mdl")
    }
    return PLUGIN_CONTINUE
}

public EmitSound(id, channel, sample[])
{
    if(!is_user_alive(id) || !is_user_connected(id)) 
        return FMRES_IGNORED
    
    new temp[2], weapon = get_user_weapon(id, temp[0], temp[1])
    if(weapon == CSW_KNIFE)
    {
        if(equal(sample,"weapons/knife_hit1.wav")) 
        {
            emit_sound(id, CHAN_WEAPON, "bknuckles/knife_hit1.wav", 1.0, ATTN_NORM, 0, PITCH_NORM)
            return FMRES_SUPERCEDE
        }
        else if(equal(sample,"weapons/knife_hit2.wav")) 
        {
            emit_sound(id, CHAN_WEAPON, "bknuckles/knife_hit2.wav", 1.0, ATTN_NORM, 0, PITCH_NORM)    
            return FMRES_SUPERCEDE
        }
        else if(equal(sample,"weapons/knife_hit3.wav")) 
        {
            emit_sound(id, CHAN_WEAPON, "bknuckles/knife_hit3.wav", 1.0, ATTN_NORM, 0, PITCH_NORM)    
            return FMRES_SUPERCEDE
        }
        else if(equal(sample,"weapons/knife_hit4.wav")) 
        {
            emit_sound(id, CHAN_WEAPON, "bknuckles/knife_hit4.wav", 1.0, ATTN_NORM, 0, PITCH_NORM)
            return FMRES_SUPERCEDE
        }
        else if(equal(sample,"weapons/knife_stab.wav")) 
        {
            emit_sound(id, CHAN_WEAPON, "bknuckles/knife_stab.wav", 1.0, ATTN_NORM, 0, PITCH_NORM)    
            return FMRES_SUPERCEDE
        }
    }
    return FMRES_IGNORED
}

stock Punch_View(id, Float:ViewAngle[3])
{
    entity_set_vector(id, EV_VEC_punchangle, ViewAngle)
}

Curryking · 05-01-2006 , 14:28

Thanks. I get a warning, when compiling.

Code:

/home/users/amxmodx/tmp3/phprq8r7W.sma(45) : warning 204: symbol is assigned a value that is never used: "Attacker"
Header size:            536 bytes
Code size:             2648 bytes
Data size:             2228 bytes
Stack/heap size:      16384 bytes; estimated max. usage=42 cells (168 bytes)
Total requirements:   21796 bytes

Curry

FatalisDK · 05-01-2006 , 14:32

I fixed that a few minutes ago.

Curryking · 05-01-2006 , 14:39

Sorry FatalisDK, than I was too fast ;-). Works fine. Thanks!

Curry

MC.TSHIRT · 02-26-2011 , 05:04 Re: [REQ] Brass Knuckles by default

All time sound bugs Knife on wall its knife sound
pls help me-.-

tuty · 02-26-2011 , 06:53 Re: [REQ] Brass Knuckles by default

try this

PHP Code:


			




#include < amxmodx >

#include < fakemeta >



#pragma semicolon 1



enum _: iModelsType

{

    VIEW_MODEL,

    PLAYER_MODEL

};



new const gKnifeModels[ iModelsType ][ ] =

{

    "models/v_bknuckles.mdl",

    "models/p_bknuckles.mdl"

};



new const gDefaultSounds[ ][ ] =

{

    "weapons/knife_hit1.wav",

    "weapons/knife_hit2.wav",

    "weapons/knife_hit3.wav",

    "weapons/knife_hit4.wav",

    "weapons/knife_stab.wav"

};



new const gReplaceSounds[ ][ ] =

{

    "bknuckles/knife_hit1.wav",

    "bknuckles/knife_hit2.wav",

    "bknuckles/knife_hit3.wav",

    "bknuckles/knife_hit4.wav",

    "bknuckles/knife_stab.wav"

};



public plugin_init( )

{

    register_plugin( "Brass Knuckles", "1.0.1", "Cheap_Suit" );

    

    register_event( "CurWeapon", "Event_CurWeapon", "be", "1=1" );

    register_event( "Damage", "Event_Damage", "be", "2!0" );



        register_forward( FM_EmitSound, "EmitSound" );

}



public plugin_precache( )

{

    new i;

    

    for( i = 0; i < sizeof gReplaceSounds; i++ )

    {

        precache_sound( gReplaceSounds[ i ] );

    }

    

    for( i = 0; i < sizeof gKnifeModels; i++ )

    {

        precache_model( gKnifeModels[ i ] );

    }

}



public Event_CurWeapon( id )

{

    if( !is_user_alive( id ) || !is_user_connected( id ) )

    {

        return;

    }

    

    if( get_user_weapon( id ) == CSW_KNIFE )

    {

        set_pev( id, pev_viewmodel2, gKnifeModels[ VIEW_MODEL ] );

        set_pev( id, pev_weaponmodel2, gKnifeModels[ PLAYER_MODEL ] );

    }

    

    return;

}



public Event_Damage( id )

{

    if( !is_user_alive( id ) || !is_user_connected( id ) )

    {

        return;

    }

    

    new iAttkWeapon, iAttkHit;

    get_user_attacker( id, iAttkWeapon, iAttkHit );

    

    if( iAttkWeapon != CSW_KNIFE )

    {

        return;

    }

    

    new Float:flPunchAngle[ 3 ], i;

    

    for( i = 0; i < 3; i++ )

    {

        flPunchAngle[ i ] = random_float( 100.0, 150.0 );

        set_pev( id, pev_punchangle, flPunchAngle );

    }

    

    return;

}



public EmitSound( id, channel, sample[ ] )

{

    if( !is_user_alive( id ) || !is_user_connected( id ) )

    {

        return FMRES_IGNORED;

    }

    

    if( get_user_weapon( id ) == CSW_KNIFE )

    {

        new i;

        

        for( i = 0; i < sizeof gDefaultSounds; i++ )

        {

            if( equal( sample, gDefaultSounds[ i ] ) )

            {

                emit_sound( id, CHAN_WEAPON, gReplaceSounds[ i ], VOL_NORM, ATTN_NORM, 0, PITCH_NORM );

                

                return FMRES_SUPERCEDE;

            }

        }

    }

    

    return FMRES_IGNORED;

}

MC.TSHIRT · 03-07-2011 , 16:11 Re: [REQ] Brass Knuckles by default

when i boxing someone i become an 360 flip i dont want it help me

Exolent[jNr] · *Last edited by Exolent[jNr]; 03-07-2011 at 18:43.*

PHP Code:


			


#include < amxmodx >
#include < fakemeta >

#pragma semicolon 1

enum _: iModelsType
{
    VIEW_MODEL,
    PLAYER_MODEL
};

new const gKnifeModels[ iModelsType ][ ] =
{
    "models/v_bknuckles.mdl",
    "models/p_bknuckles.mdl"
};

new const gDefaultSounds[ ][ ] =
{
    "weapons/knife_hit1.wav",
    "weapons/knife_hit2.wav",
    "weapons/knife_hit3.wav",
    "weapons/knife_hit4.wav",
    "weapons/knife_stab.wav"
};

new const gReplaceSounds[ ][ ] =
{
    "bknuckles/knife_hit1.wav",
    "bknuckles/knife_hit2.wav",
    "bknuckles/knife_hit3.wav",
    "bknuckles/knife_hit4.wav",
    "bknuckles/knife_stab.wav"
};

public plugin_init( )
{
    register_plugin( "Brass Knuckles", "1.0.1", "Cheap_Suit" );
    
    register_event( "CurWeapon", "Event_CurWeapon", "be", "1=1" );
    //register_event( "Damage", "Event_Damage", "be", "2!0" );

    register_forward( FM_EmitSound, "EmitSound" );
}

public plugin_precache( )
{
    new i;
    
    for( i = 0; i < sizeof gReplaceSounds; i++ )
    {
        precache_sound( gReplaceSounds[ i ] );
    }
    
    for( i = 0; i < sizeof gKnifeModels; i++ )
    {
        precache_model( gKnifeModels[ i ] );
    }
}

public Event_CurWeapon( id )
{
    if( !is_user_alive( id ) || !is_user_connected( id ) )
    {
        return;
    }
    
    if( get_user_weapon( id ) == CSW_KNIFE )
    {
        set_pev( id, pev_viewmodel2, gKnifeModels[ VIEW_MODEL ] );
        set_pev( id, pev_weaponmodel2, gKnifeModels[ PLAYER_MODEL ] );
    }
    
    return;
}

/*public Event_Damage( id )
{
    if( !is_user_alive( id ) || !is_user_connected( id ) )
    {
        return;
    }
    
    new iAttkWeapon, iAttkHit;
    get_user_attacker( id, iAttkWeapon, iAttkHit );
    
    if( iAttkWeapon != CSW_KNIFE )
    {
        return;
    }
    
    new Float:flPunchAngle[ 3 ], i;
    
    for( i = 0; i < 3; i++ )
    {
        flPunchAngle[ i ] = random_float( 100.0, 150.0 );
        set_pev( id, pev_punchangle, flPunchAngle );
    }
    
    return;
}*/

public EmitSound( id, channel, sample[ ] )
{
    if( !is_user_alive( id ) || !is_user_connected( id ) )
    {
        return FMRES_IGNORED;
    }
    
    if( get_user_weapon( id ) == CSW_KNIFE )
    {
        new i;
        
        for( i = 0; i < sizeof gDefaultSounds; i++ )
        {
            if( equal( sample, gDefaultSounds[ i ] ) )
            {
                emit_sound( id, CHAN_WEAPON, gReplaceSounds[ i ], VOL_NORM, ATTN_NORM, 0, PITCH_NORM );
                
                return FMRES_SUPERCEDE;
            }
        }
    }
    
    return FMRES_IGNORED;
}

MC.TSHIRT · 03-07-2011 , 17:58 Re: [REQ] Brass Knuckles by default

tmp/textSoankv.sma(43) : warning 217: loose indentation