[abckrieger]

Hello,

i wanna display the current value of a running timer in the title of a menu.
but i dont know how i can refresh the menu without closing it

my first idea was to set a global handle and redraw the menu somehow in the timer..

thx 4 help

[11530]

It seems you cannot re-set a title once it's been set and displayed, so this is the best I can come up with:

PHP Code:

#include <sourcemod>

#pragma semicolon 1

public OnPluginStart()
{
    RegAdminCmd("sm_menutimer", OnMenuTimer, ADMFLAG_ROOT);
}

public Action:OnMenuTimer(client, args)
{
    if (client == 0)
    {
        return Plugin_Handled;
    }

    ShowMenu(client, 20);
    
    return Plugin_Handled;
}

ShowMenu(const client, const duration)
{
    new Handle:menu = CreateMenu(MenuCallback);
    SetMenuTitle(menu, "Time left: %d", duration);
    AddMenuItem(menu, "0", "Some Value");
    DisplayMenu(menu, client, duration);
    
    new Handle:pack;
    CreateDataTimer(1.0, MenuUpdate, pack);
    WritePackCell(pack, GetClientUserId(client));
    WritePackCell(pack, duration - 1);
}

public MenuCallback(Handle:menu, MenuAction:action, param1, param2)
{
    if (action == MenuAction_Select)
    {
        //Stuff
    }
    else if (action == MenuAction_End)
    {
        CloseHandle(menu);
    }
}

public Action:MenuUpdate(Handle:timer, Handle:pack)
{
    ResetPack(pack);
    new client = GetClientOfUserId(ReadPackCell(pack));
    new duration = ReadPackCell(pack);
    
    if (client > 0 && duration >= 1)
    {
        ShowMenu(client, duration);
    }
} 


[abckrieger]

working perfectly, thx :-)