[EDIT] Menu For CT only + CallBack feature

5aloOod · **Author**

Hello Every one !
i want help from you guys to edit this menu for me to make it works only with CT team and add to the first code Callback feature so the menu will be always on screen for CT players
Code:

PHP Code:


			
/* Plugin generated by AMXX-Studio */ 

#include <amxmodx> 
#include <hamsandwich>

public plugin_init() 
{ 
    register_plugin("JailBreak Guards Menu", "1.0", "HUMAN"); 
    register_clcmd("say /menu", "ShowMenu", _, "");
    RegisterHam(Ham_Spawn, "player", "fwHamPlayerSpawnPost", 1)
} 

public ShowMenu(id) 

{ 
    new menu = menu_create("\rJailbreak Guards Menu!", "ModsMenu_Handler"); 

    menu_additem(menu, "\yChoose Your \rGuard Class", "", 0); // case 0 
    menu_additem(menu, "\yBe \rThe Simon", "", 0); // case 1 
    menu_additem(menu, "\yOpen Jail Doors", "", 0); // case 2 
    menu_additem(menu, "\yDays Menu", "", 0); // case 3 
    menu_additem(menu, "\yCountdown Menu", "", 0); // case 4 
    menu_additem(menu, "\yGlow Menu", "", 0); // case 5
    menu_additem(menu, "\yFreeDay Menu", "", 0); // case 6
    menu_additem(menu, "\yBall Menu", "", 0); // case 7
    
    menu_setprop(menu, MPROP_EXIT, MEXIT_ALL); 
    menu_setprop(menu, MPROP_BACKNAME, "\wBack"); 
    menu_setprop(menu, MPROP_NEXTNAME, "\wNext"); 
    menu_setprop(menu, MPROP_EXITNAME, "\wExit"); 
    menu_setprop(menu, MPROP_NOCOLORS, 1); 

    menu_display(id, menu, 0); 

    return PLUGIN_HANDLED; 
} 

public ModsMenu_Handler(id, menu, item) 
{ 
    if(item == MENU_EXIT) 
    { 
        menu_cancel(id); 
        return PLUGIN_HANDLED; 
    } 

    new command[6], name[64], access, callback; 

    menu_item_getinfo(menu, item, access, command, sizeof command - 1, name, sizeof name - 1, callback); 

    switch(item) 
    { 
        case 0: client_cmd(id, "say /class"); 
        case 1: client_cmd(id, "say /simon"); 
        case 2: client_cmd(id, "say /open"); 
        case 3: client_cmd(id, "say /daysmenu"); 
        case 4: client_cmd(id, "say /cd"); 
        case 5: client_cmd(id, "say /glow");
        case 6: client_cmd(id, "say /fd");
        case 7: client_cmd(id, "say /ball");

    } 

    menu_destroy(menu); 

    return PLUGIN_HANDLED; 
}
public fwHamPlayerSpawnPost(id)
{
    ShowMenu(id)
}

Help Please

Thanks for your attention

GinNNy · 07-22-2014 , 17:55 Re: [EDIT] Menu For CT only + CallBack feature

try this NOT TESTED

PHP Code:


			
/* Plugin generated by AMXX-Studio */ 

#include <amxmodx> 
#include <hamsandwich>
#include <cstrike>
public plugin_init() 
{ 
    register_plugin("JailBreak Guards Menu", "1.0", "HUMAN"); 
    register_clcmd("say /menu", "ShowMenu")
    
} 

public ShowMenu(id) 
{
    if(cs_get_user_team(id) != CS_TEAM_CT)
    {
        return PLUGIN_HANDLED;
    }
     
    new menu = menu_create("\rJailbreak Guards Menu!", "ModsMenu_Handler"); 
    
    menu_additem(menu, "\yChoose Your \rGuard Class", "", 0); // case 0 
    menu_additem(menu, "\yBe \rThe Simon", "", 0); // case 1 
    menu_additem(menu, "\yOpen Jail Doors", "", 0); // case 2 
    menu_additem(menu, "\yDays Menu", "", 0); // case 3 
    menu_additem(menu, "\yCountdown Menu", "", 0); // case 4 
    menu_additem(menu, "\yGlow Menu", "", 0); // case 5
    menu_additem(menu, "\yFreeDay Menu", "", 0); // case 6
    menu_additem(menu, "\yBall Menu", "", 0); // case 7
        
        
    menu_display(id, menu, 0); 
    return PLUGIN_HANDLED; 
    
    
} 

public ModsMenu_Handler(id, menu, item) 
{ 
    if(item == MENU_EXIT) 
    { 
        menu_destroy(menu); 
        return PLUGIN_HANDLED; 
    } 
    

    switch(item) 
    { 
        case 0: client_cmd(id, "say /class"); 
        case 1: client_cmd(id, "say /simon"); 
        case 2: client_cmd(id, "say /open"); 
        case 3: client_cmd(id, "say /daysmenu"); 
        case 4: client_cmd(id, "say /cd"); 
        case 5: client_cmd(id, "say /glow");
        case 6: client_cmd(id, "say /fd");
        case 7: client_cmd(id, "say /ball");

    } 

    menu_destroy(menu); 

    return PLUGIN_HANDLED; 
}

Flick3rR · 07-22-2014 , 18:06 Re: [EDIT] Menu For CT only + CallBack feature

And what should this callback feature be? I mean, I didn't got the idea... What do you mean by "always on the screen"?

5aloOod · 07-22-2014 , 19:01 Re: [EDIT] Menu For CT only + CallBack feature

Thanks ginny for your help. Works great

Quote:

Originally Posted by Flick3rR

And what should this callback feature be? I mean, I didn't got the idea... What do you mean by "always on the screen"?

Like when player choose "Days Menu" so another menu will popup, then when the other menu closed i want to this menu come back automatically. so it will be always on

Xalus · *Last edited by Xalus; 07-23-2014 at 06:10.*

So after some testing to detect menu close / exit, didn't workout well..
so anyway, this is the best I can give

PHP Code:


			
#include <amxmodx>
#include <amxmisc>
#include <cstrike>
#include <hamsandwich>

#define PLUGIN "Jailbreak guard system"
#define VERSION "1.0.1"
#define AUTHOR "Xalus"

#define ITEMS_Guardmenu 8

enum _:enumGuardmenu
{
    guardItem[32],
    guardSay[20]
}

new const g_arrayGuardMenu[ITEMS_Guardmenu][enumGuardmenu] =
{
    {"\yChoose Your \rGuard Class", "/class"},
    {"\yBe \rThe Simon", "/simon"},
    {"\yOpen Jail Doors", "/open"},
    {"\yDays Menu", "/daysmenu"},
    {"\yCountdown Menu", "/cd"},
    {"\yGlow Menu", "/glow"},
    {"\yFreeDay Menu", "/fd"},
    {"\yBall Menu", "/ball"}
}

new g_intGuardmenu

public plugin_init() 
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    // Register: Ham
    RegisterHam(Ham_Spawn, "player", "Ham_PlayerSpawn_Post", 1)
    
    // Register: Menu
    static strTemp[100]
    if(!strTemp[0])
    {
        formatex(strTemp, charsmax(strTemp), "\rJailbreak Guards Menu!^n\dVersion: %s", VERSION)
    }
    g_intGuardmenu = menu_create(strTemp, "Handler_Menu_Guard")
    
    for(new i = 0; i < ITEMS_Guardmenu; i++)
    {
        menu_additem(g_intGuardmenu, g_arrayGuardMenu[i][guardItem])
    }
    menu_setprop(g_intGuardmenu, MPROP_EXIT, MEXIT_NEVER)
}
// Public: Ham
public Ham_PlayerSpawn_Post(id)
{
    if(is_user_alive(id))
    {
        if(cs_get_user_team(id) == CS_TEAM_CT)
        {
            menu_display(id, g_intGuardmenu)
        }
        else 
        {
            // Cancel for possible teamchangers?
            menu_cancel(id)
        }
    }
}

// Public: Menu's
public Handler_Menu_Guard(id, menu, item)
{
    if(cs_get_user_team(id) == CS_TEAM_CT)
    {
        if(item != MENU_EXIT)
        {
            client_cmd(id, "say %s", g_arrayGuardMenu[item][guardSay])
            
            menu_display(id, g_intGuardmenu)
        }
        else if(!task_exists(id + 25174))
        {
            set_task(1.0, "Task_Menu_Guard", id + 25174, .flags="b")
        }
    }
}

public Task_Menu_Guard(id)
{
    id -= 25174
    if(is_user_alive(id)
    && cs_get_user_team(id) == CS_TEAM_CT)
    {
        new intInfo[3]
        player_menu_info(id, intInfo[0], intInfo[1], intInfo[2]);
        
        if(intInfo[1] == g_intGuardmenu)
        {
            remove_task(id + 25174)
        }
        else if(intInfo[1] < 1 && intInfo[0] < 1)
        {
            menu_display(id, g_intGuardmenu)
            remove_task(id + 25174)
        }
        return
    }
    remove_task(id + 25174)
}

5aloOod · 07-23-2014 , 01:42 Re: [EDIT] Menu For CT only + CallBack feature

Thanks Xalus for your help. Tested and worked great

5aloOod · *Last edited by 5aloOod; 07-23-2014 at 05:47.*

only one thing the plugin blocks some other menus like default amxmodx menu

Xalus · 07-23-2014 , 06:08 Re: [EDIT] Menu For CT only + CallBack feature

Quote:

Originally Posted by 5aloOod

only one thing the plugin blocks some other menus like default amxmodx menu

Updated post.