[meng]

what i want to do pick a random player from the available living players.
im clueless. but maybe this helps.... its the general idea...

PHP Code:

Pick_T_Player()
{
    new players;
    new pickedplayer;
    for (new i = 1; i <= MaxClients; i++)
    {
        if (IsClientInGame(i) && 
        IsPlayerAlive(i) &&
        GetClientTeam(i) == 2)
        {
            players++;
        }
    }
    pickedplayer = GetRandomInt( 1, players);
    return pickedplayer;
} 


i need "pickedplayer" to be a usable id i can use on player_spawn.

[javalia]

i was made almost same thing for my jail server plugin. here.....

for(new i = 1;i <= 10000; i++){
        
                //죄수들 중에서 랜덤하게 1명을 골라서 죄수대장으로 만든다.
                tempselect = GetRandomInt(1, MaxClients);
        
                if(isplayerconnectedingamealive(tempselect) == true){
                    
                    if(GetClientTeam(tempselect) == 2){
                        
                        new String:gangleadername[64];
                        GetClientName(tempselect, gangleadername, 64);
                        gangleader = tempselect;
                    
                        for(new temp = 1;temp <= MaxClients;temp++){
                        
                            if(isplayerconnectedingamealive(temp) == true){
                        
                                if(GetClientTeam(temp) == 2){
                            
                                    if(temp == gangleader){
                            
                                        PrintToChat(temp, "\x04당신이 이번 라운드의 죄수대장입니다");
                            
                                    }else{
                                
                                        PrintToChat(temp, "\x04%s 님이 이번 라운드의 죄수대장입니다", gangleadername);
                                
                                    }
                            
                                }
                        
                            }
                        
                        }
                    
                        gangleaderhelppanel(tempselect);
                        break;
                    
                    }
            
                }
        
            }

it may more clear code if use while statement.....anyway this is loose way..
some times it will not work....

so...hmm...

maybe u can make a list to save alive t and
just randomy select from the list.

[BrutalGoerge]

@op that is likely to return an invalid index, or someone not alive and on team #2

PHP Code:

pick()
{
    new count, clients[MaxClients];
    for (new i = 1; i <= MaxClients; i++)
    {
        if (IsClientInGame(i) && IsPlayerAlive(i) && GetClientTeam(i) == 2)
            clients[count++] = i; 
    }
    return clients[GetRandomInt(0,count)];
} 


[javalia]

Originally Posted by BrutalGoerge @op that might return an invalid index PHP Code: pick() {     new count, clients[MaxClients];     for (new i = 1; i <= MaxClients; i++)     {         if (IsClientInGame(i) && IsPlayerAlive(i) && GetClientTeam(i) == 2)             client[count++] = i;      }     return clients[GetRandomInt(0,count)]; }

what a incradevl awsome way!
my thing looks dummy......-_-;

[meng]

wow, slick. so the id im looking for is just an integer within MaxClients?

how do call it in player_spawn? since its not global v.

ex.

PHP Code:

new client = GetClientOfUserId(GetEventInt(event, "userid"));
if (client == pickedplayer)
    //do stuff 


[Lord Canistra]

If I understood you correctly...

PHP Code:

new chosen = GetRandomInt(1, GetClientCount())

while(!IsPlayerAlive(chosen))    // Here goes checking of whatever you need.
{
    chosen = GetRandomInt(1, GetClientCount())
}

// Do something with player.
PrintToChatAll("Chosen id is %i", chosen) 


[meng]

hmm. looking this over. there may be another problem. i need a player to be picked per team. so i need to store ids of players on specific teams. then chose between those ids separately.

and thanks! that all is making sense.

can i do this?

PHP Code:

pick(clientteam)
{
    new count, picked[MaxClients];
    for (new i = 1; i <= MaxClients; i++)
    {
        if (IsClientInGame(i) && IsPlayerAlive(i) && GetClientTeam(i) == clientteam)
            picked[count++] = i; 
    }
    return picked[GetRandomInt(0,count)];
} 

public EventPlayerSpawn(Handle:event, const String:name[],bool:dontBroadcast)
{
    new client = GetClientOfUserId(GetEventInt(event, "userid"));
    new clientteam = GetClientTeam(client);
    if (client == pick(clientteam))
        //do stuff 


[Kigen]

PickPlayerFromTeam(f_iTeam)
{
	new f_iClients[MaxClients+1], f_iCount;
	for(new i=1;i<=MaxClients;i++)
		if ( IsClientInGame(i) && GetClientTeam(i) == f_iTeam && IsPlayerAlive(i) )
			f_iClients[f_iCount++] = i;
	if ( f_iCount == 0 )
		return -1; // No clients to choose from.
	else
		return f_iClients[GetRandomInt(0, f_iCount-1)];
}

Should work. But untested.

[Theme97]

You're taking the wrong approach.

Say there are two CTs. The first CT spawns. pick() chooses him, so stuff happens. Then the other CT spawns. pick() runs again and also chooses him. Stuff happens to him too.

What you want to do is pick a T and CT on round_start instead of player_spawn.

[BrutalGoerge]

slight oversight on my part if you use what i posted... the return line should have 'count -1' since array starts at 0