[Hedgehog Fog]

Custom Entities API

Description

This API help you create some custom entities for your mod with some presets like models, size, etc.
It's can be used to create gameplay entities, items, props.

Create custom entity on your map

Just create entity with custom classname, which registered in CE API

Create custom entity

PHP Code:

new ceEnt = CE_Create(szClassname, vOrigin);
if (ceEnt) {
    dllfunc(DLLFunc_Spawn, ceEnt);
} 


Remove custom entity correctly

PHP Code:

CE_Remove(ent); 


API

PHP Code:

#define CE_LOG_PREFIX "[CE]"
#define CE_BASE_CLASSNAME "info_target"

enum CEPreset
{
    CEPreset_None = 0,
    CEPreset_Item, // For items
    CEPreset_NPC, // For NPC
    CEPreset_Prop // For static props
};

enum CEFunction
{
    CEFunction_Spawn, // Call when entity spawned
    CEFunction_Kill, // Call when some plugin try to kill entity. return PLUGIN_HANDLED to discard kill.
    CEFunction_Killed, // Call when entity killed
    CEFunction_Remove,    // Call when entity removed
    CEFunction_Picked, // Call when player pick item
    CEFunction_Pickup, // Call when player touch item. Should return PLUGIN_HANDLED if picked.
    CEFunction_KVD // Call when new key value obtained
};
/*
 * Register entity.
 *
 * @param szName            Name of entity.
 * @param modelIndex        Precached model index.
 * @param size                Size of entity.
 * @param offset            Offset of entity origin.
 * @param lifeTime            Life time of entity.
 * @param preset            Preset for entity.
 * @return                    Handler of registered entity.
 */
native CE_Register
(
    const szName[],
    modelIndex = 0,
    const Float:vMins[3] = {-8.0, -8.0, -8.0},
    const Float:vMaxs[3] = {8.0, 8.0, 8.0},
    Float:fLifeTime = 0.0,
    Float:fRespawnTime = 10.0,
    bool:ignoreRounds = false,
    CEPreset:preset = CEPreset_None
);

/*
 * Spawn entity.
 *
 * @param szName            Name of entity.
 * @param vOrigin            Spawn origin.
 * @return                    Entity index.
 */
native CE_Create(const szName[], const Float:vOrigin[3], bool:temp = true);

/*
 * Kill entity.
 *
 * @param ent                Index of entity.
 * @param killer            Index of killer.
 */
native bool:CE_Kill(ent, killer = 0);


/*
 * Gets size of entity.
 *
 * @param szClassname        Classname of entity.
 * @param vSize                Output vector.
 */
native CE_GetSize(const szName[], Float:vMins[3], Float:vMaxs[3]);

/*
 * Gets modelindex of entity.
 *
 * @param szClassname        Classname of entity.
 * @return                    Modelindex of entity
 */
native CE_GetModelIndex(const szName[]);

/*
 * Remove entity correctly.
 *
 * @param ent                Index of entity.
 * @return                    Result true/false
 */
native bool:CE_Remove(ent);

/*
 * Register new hook for entity.
 *
 * @param function            Function handler
 * @param szClassname        Classname of entity
 * @param szCallback        Callback
 */
native CE_RegisterHook(CEFunction:function, const szClassname[], const szCallback[]);

/*
 * Check if entity is associated with current plugin.
 *
 * @param ent                Index of entity.
 * @return                    Result true/false
 */
native CE_CheckAssociation_(ent);

stock bool:CE_CheckAssociation(ent) {
    static bool:notified = false;
    if (!notified) {
        log_amx("%s function ^"CE_CheckAssociation^" is deprecated. Check ^"CE_GetHandlerByEntity^" function.", CE_LOG_PREFIX);
        notified = true;
    }
    
    return CE_CheckAssociation_(ent);
}

native CE_GetHandler(const szClassname[]);
native CE_GetHandlerByEntity(ent); 


CE_SPAWNER

Custom Entity Spawner.

Spawner KVD

• ce_name (string) - Entity to spawn
• delay (float) - Delay before spawn (0.0 - spawn once per round)
• impulse (float) - Max velocity for entity after spawn.

[Hedgehog Fog]

Examples

Super Healthkit

PHP Code:

#pragma semicolon 1

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>

#include <api_custom_entities>

#define ENTITY_NAME "item_super_healthkit"

#define MAX_HEALTH 100.0
#define HEAL_AMOUNT MAX_HEALTH

new g_szSndItemSpawn[] = "fvox/beep.wav";
new g_szSndItemPickup[] = "items/smallmedkit1.wav";
new g_szSndItemDisappeared[] = "fvox/buzz.wav";

new g_ceHandler;

public plugin_precache()
{
    precache_sound(g_szSndItemSpawn);
    precache_sound(g_szSndItemPickup);
    precache_sound(g_szSndItemDisappeared);

    //Register new entity
    g_ceHandler = CE_Register(
        .szName = ENTITY_NAME, //classname
        .modelIndex = precache_model("models/w_medkit.mdl"), //modelindex
        .vMins = Float:{-12.0, -12.0, 0.0}, //min size
        .vMaxs = Float:{12.0, 12.0, 24.0}, //max size
    .fLifeTime = 10.0, //lifetime of entity(0.0 to permanent)
    .fRespawnTime = 25.0, // respawn delay
        .preset = CEPreset_Item //preset for entity
    );
    
    //Register spawn hook.
    CE_RegisterHook(CEFunction_Spawn, ENTITY_NAME, "OnSpawn");

    //Register pickup hook.
    CE_RegisterHook(CEFunction_Pickup, ENTITY_NAME, "OnPickup");

    //Register picked hook
    CE_RegisterHook(CEFunction_Picked, ENTITY_NAME, "OnPicked");

    //Register kill hook.
    CE_RegisterHook(CEFunction_Killed, ENTITY_NAME, "OnKilled");
    
}

public plugin_init()
{
    register_plugin("[Custom Entity] Item Super Health Kit", "1.0.0", "Hedgehog Fog");

    //Register Think Hook for custom entity
    RegisterHam(Ham_Think, CE_BASE_CLASSNAME, "OnThink");
}

public OnSpawn(ent)
{
    //Some effect for item
    set_pev(ent, pev_rendermode, kRenderNormal);
    set_pev(ent, pev_renderfx, kRenderFxGlowShell);
    set_pev(ent, pev_renderamt, 4.0);
    set_pev(ent, pev_rendercolor, {255.0, 255.0, 255.0});
    
    //Emit spawn sound
    emit_sound(ent, CHAN_BODY, g_szSndItemSpawn, VOL_NORM, ATTN_NORM, 0, PITCH_NORM);
}

public OnPickup(ent, id)
{
    //Get player health
    static Float:fHealth;
    pev(id, pev_health, fHealth);
    
    if (fHealth < MAX_HEALTH) {
        //Can be picked
        return PLUGIN_HANDLED;
    }

    //Can not be picked
    return PLUGIN_CONTINUE;
}

public OnPicked(ent, id)
{
    //Get player health
    static Float:fHealth;
    pev(id, pev_health, fHealth);

    //Add health to player
    fHealth += HEAL_AMOUNT;
    if (fHealth > MAX_HEALTH) {
        fHealth = MAX_HEALTH;
    } set_pev(id, pev_health, fHealth);

    //Emit pickup sound
    emit_sound(ent, CHAN_VOICE, g_szSndItemPickup, VOL_NORM, ATTN_NORM, 0, PITCH_NORM);
}

public OnKilled(ent, bool:picked)
{
    if (!picked) {
        //Emit disappear sound
        emit_sound(ent, CHAN_VOICE, g_szSndItemDisappeared, VOL_NORM, ATTN_NORM, 0, PITCH_NORM);
    }
}

public OnThink(ent)
{
    //Check if custom entity is associated with current plugin
  if (g_ceHandler != CE_GetHandlerByEntity(ent)) {
        return;
    }

    //Make something here
} 


[gabuch2]

???? Last time I checked item_medkit existed in (most)all mods. Including CS.

I know that's just an example, but still.

[Hedgehog Fog]

Shattered Heart Lynx
If you interested in more complex examples:

https://forums.alliedmods.net/showthread.php?t=273992

[EFFx]

I like this, but all entities can move/attack players?

[Hedgehog Fog]

EFFx
If you talking about npc preset, it's just a basics setups for npc (private data) like movetype, solidtype, takedamage etc.
If you wanna make something like npc, you need to add hook for think, make first think in spawn event for entity and set pev_nextthink every think event.
In think event you need make some npc logic, like target finding and attack.

[EFFx]

And what you think if you add this on your Custom Entities? Only making entities have no sense for me, whats your opinion about this?

[Hedgehog Fog]

EFFx,
I have no idea what do you need.
It's can be helpful for complex project (Halloween Mod for example).
This allow to you register new entity class and use this class on your map for example.
This allow you to controll entity remove and clear some data, for example arrays, which binded to entity and store in pev_iuser1 as handlers.
It's remove entities automatically in new round.
It's allows you to make temp entities with life time.
It's allows you to hook pickup events, it's can be usefull if you have a lot of item entities, so you don't need to create forward for each item.

[EFFx]

Originally Posted by Hedgehog95 EFFx, It's remove entities automatically in new round.

And if I don't want that? Any cvar?

[Hedgehog Fog]

EFFx

PHP Code:

/*
 * Create entity.
 *
 * @param szName           Name of entity.
 * @param vOrigin          Spawn origin.
 * @param temp             Remove entity in next round if true.
 * @return                 Entity index.
 */
native CE_Create(const szName[], const Float:vOrigin[3], bool:temp = true);