[kirksite]

I have googled and searched Allied Modders for a plugin that would allow a server to set round start health by STEAM ID and the closest I found was a handycap plugin. HAs this been done in the past and if not could it be done?

https://forums.alliedmods.net/showthread.php?t=15480

[Bugsy]

Of course it can be done. How do you want to define the steam-id's that get the higher health?

[Supremache]

Originally Posted by kirksite I have googled and searched Allied Modders for a plugin that would allow a server to set round start health by STEAM ID and the closest I found was a handycap plugin. HAs this been done in the past and if not could it be done? https://forums.alliedmods.net/showthread.php?t=15480

PHP Code:

#include <amxmodx>
#include <amxmisc>
#include <fakemeta>
#include <hamsandwich>

#if !defined TrieGetSize
    native TrieGetSize( Trie:handle )
#endif

#if !defined MAX_PLAYERS
    const MAX_PLAYERS = 32
#endif

#if !defined MAX_AUTHID_LENGTH
    const MAX_AUTHID_LENGTH = 64
#endif

enum _:PlayerHealth
{
    Player_SteamID[ MAX_AUTHID_LENGTH ],
    Player_Health[ 12 ]
}

new Trie:g_tHealth, eData[ PlayerHealth ], g_szSteamID[ MAX_PLAYERS + 1 ][ MAX_AUTHID_LENGTH ];

public plugin_init( ) 
{
    register_plugin( "Hp by steamid", "1.0", "Supremache" )
    
    RegisterHam( Ham_Spawn, "player", "OnPlayerSpawn", 1 )
    
    g_tHealth = TrieCreate( );
    ReloadFile( );
}

public client_connect( id )
{
    get_user_authid( id, g_szSteamID[ id ], charsmax( g_szSteamID[ ] ) )
}

public plugin_end( )
{
    TrieDestroy( g_tHealth );
}

public OnPlayerSpawn( id )
{
    if( !is_user_alive( id ) )
    {
        return;
    }
    
    if( TrieGetArray( g_tHealth, g_szSteamID[ id ], eData, sizeof eData ) )
    {
        set_pev( id, pev_health, str_to_float( eData[ Player_Health ] ) )
    }
} 
ReloadFile( )
{
    new g_szFile[ 128 ]
    
    get_configsdir( g_szFile, charsmax( g_szFile ) );
    add( g_szFile, charsmax( g_szFile ), "/SteamHp.ini" )
    
    new iFile = fopen( g_szFile, "rt" );
    
    if( iFile )
    {
        new szData[ 96 ];
        
        while( fgets( iFile, szData, charsmax( szData ) ) )
        {    
            trim( szData );
            
            switch( szData[ 0 ] )
            {
                case EOS, ';', '#', '/': continue;
                default:
                {
                    parse( szData, eData[ Player_SteamID ], charsmax( eData[ Player_SteamID ] ), eData[ Player_Health ], charsmax( eData[ Player_Health ] ) ) 
                    
                    if( eData[ Player_SteamID ][ 0 ] )
                    {
                        TrieSetArray( g_tHealth, eData[ Player_SteamID ], eData, sizeof eData );
                        server_print( "SteamID: %s, HP: %d", eData[ Player_SteamID ], str_to_num( eData[ Player_Health ] ) )
                    }
                        
                    arrayset( eData, 0, sizeof( eData ) );
                }
            } 
        } 
        fclose( iFile );
        
        if( TrieGetSize( g_tHealth ) )
        {
            server_print( "Loaded %d data from the file", TrieGetSize( g_tHealth ) )
        }
    }
    else
    {
        static szErr[ 64 ];
        formatex( szErr, charsmax( szErr ), "The file %s doesn't exists" , g_szFile );
        set_fail_state( szErr );
    }
} 


[kirksite]

Originally Posted by Bugsy Of course it can be done. How do you want to define the steam-id's that get the higher health?

We have regulars who play at a level well above everyone else. I don't want to ban and I'm tired of requesting they "gun down". If I had the ability to handycap +/- 6 players by STEAM ID it would solve the problem and level the field.

[kirksite]

Supremache - each STEAM_ID is hard coded into the plugin?

[Supremache]

Originally Posted by kirksite Supremache - each STEAM_ID is hard coded into the plugin?

What do you mean about hard coded ?!
Do u wanna a config file or command for adding steam id or what ?

{ "STEAM_ID_ONE", 100 }

It's works like: player with steam id 'STEAM_ID_ONE' will get 100 healths per respawn

[kirksite]

Originally Posted by Supremache What do you mean about hard coded ?! Do u wanna a config file or command for adding steam id or what ? { "STEAM_ID_ONE", 100 } It's works like: player with steam id 'STEAM_ID_ONE' will get 100 healths per respawn

[kirksite]

a config file would probably be the simplest.

[Supremache]

Try it now, file name 'SteamHp.ini'
It's works like: "SteamID" "Health"

[kirksite]

No joy.
complied sma file and uploaded to /cstrike/addons/amxmodx/plugins
saved notepad SteamHP.ini file to /cstrike/addons/amxmodx/configs ("STEAM_0:1:269172" "80")

Hp by steamid 1.0 Supremache PlayerHealth.am running

Currently loaded modules:
name version author status
Fun 1.9.0.5294 AMX Mod X Dev Team running
Engine 1.9.0.5294 AMX Mod X Dev Team running
FakeMeta 1.9.0.5294 AMX Mod X Dev Team running
CStrike 1.9.0.5294 AMX Mod X Dev Team running
CSX 1.9.0.5294 AMX Mod X Dev Team running
Ham Sandwich 1.9.0.5294 AMX Mod X Dev Team running
MySQL 1.9.0.5294 AMX Mod X Dev Team running