[bally]

Hi guys, I've been looking into netprops but uh I can't seem to figure this out. I want to remove someone's clip and reserve ammo on a weapon, but I've been only lucky with the clip.. Any thoughts/help? Thanks

My code:

PHP Code:

stock SetReserveAmmo(client, ammo)
{
    new weapon = GetEntPropEnt(client, Prop_Data, "m_hActiveWeapon");
    if(weapon < 1) return;
    
    new ammotype = GetEntProp(weapon, Prop_Send, "m_iPrimaryAmmoType");
    if(ammotype == -1) return;
    
    SetEntProp(client, Prop_Send, "m_iAmmo", ammo, _, ammotype);
    PrintToChatAll("ammo: %i", ammo); // it does parse 0...
} 

public Action:SomeFunction(client, args)
{
new Primary = GetPlayerWeaponSlot(client, 0);
//new Secondary = GetPlayerWeaponSlot(client, 1);
new String:pc[32] = "null";
//new String:sc[32] = "null";
GetEdictClassname(Primary, pc, sizeof(pc));
Client_SetWeaponClipAmmo(client, pc, 0, 0);
SetReserveAmmo(client, 0);
} 


AND yes I also tried smlibs one, again doesn't seem to work!! welpp

[lingzhidiyu]

From dr.api's drapi_ammo.

PHP Code:

/***********************************************************/
/**************** SET AMMO PLAYER WEAPON *******************/
/***********************************************************/
stock int Client_SetWeaponPlayerAmmoEx(int client, int weapon, int primaryAmmo=-1, int secondaryAmmo=-1)
{
    int offset_ammo = FindDataMapOffs(client, "m_iAmmo");

    if (primaryAmmo != -1) 
    {
        int offset = offset_ammo + (Weapon_GetPrimaryAmmoType(weapon) * 4);
        SetEntData(client, offset, primaryAmmo, 4, true);
    }

    if (secondaryAmmo != -1) 
    {
        int offset = offset_ammo + (Weapon_GetSecondaryAmmoType(weapon) * 4);
        SetEntData(client, offset, secondaryAmmo, 4, true);
    }
}

/***********************************************************/
/***************** GET PRIMARY AMMO TYPE *******************/
/***********************************************************/
stock int Weapon_GetPrimaryAmmoType(int weapon)
{
    return GetEntProp(weapon, Prop_Data, "m_iPrimaryAmmoType");
}

/***********************************************************/
/**************** GET SECONDARY AMMO TYPE ******************/
/***********************************************************/
stock int Weapon_GetSecondaryAmmoType(int weapon)
{
    return GetEntProp(weapon, Prop_Data, "m_iSecondaryAmmoType");
}

/***********************************************************/
/******************** GET PRIMARY AMMO *********************/
/***********************************************************/
stock int GetPrimaryAmmo(int client, int weapon)
{
    int ammotype = Weapon_GetPrimaryAmmoType(weapon);
    if(ammotype == -1) 
    {
        return -1;
    }
    
    return GetEntProp(client, Prop_Send, "m_iAmmo", _, ammotype);
} 


[lingzhidiyu]

And your stock is fine.

[bally]

I'm calling the function like this Client_SetWeaponPlayerAmmoEx(client, Primary, 0, 0);
It's not working unfortunately.

Primary = GetPlayerWeaponSlot(client, 0);

I also get a big bunch of errors such as:

L 09/21/2015 - 15:07:24: [SM] Native "GetEntProp" reported: Property "m_iPrimaryAmmoType" not found (entity 0/worldspawn)
L 09/21/2015 - 15:07:24: [SM] Displaying call stack trace for plugin "remove_ammo.smx":
L 09/21/2015 - 15:07:24: [SM] [0] Line 73, D:\csgos\csgo\addons\sourcemod\scripting\remo ve_ammo.sp::Weapon_GetPrimaryAmmoType()
L 09/21/2015 - 15:07:24: [SM] [1] Line 57, D:\csgos\csgo\addons\sourcemod\scripting\remo ve_ammo.sp::Client_SetWeaponPlayerAmmoEx()
L 09/21/2015 - 15:07:24: [SM] [2] Line 48, D:\csgos\csgo\addons\sourcemod\scripting\remo ve_ammo.sp::RemoveAmmoBro()
L 09/21/2015 - 15:07:24: [SM] [3] Line 41, D:\csgos\csgo\addons\sourcemod\scripting\remo ve_ammo.sp::SpawnEvent()
L 09/21/2015 - 15:07:24: [SM] Native "GetEntProp" reported: Property "m_iPrimaryAmmoType" not found (entity 0/worldspawn)
L 09/21/2015 - 15:07:24: [SM] Displaying call stack trace for plugin "remove_ammo.smx":

[lingzhidiyu]

PHP Code:

public Action:SomeFunction(client, args)
{
    new Primary = GetPlayerWeaponSlot(client, CS_SLOT_PRIMARY);
    new Secondary = GetPlayerWeaponSlot(client, CS_SLOT_SECONDARY);

    if (Primary != -1)
    {
        Weapon_SetPrimaryClip(Primary, 0);
        SetReserveAmmo(client, Primary, 0);
    }

    if (Secondary != -1)
    {
        Weapon_SetPrimaryClip(Secondary, 0);
        SetReserveAmmo(client, Secondary, 0);
    }
}  

stock SetReserveAmmo(client, weapon, ammo)
{
    new ammotype = GetEntProp(weapon, Prop_Send, "m_iPrimaryAmmoType");
    if(ammotype == -1) return;
    
    SetEntProp(client, Prop_Send, "m_iAmmo", ammo, _, ammotype);
} 


[bally]

Originally Posted by lingzhidiyu PHP Code: public Action:SomeFunction(client, args) {     new Primary = GetPlayerWeaponSlot(client, CS_SLOT_PRIMARY);     new Secondary = GetPlayerWeaponSlot(client, CS_SLOT_SECONDARY);     if (Primary != -1)     {         Weapon_SetPrimaryClip(Primary, 0);         SetReserveAmmo(client, Primary, 0);     }     if (Secondary != -1)     {         Weapon_SetPrimaryClip(Secondary, 0);         SetReserveAmmo(client, Secondary, 0);     } }   stock SetReserveAmmo(client, weapon, ammo) {     new ammotype = GetEntProp(weapon, Prop_Send, "m_iPrimaryAmmoType");     if(ammotype == -1) return;          SetEntProp(client, Prop_Send, "m_iAmmo", ammo, _, ammotype); }

Hi, thanks for your fast reply, however It seems it doesn't completely work, the clip on the weapon is emptied, however the ammo that's left is not.. any help? so it seems that only the smlib function works :/

[Graffiti]

SetEntProp(weapon, Prop_Send, "m_iPrimaryReserveAmmoCount", 0);
SetEntProp(weapon, Prop_Send, "m_iClip1", 0);

[bally]

Originally Posted by Graffiti SetEntProp(weapon, Prop_Send, "m_iPrimaryReserveAmmoCount", 0); SetEntProp(weapon, Prop_Send, "m_iClip1", 0);

thats it sir! thanks ^^