[dataviruset]

Hello!

I don't understand why my RoundStart-event just stops working in a loop.
No code afterwards is being executed, why?

PHP Code:

public Event_RoundStart(Handle:event, const String:name[], bool:dontBroadcast)
{
    new ct_give = GetConVarInt(sm_hosties_ct_start);

    // strip all weapons and give new stuff
    new wepIdx;
    for(new i=1; i <= GetMaxClients(); i++)
    {
        if ( (IsClientConnected(i)) && (IsClientInGame(i)) && (IsPlayerAlive(i)) ) // if player exists and is alive
        {
            for (new s = 0; s < 4; s++)
            {
                if ((wepIdx = GetPlayerWeaponSlot(i, s)) != -1)
                {
                    RemovePlayerItem(i, wepIdx);
                    RemoveEdict(wepIdx);
                }
            }
        }

        // if player == T
        if (GetClientTeam(i) == 2)
        {
            GivePlayerItem(i, "weapon_knife");
        }
        // if player == CT
        else if (GetClientTeam(i) == 3)
        {
            GivePlayerItem(i, "weapon_knife");
            if (ct_give > 0)
                GivePlayerItem(i, "weapon_deagle");
            if (ct_give > 1)
                GivePlayerItem(i, "weapon_m4a1");
        }

        PrintToChatAll("\x04[SM_Hosties DEBUG] \x01Weapon stripper: Loop %d finished.", i);
    }

    // everything done, enable player weapon dropping again
    AllowWeaponDrop = true; // >THIS< will not be executed?
} 


[BrutalGoerge]

if its halting, then chances are there's something in your error logs that could help

perhaps check to make sure they're alive when you give the weapons?

[thetwistedpanda]

Throw some PrintToChatAll() debug messages in your code and try to locate where it's bugging down at. Also, you might want to look into using a SDK call to strip players rather then having to do all that fun stuff.

Minor optimization: replace GetMaxClients() with MaxClients

[dataviruset]

This was a bit embarrasing, the error was BrutalGoerge's guess (that I should have checked to make sure that the players are alive when I give the weapons ).
But thanks to both of you, I will check that SDKCall out aswell!

[meng]

you already check if they are in game and alive. just give weapons inside that bracket

PHP Code:

    for (new i = 1; i <= MaxClients; i++)
    {
        if (IsClientInGame(i) && IsPlayerAlive(i)) // if player exists and is alive
        {
            for (new s = 0; s < 4; s++)
            {
                if ((wepIdx = GetPlayerWeaponSlot(i, s)) != -1)
                {
                    RemovePlayerItem(i, wepIdx);
                    RemoveEdict(wepIdx);
                }
            }
            // if player == T
            if (GetClientTeam(i) == 2)
            {
                GivePlayerItem(i, "weapon_knife");
            }
            // if player == CT
            else if (GetClientTeam(i) == 3)
            {
                GivePlayerItem(i, "weapon_knife");
                if (ct_give > 0)
                    GivePlayerItem(i, "weapon_deagle");
                if (ct_give > 1)
                    GivePlayerItem(i, "weapon_m4a1");
            }
        }
    } 


[dataviruset]

I know, solved it. Perhaps I should add [SOLVED] to the beggining of the topic