[xuxinsheng1]

sorry my bad English

I create a function to make player move slowly:

PHP Code:

public OnPlayerHurt(Handle:event, const String:name[], bool:dontBroadcast)
{
    new iUserid = GetClientOfUserId(GetEventInt(event, "userid"));
    SetEntPropFloat(iUserid, Prop_Data, "m_flMaxspeed", 45);
    CreateTimer(1, Reset_Movespeed_Function, iUserid);
} 


but now if some one do 2 shoots in first second,victim's speed will be reset by that CreateTimer
How can reset that Timer Interval to 1 second at every shoot.
Or it can be close by another command,I will restart a new timer with 1 second
please help me please
I very need help as fast as possible

Thank every one read my thread thanks

[th7nder]

Just store timer in Handle and then KillTimer(handle);

[xuxinsheng1]

Originally Posted by th7nder Just store timer in Handle and then KillTimer(handle);

I do this but not work

PHP Code:

new Handle:MoveTHandle = INVALID_HANDLE;
public OnPlayerHurt(Handle:event, const String:name[], bool:dontBroadcast) 
{ 
    KillTimer(MoveTHandle);
    new iUserid = GetClientOfUserId(GetEventInt(event, "userid")); 
    SetEntPropFloat(iUserid, Prop_Data, "m_flMaxspeed", 45); 
    MoveTHandle = CreateTimer(1, Reset_Movespeed_Function, iUserid); 
} 


any command not work in these,even "SetEntPropFloat" and "new iUserid"
what's wrong

[Kailo]

My code was wrong, see code below!

[ici]

PHP Code:

#pragma semicolon 1

#include <sourcemod>

new Handle:gH_Timers[MAXPLAYERS+1] = {INVALID_HANDLE, ...};

public OnPluginStart()
{
    HookEvent("player_hurt", Event_PlayerHurt);
}

public OnClientDisconnect(client)
{
    if (gH_Timers[client] != INVALID_HANDLE)
    {
        KillTimer(gH_Timers[client]);
        gH_Timers[client] = INVALID_HANDLE;
    }
}

public Event_PlayerHurt(Handle:event, const String:name[], bool:dontBroadcast)
{
    new userid = GetEventInt(event, "userid");
    new client = GetClientOfUserId(userid);
    
    if (!client || !IsClientInGame(client))
        return;
    
    SetEntPropFloat(client, Prop_Data, "m_flMaxspeed", 45.0);
    
    if (gH_Timers[client] != INVALID_HANDLE)
    {
        KillTimer(gH_Timers[client]);
        gH_Timers[client] = INVALID_HANDLE;
    }
    
    gH_Timers[client] = CreateTimer(1.0, Reset_Movespeed_Function, userid);
}

public Action:Reset_Movespeed_Function(Handle:timer, any:userid)
{
    new client = GetClientOfUserId(userid);
    
    if (!client || !IsClientInGame(client))
        return;

    gH_Timers[client] = INVALID_HANDLE;
    
    // do stuff ...
    
    // The return value has no meaning for one-time timers.
} 


[Neuro Toxin]

Don't pass a client index through a timer. Always use GetClientUserId and GetClientOfUserId.

This is because the client may be replaced (disconnect and a new player takes the client index) while the timer is waiting to fire.

GetClientOfUserId will return 0 if the client is no longer connected

[ici]

Thanks for the info bro.

Btw, I've seen people pass the client's unique serial identifier (GetClientSerial).

What is this actually? Is it better to pass that than the userid?

Edit:
Found some information about client serials.
https://forums.alliedmods.net/showpo...90&postcount=4

[Neuro Toxin]

I believe userid is better as its an int value.

[xuxinsheng1]

Originally Posted by ici PHP Code: #pragma semicolon 1 #include <sourcemod> new Handle:gH_Timers[MAXPLAYERS+1] = {INVALID_HANDLE, ...}; public OnPluginStart() {     HookEvent("player_hurt", Event_PlayerHurt); } public OnClientDisconnect(client) {     if (gH_Timers[client] != INVALID_HANDLE)     {         KillTimer(gH_Timers[client]);         gH_Timers[client] = INVALID_HANDLE;     } } public Event_PlayerHurt(Handle:event, const String:name[], bool:dontBroadcast) {     new userid = GetEventInt(event, "userid");     new client = GetClientOfUserId(userid);          if (!client || !IsClientInGame(client))         return;          SetEntPropFloat(client, Prop_Data, "m_flMaxspeed", 45.0);          if (gH_Timers[client] != INVALID_HANDLE)     {         KillTimer(gH_Timers[client]);         gH_Timers[client] = INVALID_HANDLE;     }          gH_Timers[client] = CreateTimer(1.0, Reset_Movespeed_Function, userid); } public Action:Reset_Movespeed_Function(Handle:timer, any:userid) {     new client = GetClientOfUserId(userid);          if (!client || !IsClientInGame(client))         return;     gH_Timers[client] = INVALID_HANDLE;          // do stuff ...          // The return value has no meaning for one-time timers. }

thank you very much that worked!!!!!

)))))))))))))))))))))))))))))))))))))))

thanks thanks very thanks


and thanks every one