[MPNumB]

plugin_init()
	register_forward( FM_CmdStart, "FMCmdStart" );

public FMCmdStart( id, uc_handle, randseed )
{
	new Float:fmove, Float:smove, Float:umove;
	get_uc(uc_handle, UC_ForwardMove, fmove);
	get_uc(uc_handle, UC_SideMove, smove);
	get_uc(uc_handle, UC_UpMove, umove);
	
	new Float:maxspeed;
	pev(id, pev_maxspeed, maxspeed);
	fmove = floatabs( fmove );
	smove = floatabs( smove );
	
	if( ((fmove*fmove)+(smove*smove)+(umove*umove))<=floatpower((maxspeed*0.52), 2.0) && (fmove || smove || umove) )
	{
		client_print( id, print_center, "WALKING" );
	}
	else
	{
		client_print( id, print_center, "RUNNING" );    
	}
}

I think this would be more accurate. Supports +moveup and +movedown.

However still this method works only if player is holding any movement key (meaning, that when player is sliding down after movement [even if holding shift], this method wont detect it), and can think that +strafe and mouse movement is when user is walking. Plus people can use scripts, and so on, what can trick this method. I'd suggest to use:

plugin_init()
	register_forward( FM_CmdStart, "FMCmdStart" );

public FMCmdStart( id, uc_handle, randseed )
{
	new Float:fmove, Float:smove, Float:umove;
	get_uc(uc_handle, UC_ForwardMove, fmove);
	get_uc(uc_handle, UC_SideMove, smove);
	get_uc(uc_handle, UC_UpMove, umove);
	
	new Float:maxspeed, maxwalkspeed;
	pev(id, pev_maxspeed, maxspeed);
	fmove = floatabs( fmove );
	smove = floatabs( smove );
	maxwalkspeed = what_is_higher((maxspeed*0.52), 22500.0);
	
	if( ((fmove*fmove)+(smove*smove)+(umove*umove))<=maxwalkspeed && (fmove || smove || umove) )
	{
		client_print( id, print_center, "WALKING" );
	}
	else
	{
		client_print( id, print_center, "RUNNING" );    
	}
}

Float:what_is_higher(Float:val1, Float:val2)
{
	if( val1>val2 )
		return val1;
	
	return val2;
}

Here we are being sure, that player is attempting to move at speed below stepsound speed. However it still doesn't solve the problem of player sliding a bit when releasing movement key. In this case, I've done next:

new bool:g_walking[33];

plugin_init()
	register_forward( FM_CmdStart, "FMCmdStart" );

public client_connect(id)
	g_walking[id] = false;

public client_putinserver(id)
	g_walking[id] = false;

public client_disconnect(id)
	g_walking[id] = false;

public FMCmdStart( id, uc_handle, randseed )
{
	new Float:fmove, Float:smove, Float:umove;
	get_uc(uc_handle, UC_ForwardMove, fmove);
	get_uc(uc_handle, UC_SideMove, smove);
	get_uc(uc_handle, UC_UpMove, umove);
	
	new Float:maxspeed, maxwalkspeed;
	pev(id, pev_maxspeed, maxspeed);
	fmove = floatabs( fmove );
	smove = floatabs( smove );
	maxwalkspeed = what_is_higher((maxspeed*0.52), 22500.0);
	
	static Float:oldspeed[33];
	
	if( ((fmove*fmove)+(smove*smove)+(umove*umove))>maxwalkspeed ) // attempting to move above walking speed (150*150). It's faster to multiply, than to use sqrt - saving CPU
	{
		g_walking[id] = false;
		//client_print( id, print_center, "RUNNING" );
	}
	else if( fmove || smove || umove ) // attempting to move below running speed
	{
		new Float:velocity[3];
		pev(id, pev_velocity, velocity);
		oldspeed[id] = ((velocity[0]*velocity[0])+(velocity[1]*velocity[1])+(velocity[2]*velocity[2])+1.0); // save old speed and an extra 1ups, since sliding down wont start from this frame
		g_walking[id] = true;
		//client_print( id, print_center, "WALKING" );
	}
	else if( g_walking[id] ) // no movement attempt, but may be sliding down after walking
	{
		new Float:velocity[3], Float:speed;
		pev(id, pev_velocity, velocity);
		speed = ((velocity[0]*velocity[0])+(velocity[1]*velocity[1])+(velocity[2]*velocity[2]));
		
		if( speed>maxwalkspeed ) // pushed up to beyond walking speed
		{
			g_walking[id] = false;
			client_print( id, print_center, "PUSHED TO RUN" ); 
		}
		else if( !speed ) // stopped
		{
			g_walking[id] = false;
			client_print( id, print_center, "STANDING" ); 
		}
		else if( speed>=oldspeed[id] ) // is player not decelerating?
		{
			g_walking[id] = false;
			client_print( id, print_center, "PUSHED" ); 
		}
		
		oldspeed[id] = speed;
	}
}

Float:what_is_higher(Float:val1, Float:val2)
{
	if( val1>val2 )
		return val1;
	
	return val2;
}

So, I think last example is the best. And use "g_walking[id]" to check is player walking or no.

[Infernuz]

What if player is crouching?

[Exolent[jNr]]

Check if player flags contain FL_DUCKING.

Fakemeta:

if(pev(id, pev_flags) & FL_DUCKING)
{
    // ducking
}

Engine:

if(get_entity_flags(id) & FL_DUCKING)
{
    // ducking
}

[ConnorMcLeod]

May be this method is more reliable :

PHP Code:

#include <amxmodx>
#include <fakemeta>

#define PLUGIN "Walk Detect"
#define VERSION "0.0.1"

new const g_szCvarsNames[][] = 
{
    "cl_sidespeed",
    "cl_forwardspeed",
    "cl_backspeed",
    // "cl_upspeed",
    "cl_movespeedkey"
}

enum
{
    SIDE_SPEED,
    FORWARD_SPEED,
    BACK_SPEED,
    // UP_SPEED,
    MOVE_SPEED_KEY
}

new Float:g_flUserCvarsValues[33][sizeof(g_szCvarsNames)]
new bool:g_bIsWalking[33]

public plugin_init()
{
    register_plugin( PLUGIN, VERSION, "ConnorMcLeod" )
    register_forward(FM_CmdStart, "OnCmdStart")
}

public client_disconnect( id )
{
    remove_task(id)
}

public client_putinserver( id )
{
    if( !is_user_bot(id) )
    {
        set_task(0.1, "CheckCvars", id)
    }
}

public CheckCvars( id )
{
    if( is_user_connected(id) )
    {
        new cvar_index[1]
        for(new i; i<sizeof(g_szCvarsNames); i++)
        {
            cvar_index[0] = i
            query_client_cvar(id, g_szCvarsNames[i], "CvarResult", sizeof(cvar_index), cvar_index)
        }
    }
}

public CvarResult(id, szCvar[], szValue[], mParms[])
{
    if( is_user_connected(id) )
    {
        g_flUserCvarsValues[id][mParms[0]] = str_to_float(szValue)
        query_client_cvar(id, szCvar, "CvarResult", 1, mParms)
    }
}

public OnCmdStart(id, cmd)
{
    if( !is_user_alive(id) )
    {
        return
    }

    static Float:move, buttons, Float:normalmove
    buttons = get_uc(cmd, UC_Buttons)

    if( buttons & (IN_FORWARD|IN_BACK) != (IN_FORWARD|IN_BACK) )
    {
        normalmove = 0.0
        get_uc(cmd, UC_ForwardMove, move)
        
        if( buttons & IN_FORWARD )
        {
            normalmove += g_flUserCvarsValues[id][FORWARD_SPEED]
        }
        else
        {
            normalmove += g_flUserCvarsValues[id][BACK_SPEED]
        }
        
        if( move == normalmove * g_flUserCvarsValues[id][MOVE_SPEED_KEY] )
        {
            g_bIsWalking[id] = true
            return
        }
    }

    if( buttons & (IN_MOVELEFT|IN_MOVERIGHT) != (IN_MOVELEFT|IN_MOVERIGHT) )
    {
        normalmove = 0.0
        get_uc(cmd, UC_SideMove, move)
        
        if( buttons & IN_MOVELEFT )
        {
            normalmove -= g_flUserCvarsValues[id][SIDE_SPEED]
        }
        else
        {
            normalmove += g_flUserCvarsValues[id][SIDE_SPEED]
        }
        
        if( move == normalmove * g_flUserCvarsValues[id][MOVE_SPEED_KEY] )
        {
            g_bIsWalking[id] = true
            return
        }
    }
    g_bIsWalking[id] = false
} 


Client code :

Spoiler

/*
================
CL_CreateMove

Send the intended movement message to the server
if active == 1 then we are 1) not playing back demos ( where our commands are ignored ) and
2 ) we have finished signing on to server
================
*/
void DLLEXPORT CL_CreateMove ( float frametime, struct usercmd_s *cmd, int active )
{	
	float spd;
	vec3_t viewangles;
	static vec3_t oldangles;

	if ( active )
	{
		//memset( viewangles, 0, sizeof( vec3_t ) );
		//viewangles[ 0 ] = viewangles[ 1 ] = viewangles[ 2 ] = 0.0;
		gEngfuncs.GetViewAngles( (float *)viewangles );

		CL_AdjustAngles ( frametime, viewangles );

		memset (cmd, 0, sizeof(*cmd));
		
		gEngfuncs.SetViewAngles( (float *)viewangles );

		if ( in_strafe.state & 1 )
		{
			cmd->sidemove += cl_sidespeed->value * CL_KeyState (&in_right);
			cmd->sidemove -= cl_sidespeed->value * CL_KeyState (&in_left);
		}

		cmd->sidemove += cl_sidespeed->value * CL_KeyState (&in_moveright);
		cmd->sidemove -= cl_sidespeed->value * CL_KeyState (&in_moveleft);

		cmd->upmove += cl_upspeed->value * CL_KeyState (&in_up);
		cmd->upmove -= cl_upspeed->value * CL_KeyState (&in_down);

		if ( !(in_klook.state & 1 ) )
		{	
			cmd->forwardmove += cl_forwardspeed->value * CL_KeyState (&in_forward);
			cmd->forwardmove -= cl_backspeed->value * CL_KeyState (&in_back);
		}	

		// adjust for speed key
		if ( in_speed.state & 1 )
		{
			cmd->forwardmove *= cl_movespeedkey->value;
			cmd->sidemove *= cl_movespeedkey->value;
			cmd->upmove *= cl_movespeedkey->value;
		}

		// clip to maxspeed
		spd = gEngfuncs.GetClientMaxspeed();
		if ( spd != 0.0 )
		{
			// scale the 3 speeds so that the total velocity is not > cl.maxspeed
			float fmov = sqrt( (cmd->forwardmove*cmd->forwardmove) + (cmd->sidemove*cmd->sidemove) + (cmd->upmove*cmd->upmove) );

			if ( fmov > spd )
			{
				float fratio = spd / fmov;
				cmd->forwardmove *= fratio;
				cmd->sidemove *= fratio;
				cmd->upmove *= fratio;
			}
		}

		// Allow mice and other controllers to add their inputs
		IN_Move ( frametime, cmd );
	}

	cmd->impulse = in_impulse;
	in_impulse = 0;

	cmd->weaponselect = g_weaponselect;
	g_weaponselect = 0;
	//
	// set button and flag bits
	//
	cmd->buttons = CL_ButtonBits( 1 );

	// If they're in a modal dialog, ignore the attack button.
	if(GetClientVoiceMgr()->IsInSquelchMode())
		cmd->buttons &= ~IN_ATTACK;

	// Using joystick?
	if ( in_joystick->value )
	{
		if ( cmd->forwardmove > 0 )
		{
			cmd->buttons |= IN_FORWARD;
		}
		else if ( cmd->forwardmove < 0 )
		{
			cmd->buttons |= IN_BACK;
		}
	}

	gEngfuncs.GetViewAngles( (float *)viewangles );
	// Set current view angles.

	if ( g_iAlive )
	{
		VectorCopy( viewangles, cmd->viewangles );
		VectorCopy( viewangles, oldangles );
	}
	else
	{
		VectorCopy( oldangles, cmd->viewangles );
	}

}

I haven't implemented anything with upspeed because there is no IN_UP and IN_DOWN so any attempt wouldn't be reliable, also i think it is only used in water ?

[Fr33m@n]

I just tested this version, it doesn't work ConnorMcLeod. The return value is always 0 even if i move the non working get_uc(cmd, UC_Buttons, buttons) by the working buttons = get_uc(cmd, UC_Buttons)
Your previous one in previous pages is working well but sometimes false walk repport.

[ConnorMcLeod]

And with fixed buttons = get_uc(cmd, UC_Buttons) ?