[VJScope]

Problem:
It appears that some of the latest updates included that you can't buy 2 tasers in the same round. This also prevents my plugin to work.

Plugin idea:
If you kill a player with taser, you will get another one. If you miss, you will not get another one.

Tests 1:
I replaced weapon_taser with weapon_ak47 and it works every time. I have confirmed in various ways that the problem is:

GivePlayerItem(client, "weapon_taser");

Code:

#include <sourcemod>
#include <sdktools>
#include <cstrike>
#include <sdkhooks>
#include <colors>
#include <updater>

#define		MAX_WEAPON_STRING		80

new Handle:ClientTimer[MAXPLAYERS+1] = {INVALID_HANDLE, ...};

public Plugin:myinfo = 
{
	name = "Zeus Refill",
	author = "Original code TnTSCS, modified by VJScope",
	description = "If you kill with taser, you get another one",
	version = "",
	url = ""
}

public OnPluginStart()
{
	HookEvent("player_death", Event_PlayerDeath);
}

public Event_PlayerDeath(Handle:event, const String:name[], bool:dontBroadcast)
{
	new killer = GetClientOfUserId(GetEventInt(event, "attacker"));
	
	decl String:weapon[MAX_WEAPON_STRING];
	weapon[0] = '\0';
	
	GetEventString(event, "weapon", weapon, sizeof(weapon));
	
	if (StrEqual(weapon, "taser", false) || StrEqual(weapon, "knife", false))
	{
		ClientTimer[killer] = CreateTimer(0.5, Timer_GiveZeus, killer);
	}
}

public Action:Timer_GiveZeus(Handle:timer, any:client)
{
	ClientTimer[client] = INVALID_HANDLE;
	
	GivePlayerItem(client, "weapon_taser");
}

Tests 2:
We did some further testing with my another plugin which basically should give you taser every time you press mouse1 (fire a weapon). Here are the results.

Buy a taser = you will not get another when you press mouse1. It creates the weapon but forces you to drop it.
Use mouse1 to get a taser + terrorists fire the first taser = Everyone gets new taser after pressing mouse1.
Use mouse1 to get taser + CTs fire the first taser = No one will get another taser when they press mouse1. It creates the weapon but forces to drop it.

Code for 'Tests 2'

#include <sourcemod>
#include <sdktools>
#include <sdkhooks>

new Handle:ClientTimer[MAXPLAYERS+1] = {INVALID_HANDLE, ...};

public Plugin:myinfo = 
{
	name = "Zeus Refill Alltime",
	author = "VJScope",
	description = "Refills taser everytime",
	version = "",
	url = ""
}

public OnPluginStart()
{
	HookEvent("weapon_fire", Event_WeaponFire);
}

public Event_WeaponFire(Handle:event, const String:name[], bool:dontBroadcast)
{
	new client = GetClientOfUserId(GetEventInt(event, "userid"));
	
	ClientTimer[client] = CreateTimer(0.5, Timer_GiveZeus, client);
}

public Action:Timer_GiveZeus(Handle:timer, any:client)
{
	ClientTimer[client] = INVALID_HANDLE;
	
	GivePlayerItem(client, "weapon_taser");
}

Can anyone help?

[iGANGNAM]

If it is ZEUS ONLY server than you can use
sv_infinite_ammo 1

Maybe try messing up something with ammo than? Smlib have some functions I think

[VJScope]

It's not taser only server but there are few players who like playing with taser only/mostly. This is really bad thing for me. I have played cs games something like 10 years and taser + this plugin was pretty much the only thing that kept me interested...

"Maybe try messing up something with ammo than?" I guess, I have to look into that too..

[blaacky]

This works for me:

PHP Code:

public OnPluginStart()
{
    HookEvent("player_death", Event_PlayerDeath);
}

public Event_PlayerDeath(Handle:event, const String:name[], bool:dontBroadcast)
{
    new killer = GetClientOfUserId(GetEventInt(event, "attacker"));
    if(killer != 0)
    {
        decl String:weapon[64];
        GetEventString(event, "weapon", weapon, sizeof(weapon));
        
        if(StrEqual(weapon, "taser", false) || StrContains(weapon, "knife", false) != -1)
        {
            CreateTimer(0.5, Timer_GiveZeus, GetClientUserId(killer));
        }
    }
}

public Action:Timer_GiveZeus(Handle:timer, any:userid)
{
    new client = GetClientOfUserId(userid);
    
    if(client != 0)
    {
        GivePlayerItem(client, "weapon_taser");
    }
} 


I killed bots with a zeus and it gave me a new one every time.

And this gives me a zeus almost instantly:

PHP Code:

public OnPluginStart()
{
    HookEvent("player_death", Event_PlayerDeath);
}

public Event_PlayerDeath(Handle:event, const String:name[], bool:dontBroadcast)
{
    new killer = GetClientOfUserId(GetEventInt(event, "attacker"));
    if(killer != 0)
    {
        decl String:sWeapon[64];
        GetEventString(event, "weapon", sWeapon, sizeof(sWeapon));
        
        bool bGiveZeus;
        if(StrEqual(sWeapon, "taser", false))
        {
            int weapon = Client_GetActiveWeapon(killer);
            AcceptEntityInput(weapon, "Kill");
            
            bGiveZeus = true;
        }
        else if(StrContains(sWeapon, "knife", false) != -1)
        {
            bGiveZeus = true;
        }
        
        if(bGiveZeus == true)
        {
            RequestFrame(GiveZeus, GetClientUserId(killer));
        }
        
    }
}

public void GiveZeus(any userid)
{
    new client = GetClientOfUserId(userid);
    
    if(client != 0)
    {
        GivePlayerItem(client, "weapon_taser");
    }
} 


[lingzhidiyu]

PHP Code:

public Action:CS_OnBuyCommand(client, const String:weapon[])
{
    if (StrEqual(weapon, "taser", true))
    {
        GivePlayerItem(client, "weapon_taser");
        return Plugin_Handled;
    }

    return Plugin_Continue;
} 


[VJScope]

blaacky I tried your code but still doesn't work.. What other plugins did you have on? I took all off - except the default sourcemod plugins...

[Neuro Toxin]

You could set the ammo and fire rates in the weapon script also.

[lingzhidiyu]

Originally Posted by VJScope blaacky I tried your code but still doesn't work.. What other plugins did you have on? I took all off - except the default sourcemod plugins...

I am sure it does't work when i bought it and kill someone, dont use give cheat command.
You can use my code and need check money team buyzone and buytime.

[Bacardi]

@VJScope, this give you problem I assume
http://ranut.omafoorumi.net/t288-tas...tulen-rajoitin

*updated my post in there