[HamletEagle]

Let's check each plugin:

api_player_burn:

• You should use real offset names, so instead of m_flPainShock you should put m_flVelocityModifier. Changing the name does not impact on the code, but it helps on readability. Someone who is reading your code can check HLSDK/CSSDK(if it is the case) and understand what this offset is used for.
• Do you mind using orpheu ? Checking if player is in water in PreThink it's a poor way. You can hook PM_CheckWater as post and do what you do in PreThink there. The difference is that this happens at the right moment. Here's what you should do, with explanations(if you don't understand something please tell me):
  
  Spoiler

  
  

  PHP Code:

  #include <amxmodx>
#include <orpheu>
#include <orpheu_stocks>
#include <fakemeta>

new OrpheuStruct:g_ppmove
new OrpheuHook:HandlePM_MoveHook

public plugin_init()
{
    HandlePM_MoveHook = OrpheuRegisterHook(OrpheuGetDLLFunction("pfnPM_Move", "PM_Move"), "OnPM_Move")
    OrpheuRegisterHook(OrpheuGetFunction("PM_CheckWater"), "OnPM_CheckWater", OrpheuHookPost)
}

public OnPM_Move(OrpheuStruct:ppmove)
{
    //saving ppmove structure address, we need this for retrieving members(like player_index) from it later
    g_ppmove = ppmove
    OrpheuUnregisterHook(HandlePM_MoveHook) //remove the hook, we got what we wanted
}

//Function is called to check if player is in water
//For example, from PM_PlayerMove
public OnPM_CheckWater()
{
    new id = OrpheuGetStructMember(g_ppmove, "player_index") + 1 //retrieve the player index
    if(is_user_alive(id))
    {
        if(pev(id, pev_flags) & FL_INWATER)
        {
            extinguish_player(id)
        }
    }
} 

  
  The needed signatures are here:
  
  Spoiler

  
  

  {
  	"name" : "PM_CheckWater",
  	"library" : "mod",
  	"return" :
  	{
  		"type" : "qboolean"
  	},
  	"identifiers" :
  	[
  		{
  			"os" : "windows",
  			"mod" : "cstrike",
  			"value" : [0x81,"*","*","*","*","*",0x53,0x8B,"*","*","*","*","*",0x55,0x33,"*",0x8B,"*","*",0x8B]
  		},
  		{
  			"os" : "linux",
  			"mod" : "cstrike",
  			"value" : "PM_CheckWater"
  		}
  	]
  }

  {
      "name"      : "PM_Move",
      "library"   : "mod",
      "arguments" :
      [
          {
              "type" : "playermove_s *"
          },
          {
              "type" : "qboolean"
          }
      ]
  }

  *both files should be put into addons/amxmodx/configs/orpheu/functions. Create two text files without extension called PM_Move and PM_CheckWater and put the contect of the corresponding function in them.
  
• Don't use natives with style 1, it is considered deprected functionality. Swith to style 0. Remember that when using style 0 you don't have the params in the header, you access them with get_param/get_string/get_array(depending on the param type). Do this in all your plugins.
• In on_player_spawn check if the user is alive before doing something.

api_player_cosmetics:

• if(g_playerHatEntity[id][slot] <= 0 || !pev_valid(g_playerHatEntity[id][slot])) checking only if entity is invalid should be enough.
• Allocating a string is an expensive operation, so this engfunc(EngFunc_AllocString, "info_target") should be cached in a place like init, then use it's value.
• In get_player_cosmetic_model_index check if the entity is valid before retrieving model index.

api_player_invisible:

• #define AUTHOR "FiEctro" are you FiEctro ? If not, give proper credits please.

cs_api_player_spawn:

• Nothing should be static, use new.

cs_api_player_team does not make much sense, remove it and use the natives from cstrike module. Also in hmw_weapons: please remove your useless implementation of give_item/cs_set_weapon_ammo etc and use the natives from the modules. They should be faster. So give_user_weapon -> give_item; set_user_ammo -> cs_set_user_bpammo. Your weapons menu never change during run time, so you can build it only one time in precache, then just show it when the command is used. Remember to change menu_destroy to menu_cancel, because you will need the menu later.

I did not checked all of them, because there is a lot of code. I would prefer to take things step by step. Read what I said and try to modify. You can PM me when you made the changes, so we can continue.

Don't forget, if you don't understand something ask.