[Supremache]

VIP System


Table of contents:

• Description
• API
• Credits
• Changelog
• Download Files
• Server using this plugin

DESCRIPTION
0

It work like admin system of AMX-MODX with optimized coding you can create flags and assign to each flag some functions
This adds can edit easly from VIPSettings file:

✓ Auto reload or command to reload vip
✓ Scoreboard
✓ Command for adding user to the vip file
✓ Connect message
✓ list vip's online
✓ Free vip time

API
0

Full documentation can be found there, as well in include file:

PHP Code:

#if defined _vip_included
    #endinput
#endif

#define _vip_included

enum _:(<<= 1)
{
    VIP_ALL,
    VIP_LEVEL_A,
    VIP_LEVEL_B,
    VIP_LEVEL_C,
    VIP_LEVEL_D,
    VIP_LEVEL_E,
    VIP_LEVEL_F,
    VIP_LEVEL_G,
    VIP_LEVEL_H,
    VIP_LEVEL_I,
    VIP_LEVEL_J,
    VIP_LEVEL_K,
    VIP_LEVEL_L,
    VIP_LEVEL_M,
    VIP_LEVEL_N,
    VIP_LEVEL_O,
    VIP_LEVEL_P,
    VIP_LEVEL_Q,
    VIP_LEVEL_R,
    VIP_LEVEL_S,
    VIP_LEVEL_T,
    VIP_LEVEL_U,
    VIP_LEVEL_V,
    VIP_LEVEL_W,
    VIP_LEVEL_X,
    VIP_LEVEL_Y,
    VIP_USER
}

/**
 * Returns the chat prefix set in the plugin's configuration file.
 *
 * @param szBuffer         Buffer to store the prefix in.
 * @param iLen             Maximum buffer length.
 * @noreturn
 */
 
native get_vip_prefix( szBuffer[ ], iLen )
 
 /**
 * Returns the vip expire date set in the plugin's configuration file.
 *
 * @param id            Client index.
 * @param szBuffer         Buffer to store the prefix in.
 * @param iLen             Maximum buffer length.
 * @noreturn
 */

native get_vip_expire( id, szBuffer[ ], iLen )

/**
 * Set in the plugin's configuration file.
 *
 * @param szID             Client name or authid
 * @param szPassword         Client password
 * @param szFlags         Client Flags
 * @param szExpireDate      Client Expire Date
 * @noreturn
 */
 
native add_user_vip( const szID[ ], const szPassword[ ], const szFlags[ ], const szExpireDate[ ] )

/**
 * Checks if the client is VIP according to the VIP flags set in the plugin's configuration file or in subplugin's.
 *
 * @param id            Client index.
 * @return            True if he is, false otherwise.
 */
 
native bool:is_user_vip( id )

/**
 * Checks if the free vip time is active.
 *
 * @param id            Client index.
 * @return            True if free vip active, false otherwise.
 */
 
native bool:is_free_vip_time( )

/**
 * Returns the client is VIP according to the VIP flags.
 *
 * @param id             Client index.
 * @return            Client VIP.
 * @ex:             get_user_vip( id ) & VIP_LEVEL_A 
 */
 
native get_user_vip( id )

/**
 * Set the client as VIP.
 *
 * @param id             Client index.
 * @param szFlags        Client Flags.
 * @return            Client VIP.
 */
 
native set_user_vip( id, szFlags )

/**
 * Remove the client from VIP flags.
 *
 * @param id             Client index.
 * @param szFlags        Client Flags select one flags to get remove
 * @noreturn        
 */
 
native remove_user_vip( id, szFlags = -1 )

/**
 * Returns if the client has any of the specified vip flags.
 *
 * @param id      Client index
 * @param flags   Flag string
 *
 * @return        1 if the user has any of the specified flags, 0 otherwise
 */
 
stock has_vip_flag( id, const szFlags[ ] )
{
    return( get_user_vip( id ) & read_flags( szFlags ) );
}

/**
 * Returns if the client has all of the specified vip flags.
 *
 * @param id      Client index
 * @param flags   Flag string
 *
 * @return        1 if the user has all of the specified flags, 0 otherwise
 */
 
stock has_all_vip_flags( id, const szFlags[ ] )
{
    new _Flags = read_flags( szFlags );
    return( ( get_user_vip( id ) & _Flags ) == _Flags );
} 


CHANGELOG
0

v1.0.5 : February, 17, 2022

• Added option for file to enable or disable VIP auto reload.
• Added console command to reload VIPs, It's work only if you disable option auto reload.

v1.0.4 : February, 15, 2022

• Fixed a bug when free vip time started it was given a random access or full access for everyone.

v1.0.3 : February, 14, 2022

• Code Optimized.
• Create account file from "VIPSettings.ini" file
• If the user has expired or is disabled, it will not be read from the file
• Added support for IP, now you can add user by IP
• Added has_vip_flag( id, szFlag[ ] ) for returns if the client has any of the specified vip flags.
• Added has_all_vip_flags( id, szFlag[ ] ) for returns if the client has any of the specified vip flags or multi flags.
• Added a log that show how many accounts in the file.

v1.0.2 : January, 5, 2022

• Added %expiredate% field for connect message
• Added native get_vip_expire( id, buffer, ilen ) for return the vip expire date.

v1.0.1 : December, 14, 2021

• Create the connect message from VIPSetting.ini, if the message empty, will not show.
• Added fields %name% , %authid% , %flag% for connect message.
• Control the time of task's from VIPSetting.ini.

v1.0.0 : December, 10, 2021

• Initial release.

CREDITS
0

➥ OciXCrom - (CromChat).
➥ edon1337 I learned many things from his plugin "elite admin system"

DOWNLOAD FILES ( Server using this plugin )
0

DOWNLOAD SOURCE CODE

[Supremache]

#include <amxmodx>
#include <vip>
#include <hamsandwich>

new g_cExtraDamage

public plugin_init()
{
	register_plugin("Extra Damage", "1.0", "Supremache")
	g_cExtraDamage = register_cvar( "vp_extra_dmg", "1.2" )
	
	RegisterHam( Ham_TakeDamage, "player", "PreTakeDamage" )
}


public PreTakeDamage( iVictim, iInflictor, iAttacker, Float:fDamage, iDamageBits )
{
	if( is_user_connected( iAttacker ) && iAttacker == iInflictor && get_user_vip( iAttacker ) & VIP_LEVEL_A )
	{
		SetHamParamFloat( 4, fDamage * get_pcvar_float( g_cExtraDamage ) )
	}
}

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>
#include <vip>

public plugin_init( )
{
	register_plugin("VIP: No Fall Damage on Head", "1.0", "OciXCrom")
	RegisterHam(Ham_TakeDamage, "player", "PreTakeDamage")
}

public PreTakeDamage(iVictim, iInflictor, iAttacker, Float:fDamage, iBits)
{
	if(iBits & DMG_FALL && !is_user_connected(iAttacker) && get_user_vip( iAttacker ) & VIP_LEVEL_A )
	{
		new iEnt = pev(iVictim, pev_groundentity)

		if(!pev_valid(iEnt))
		{
			return HAM_IGNORED
		}

		if(is_user_connected(iEnt))
		{
			return HAM_SUPERCEDE
		}
	}

	return HAM_IGNORED
}

#include <amxmodx>
#include <fakemeta>
#include <vip>

enum _:eTotalCvars
{
	Kill_Health,
	Kill_Armor,
	Hs_Kill_Health,
	Hs_Kill_Armor,
	He_Kill_Health,
	He_Kill_Armor,
	Knife_Kill_Health,
	Knife_Kill_Armor
}
	
new g_iTotalCvars[ eTotalCvars ];

public plugin_init( ) 
{
	register_plugin( "VIP: Kill Reward (HP & Armor)", "1.0.0", "Supremache" )
	register_event( "DeathMsg", "OnPlayerKilled", "a" )
	
	/* Set cvar as zero to disable any option */
	g_iTotalCvars[ Kill_Health ] = register_cvar( "vp_normal_kill_hp", "10" );
	g_iTotalCvars[ Kill_Armor ] = register_cvar( "vp_normal_kill_armor", "10" );
	g_iTotalCvars[ Hs_Kill_Health ] = register_cvar( "vp_headshot_kill_hp", "15" );
	g_iTotalCvars[ Hs_Kill_Armor ] = register_cvar( "vp_headshot_kill_armor", "15" );
	g_iTotalCvars[ He_Kill_Health ] = register_cvar( "vp_hegrenade_kill_hp", "20" );
	g_iTotalCvars[ He_Kill_Armor ] = register_cvar( "vp_hegrenade_kill_armor", "20" );
	g_iTotalCvars[ Knife_Kill_Health ] = register_cvar( "vp_knife_kill_hp", "30" );
	g_iTotalCvars[ Knife_Kill_Armor ] = register_cvar( "vp_knife_kill_hp", "30" );
}

public OnPlayerKilled( )
{
	new szWeapon[ 16 ], iAttacker = read_data( 1 ), iVictim = read_data( 2 ), iHeadShot = read_data( 3 );
	read_data( 4, szWeapon, charsmax( szWeapon ) );
	
	if( iAttacker == iVictim || ! is_user_connected( iAttacker ) || ! is_user_connected( iVictim ) && ! is_user_vip( iAttacker ) )
		return;
	
	new iHP, iArmor
	
	if( equal( szWeapon, "hegrenade" ) )
	{
		iHP = get_pcvar_num( g_iTotalCvars[ He_Kill_Health ] );
		iArmor = get_pcvar_num( g_iTotalCvars[ He_Kill_Armor ] );
	}
	else if( equal( szWeapon, "knife" ) )
	{
		iHP = get_pcvar_num( g_iTotalCvars[ Knife_Kill_Health ] );
		iArmor = get_pcvar_num( g_iTotalCvars[ Knife_Kill_Armor ] );
	}
	else if( iHeadShot )
	{
		iHP = get_pcvar_num( g_iTotalCvars[ Hs_Kill_Health ] );
		iArmor = get_pcvar_num( g_iTotalCvars[ Hs_Kill_Armor ] );
	}
	else
	{
		iHP = get_pcvar_num( g_iTotalCvars[ Kill_Health ] );
		iArmor = get_pcvar_num( g_iTotalCvars[ Kill_Armor ] );
	}
	
	if( get_pcvar_num( g_iTotalCvars[ He_Kill_Health ] ) || get_pcvar_num( g_iTotalCvars[ Hs_Kill_Health ] )
	|| get_pcvar_num( g_iTotalCvars[ Knife_Kill_Health ] ) || get_pcvar_num( g_iTotalCvars[ Kill_Health ] ) )
	{
		set_pev( iAttacker, pev_health, float( pev( iAttacker, pev_health ) + iHP ) );
		client_print( iAttacker, print_chat, "You got %i hp", iHP );
	}
	
	if( get_pcvar_num( g_iTotalCvars[ He_Kill_Armor ] ) || get_pcvar_num( g_iTotalCvars[ He_Kill_Armor ] )
	|| get_pcvar_num( g_iTotalCvars[ Knife_Kill_Armor ] ) || get_pcvar_num( g_iTotalCvars[ Kill_Armor ] ) )
	{
		set_pev( iAttacker, pev_armorvalue, float( pev( iAttacker, pev_armorvalue ) + iArmor ) );
		client_print( iAttacker, print_chat, "You got %i armor", iArmor );
	}
}

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>
#include <vip>

new g_cMaxSpeed

public plugin_init( ) 
{
	register_plugin( "VIP: Speed", "1.0.0", "Supremache" )
	
	g_cMaxSpeed = register_cvar( "vp_max_speed", "400" );
	
	RegisterHam( Ham_Item_PreFrame, "player", "OnPlayerResetMaxSpeed", 1 );
}

public OnPlayerResetMaxSpeed( id )
{
	if( is_user_alive( id ) && is_user_vip( id ) )
	{
		set_pev( id, pev_maxspeed, get_pcvar_float( g_cMaxSpeed ) );
	}
}

How to use: Go to addons\amxmodx\configs and create config file with this name CustomModels.ini.
How to create a model: "Model Name" "Model Flags" "Model Team" for example "vip_model" "abcde" "1"

#include <amxmodx>
#include <hamsandwich>
#include <cstrike>
#include <amxmisc>
#include <vip>

new const g_szModelFile[ ] = "CustomModels.ini";

enum _:ModelData
{ 
	Model_Name[ 64 ],
	Model_Flag[ 32 ],
	CsTeams:Model_Team
}

new Array:g_aModels, eModel[ ModelData ]

public plugin_init( ) 
{
	register_plugin( "VIP: Custom Models", "1.0.2", "Supremache" );
	RegisterHam( Ham_Spawn, "player", "CBasePlayer_Spawn", 1 )
    
	if( ArraySize( g_aModels ) )
	{
		server_print( "[Custom Models] Loaded %d models", ArraySize( g_aModels ) )
	}
}

public plugin_precache() 
{
	g_aModels = ArrayCreate( ModelData );
	ReadFile( );
}
    
public CBasePlayer_Spawn( id )
{
	if( is_user_alive( id ) )
	{
		for( new CsTeams:iTeam = cs_get_user_team( id ), i; i < ArraySize( g_aModels ); i++ )
		{
			ArrayGetArray( g_aModels, i, eModel )
			
			if( ( !eModel[ Model_Team ] || iTeam == eModel[ Model_Team ] ) && has_all_vip_flags( id , eModel[ Model_Flag ] ) )
			{
				cs_set_user_model( id, eModel[ Model_Name ] )
				break;
			}
			else cs_reset_user_model( id );
		}
	}
}

ReadFile( )
{
	new g_szFile[ 128 ], g_szConfigs[ 64 ];
	get_configsdir( g_szConfigs, charsmax( g_szConfigs ) )
	formatex( g_szFile, charsmax( g_szFile ), "%s/%s", g_szConfigs, g_szModelFile )
    
	new iFile = fopen( g_szFile, "rt" );
    
	if( iFile )
	{
		new szData[ 512 ], szModel[ 64 ], szTeam[ 32 ];
        
		while( fgets( iFile, szData, charsmax( szData ) ) )
		{    
			trim( szData );
            
			switch( szData[ 0 ] )
			{
				case EOS, ';',  '#', '/': continue;

				default:
				{
					eModel[ Model_Flag ][ 0 ] = EOS;
					szTeam[ 0 ] = EOS;
                    
					parse ( szData, szModel, charsmax( szModel ), eModel[ Model_Flag ], charsmax( eModel[ Model_Flag ] ), szTeam, charsmax( szTeam ) )
                    
					trim( szModel ); trim( szTeam ); trim( eModel[ Model_Flag ] );

					precache_player_model( szModel )
					copy( eModel[ Model_Name ], charsmax( eModel[ Model_Name ] ), szModel );
					
					eModel[ Model_Team ] = CsTeams:clamp( str_to_num( szTeam ), _:CS_TEAM_UNASSIGNED, _:CS_TEAM_SPECTATOR );
					
					ArrayPushArray( g_aModels, eModel );
				}
			}
		}
		fclose( iFile );
	}
	else log_amx( "ERROR: ^"%s^" not found!", g_szFile )
} 

//Credits to OciXCrom
precache_player_model(const szModel[], &id = 0)
{
	new model[128]
	formatex(model, charsmax(model), "models/player/%s/%sT.mdl", szModel, szModel)

	if(file_exists(model))
	{
		id = precache_generic(model)
	}

	static const extension[] = "T.mdl"
	#pragma unused extension
	
	copy(model[strlen(model) - charsmax(extension)], charsmax(model), ".mdl")
    
	return precache_generic(model)
}

https://forums.alliedmods.net/showpo...67&postcount=2
https://forums.alliedmods.net/showpo...5&postcount=15

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>
#include <vip>

#if !defined MAX_PLAYERS
	const MAX_PLAYERS = 32
#endif

#define m_afButtonPressed 246

new g_iJumps[ MAX_PLAYERS + 1 ], g_cMultiJumps

public plugin_init( )
{
	register_plugin( "VIP: Multi Jumps", "1.0.0", "Supremache" )
	
	g_cMultiJumps = register_cvar( "vip_multijumps", "2" );
	
	RegisterHam( Ham_Player_Jump, "player", "OnPlayerJump", 1 );
}

// Credits to ConnorMcLeod
public OnPlayerJump( id )
{
	if( ! is_user_alive( id ) && ! is_user_vip( id ) )
		return HAM_HANDLED;
	
	new iFlags = pev(id, pev_flags)
	
	if( iFlags & FL_WATERJUMP || pev( id, pev_waterlevel ) >= 2 || !( get_pdata_int( id, m_afButtonPressed ) & IN_JUMP ) )
	{
		return HAM_IGNORED;
	}
	
	if ( iFlags & FL_ONGROUND )
	{
		g_iJumps[ id ] = 0;
		return HAM_IGNORED;
	}
	
	if( ++g_iJumps[ id ] < get_pcvar_num( g_cMultiJumps ) )
	{
		new Float:fVelocity[ 3 ]
		pev( id, pev_velocity, fVelocity )
		fVelocity[ 2 ] = 268.328157
		set_pev( id, pev_velocity, fVelocity )
	}
	
	return HAM_IGNORED
}

https://forums.alliedmods.net/showpo...2&postcount=14
https://forums.alliedmods.net/showpo...1&postcount=19

[DJEarthQuake]

Looking forward.

[Napoleon_be]

Meh... I don't know man. Like, really? Another VIP system? It's an honest question though. What made u think this would be a good idea of putting your time and effort into something that's been already made several times?

What makes this so different from all other VIP systems, let alone OciXCrom's VIP system?

[Supremache]

We should make and remake the plugin's those has less options or hard coding or doesn't update.

Originally Posted by Napoleon_be What makes this so different from all other VIP systems, let alone OciXCrom's VIP system?

I focused on make something like AMX-MODX admin system but without module and have full api so i added the impportant things to the plugin like Description and make the code full optimized, Even though i don't know about "OciXCrom's VIP system"

[Napoleon_be]

Not exactly the same, but same idea kinda https://forums.alliedmods.net/showthread.php?t=304480

[Supremache]

Originally Posted by Napoleon_be Not exactly the same, but same idea kinda https://forums.alliedmods.net/showthread.php?t=304480

It's not the same, My plugin has a custom flags, that can let you use it like admin system but without module, you can create flags and assign to each flag some functions etc..

[bigdaddy424]

Interesting idea.
How about the expiration date hour free?
You can set the hour as static 23:59:59 so you only need "MM/DD/YYYY" on the config file. Looks much cleaner IMO

[Natsheh]

IMO this is useless instead of coming out with a new bright idea people release the same retarded stuff.

A tip don't waste your time on something dead and just move on with something new.

[Supremache]

@bigdaddy424, Month/day/year?? Or you meant minute /hour/second, It's calling "free vip hours" it should be by hours and not by minute.

@Natsheh, If this is useless then i why i didn't found server without vip system, the vip system making the player special and making the server owners earning money so i remade it with adds more feature.