[Exolent[jNr]]

Mine is just a little less advanced than connorr's but it still gets the job done.

#include <amxmodx>
#include <fakemeta>

enum CsTeams
{
    CS_TEAM_UNASSIGNED = 0,
    CS_TEAM_T,
    CS_TEAM_CT,
    CS_TEAM_SPECTATOR
};

#define OFFSET_TEAM 114
#define OFFSET_MONEY    115

#define cs_get_user_team(%1) CsTeams:get_pdata_int(%1, OFFSET_TEAM)
#define cs_get_user_money(%1) get_pdata_int(%1, OFFSET_MONEY)

#define MONEY_EXTRA 1400
#define MONEY_MAX   16000

new g_iMsgMoney;
new g_iMaxPlayers;

public plugin_init()
{
    register_plugin("Money For Losers", "0.1", "Exolent");
    register_event("SendAudio", "event_SendAudio", "a", "2&%!MRAD_terwin", "2&%!MRAD_ctwin");
    g_iMsgMoney = get_user_msgid("Money");
    g_iMaxPlayers = get_maxplayers();
}

public event_SendAudio()
{
    new sWinner[9];
    read_data(2, sWinner, sizeof(sWinner) - 1);
    
    new CsTeams:iTeam = (sWinner[7] != 'c') ? CS_TEAM_CT : CS_TEAM_T;
    
    new iMoney;
    for(new id = 1; id <= g_iMaxPlayers; id++)
    {
        if(is_user_connected(id) && cs_get_user_team(id) == iTeam)
        {
            iMoney = cs_get_user_money(id);
            if(iMoney >= MONEY_MAX)
            {
                continue;
            }
            
            iMoney = min(iMoney + MONEY_EXTRA, MONEY_MAX);
            cs_set_user_money(id, iMoney, 1);
        }
    }
}

stock cs_set_user_money(index, iMoney, iFlash = 1)
{
    if(!is_user_connected(index))
    {
        return 0;
    }
    
    set_pdata_int(index, OFFSET_MONEY, iMoney);
    
    message_begin(MSG_ONE_UNRELIABLE, g_iMsgMoney, _, index);
    write_long(iMoney);
    write_byte(iFlash ? 1 : 0);
    message_end();
    
    return 1;
}

[Maurice]

Thanks connorr, but what does this plugin all because i read something about team_advantage_streak.

Maybe it's easier if i tell something about the problem i'm trying to fix.
I've a cs_assault only server wich is for CT much harder as the terrorists to win. To give CT a better win chance i using a roundstart money plugin wich give each player on the server $3600. If a player already have $3600 or more the plugin give nothing so the plugin only helps the losing team so they can spend also $3600 for good weapons and gives a better winning chance.

The negative part of this plugin is that the "pistol round" is gone because the first round the plugin give all players $3600 and quik buyers can even get twice $3600.

It would be really great if there was a plugin that give BEFORE roundstart only the died players from the losing team $3600 and if one of the players already have $3600 or more they get nothing. The reason why alive players from the losing team don't need to receive money is because they are mostly campers or didn't do enough their best to win the round. If this plugin could be realised i would be a very happy person.

[ConnorMcLeod]

If the winning team wins X team_advantage_streak rounds in a row, the plugin gives to loosing team X * team_advantage_money $

[Maurice]

Thanks for the explanation connerr, if i set it to 1 it will disable the feature if i'm right?

Because you know alot about amxx scripting connorr can i ask you for your opinion if the idea in my last post would be possible to make into a plugin because that would for me the ultimate round start money plugin.

[ConnorMcLeod]

Yes it can be done.
Waiting this day, you can use my roundstartmoney plugin that will prevent fast buyers.
This plugin works with mp_startmoney :

[Maurice]

Thanks connerr and X-olent i didnt meantion your post earlier as now. I will test both plugins.

[Maurice]

I've just tested both plugins and both work perfect! The reason why i've choiced to use connor's roundstartmoney plugin is because with a roundstartmoney below the roundwinbonusmoney ($3600) it don't matters if all players get extra money because in all cases the winning team players get $3600.

X-olent's moneyforlosers plugin make nice distinction between the winning and losing team players but with a low extra rondstartmoney (below $3600) it dont realy matters, it would be a different storry if this plugin also maded distinction between died and living players. After testing with this plugin i noticed the money is given when all players are death from the losing team wichof it isn't editable to give only the died players extra money but nervertheless thanks for the plugin.

[kobri]

Players in my servers have found a bug - using record/stop demo makes the plugin give you money

[Jelle]

Because Conner and Exolent has to be so advanced with everything. This should work:

PHP Code:

#include <amxmodx>
#include <cstrike>



public plugin_init()
{
    register_plugin("Money for losing team", "1.0", "Jelle")
    
    register_event("SendAudio", "tr_win", "a", "2&%!MRAD_terwin")
    register_event("SendAudio", "ct_win", "a", "2&%!MRAD_ctwin")
}

public tr_win()
{
    new players[32], playerCount, i, player
    get_players(players, playerCount, "h")
    
    for ( i = 0; i < playerCount; i++ )
    {
        player = players[i]
        
        if ( cs_get_user_team(player) == CS_TEAM_CT )
        {
            cs_set_user_money(player, cs_get_user_money(player) + 1400)
        }
    }
}

public ct_win()
{
    new players[32], playerCount, i, player
    get_players(players, playerCount, "h")
    
    for ( i = 0; i < playerCount; i++ )
    {
        player = players[i]
        
        if ( cs_get_user_team(player) == CS_TEAM_T )
        {
            cs_set_user_money(player, cs_get_user_money(player) + 1400)
        }
    }
} 


[ConnorMcLeod]

Originally Posted by kobri Players in my servers have found a bug - using record/stop demo makes the plugin give you money

I have replaced #15 plugin that was the cause of this issue (was quite old plugin).