[xPaw]

how to do that?

[Dores]

What do you mean? Do you mean getting the aiming origin?
If so, use fakemeta_util's stock:

PHP Code:

stock fm_get_aimorigin(index, Float:origin[3])
{
    new Float:start[3], Float:view_ofs[3];
    pev(index, pev_origin, start);
    pev(index, pev_view_ofs, view_ofs);
    xs_vec_add(start, view_ofs, start);
    
    new Float:dest[3];
    pev(index, pev_v_angle, dest);
    engfunc(EngFunc_MakeVectors, dest);
    global_get(glb_v_forward, dest);
    xs_vec_mul_scalar(dest, 9999.0, dest);
    xs_vec_add(start, dest, dest);
    
    engfunc(EngFunc_TraceLine, start, dest, 0, index, 0);
    get_tr2(0, TR_vecEndPos, origin);
    
    return 1;
} 


If not, please explain exactly what you want.

[xPaw]

yes i want get where player is watching, and in same view(angle) set the entity, i mean entity will rotate like a player, for example how it works with MOVETYPE_FOLLOW.

[Hawk552]

You'd have to get the forward vector. Here's an example:

/* Assume id is passed to this function */
new Float:Origin[3],Float:Angle[3],Float:Forward[3],Float:Result[3]
pev(id,pev_origin,Origin)
pev(id,pev_v_angle,Angle)
        
engfunc(EngFunc_MakeVectors,Angle)
global_get(glb_v_forward,Forward)
        
Result[0] = Origin[0] + Forward[0] * 100
Result[1] = Origin[1] + Forward[1] * 100
/* This will leave it on the same z axis,
    but if you want it to go up and down,
    uncomment the line after and comment
    this one */
Result[2] = Origin[2]
//Result[2] = Origin[2] + Forward[2] * 100

engfunc(EngFunc_SetOrigin,Index,Result)

You can also make it go to the right, up, etc, using glb_v_right and glb_v_up.

[Dores]

Instead of the user's origin, I would suggest using the origin from his eyes:

PHP Code:

#include <amxmodx>
#include <fakemeta_util>

#define VERSION "1.0"

#define HEAD_POSITION    8
#define DESIRED_DISTANCE    100 // Change this to whatever.

new g_entid;

public plugin_init()
{
    register_plugin( "Moving an entity by the aim", VERSION, "Dores" );
    register_forward( FM_PlayerPreThink, "Forward_PreThink" );
    register_clcmd( "say /ent", "Cmd_Create" );
}

public Cmd_Create( id )
{
    new Float:aimorigin[ 3 ];
    fm_get_aim_origin( id, aimorigin );
    
    g_entid = fm_create_entity( "info_target" );
    set_pev( g_entid, pev_classname, "BlaBla" );
    set_pev( g_entid, pev_movetype, MOVETYPE_FOLLOW );
    set_pev( g_entid, pev_owner, id );
    
    // ETC. - Create entity with your likings.
    
    
    return PLUGIN_HANDLED;
}

public Forward_PreThink( id )
{
    if( !is_user_alive( id ) )
        return FMRES_IGNORED;
    
    static Float:start[ 3 ], Float:Forward[ 3 ], Float:end[ 3 ];
    engfunc( EngFunc_GetBonePosition, id, HEAD_POSITION, start );
    pev( id, pev_v_angle, Forward );
    engfunc( EngFunc_MakeVectors, Forward );
    global_get( glb_v_forward, Forward );
    end[ 0 ] = start[ 0 ] + Forward[ 0 ] * DESIRED_DISTANCE;
    end[ 1 ] = start[ 1 ] + Forward[ 1 ] * DESIRED_DISTANCE;
    end[ 2 ] = start[ 2 ]; // Height of the eyes.
    engfunc( EngFunc_SetOrigin, g_entid, end ); // Update the ent's origin.
    
    return FMRES_IGNORED;
} 


[xPaw]

no guys thats not that. i want that entity will be rotating like my player model rotataing
if i'm watching to right, the entity will watch there too.

EDIT:
going try that

PHP Code:

new Float:vAngles[3];

pev(id, pev_angles, vAngles);

//set the angles of the model to be the same as the player
set_pev(model, pev_angles, vAngles); 


[Dores]

You can only do that if the model is an entity.

Maybe try view angles:

PHP Code:

new Float:flAngles[ 3 ] ; pev( id, pev_v_angle, flAngles );
set_pev( model, pev_v_angle, flAngles ); 


[Hawk552]

I think you have to get the player's v_angles then set the entity's angle using that.

[Dores]

Originally Posted by Hawk552 I think you have to get the player's v_angles then set the entity's angle using that.

Sounds reasonable.

[xPaw]

i used that what i posted above, and it worked perfect