[REQ] Creating a /heal menu and plugin

devu4 · **Author**

I need someone to create me a plugin where CTs can type /heal,
this should bring up a menu, which lists the currently alive terrorists
the CT can then pick a terrorist to heal and it should heal them to 100hp and should display a message saying (terrorist) has been healed by (ct).

This is for my Jailbreak server, so if someone can help I would be grateful. Thanks

ANTICHRISTUS · 07-28-2014 , 10:13 Re: [REQ] Creating a /heal menu and plugin

at least search for heal* in titles and for /heal* in posts

devu4 · *Last edited by devu4; 07-28-2014 at 10:33.*

Quote:

Originally Posted by ANTICHRISTUS

at least search for heal* in titles and for /heal* in posts

I have searched and already looked, none of /heal plugins on here does what I want exactly. I want a menu for one and second of all it needs to be a say command /heal not a console command. Next time please read my post before coming out with links to your tutorials.

Flick3rR · *Last edited by Flick3rR; 07-28-2014 at 10:41.*

Wasn't able to test it...

PHP Code:


			
/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <colorchat>
#include <cstrike>
#include <fun>

#define PLUGIN "Heal Menu"
#define VERSION "1.0"
#define AUTHOR "Flicker"

new const Prefix[] = "[JB Heal]"
const PH = PLUGIN_HANDLED
const HEALHP = 100
const DENYACCESS = (1<<31)

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    register_clcmd("say /heal", "cmdHeal")
    register_clcmd("say_team /heal", "cmdHeal")
}

public cmdHeal(id)
{
    new CsTeams:team = cs_get_user_team(id)
    
    if(team != CS_TEAM_CT)
    {
        chat(id, "You have to be^3 CT^1 to use the command^4!")
        return PH
    }
    
    createPlayersMenu(id)
    
    return PH
}


public createPlayersMenu(id)
{
    new players[32], num, target
    get_players(players, num, "eh", "TERRORIST")
    
    new szTargetName[32], szTargetUserID[32], szPlayer[32]
    
    new szHasMaxHP[32]
    formatex(szHasMaxHP, charsmax(szHasMaxHP), "\d -\y [\rHAS %d HP\y]", HEALHP)
    
    new menu = menu_create("Terrorist Players Heal Menu", "handleHealMenu")
    
    for(new i; i < num; i++)
    {
        target = players[i]
        
        get_user_name(target, szTargetName, charsmax(szTargetName))
        
        formatex(szPlayer, charsmax(szPlayer), "%s%s", szTargetName, get_user_health(target) >= HEALHP ? szHasMaxHP : "")
        
        num_to_str(get_user_userid(target), szTargetUserID, charsmax(szTargetUserID))
        
        menu_additem(menu, szTargetName, szTargetUserID, get_user_health(target) == HEALHP ? DENYACCESS : 0)
    }
    
    menu_display(id, menu, 0)
}

public handleHealMenu(id, menu, item)
{
    if(item == MENU_EXIT)
    {
        menu_destroy(menu)
        return PLUGIN_HANDLED
    }
    
    new info[6], data[64], acc, callback
    menu_item_getinfo(menu, item, acc, info,charsmax(info), data, charsmax(data), callback)
    
    new target = find_player("k", str_to_num(info))
    
    new szTargetName[32], szIdName[32]
    get_user_name(target, szTargetName, charsmax(szTargetName))
    get_user_name(id, szIdName, charsmax(szIdName))
    
    if(!is_user_alive(target))
    {
        chat(id, "^3%s^1 has died meanwhile^4!", szTargetName)
        return PH
    }
    
    new CsTeams:IdTeam = cs_get_user_team(id)
    new CsTeams:TargetTeam = cs_get_user_team(target)
    
    if(IdTeam != CS_TEAM_CT)
    {
        chat(id, "Sorry, you are not^3 CT^1 anymore^4!")
        return PH
    }
    
    if(TargetTeam != CS_TEAM_T)
    {
        chat(id, "Sorry,^3 %s^1 is not^3 Terrorist^1 anymore^4!", szTargetName)
        return PH
    }
    
    set_user_health(target, HEALHP)
    
    chat(0, "^3%s^1 has been healed by^3 %s^4!", szTargetName, szIdName)
    
    return PH
}


stock chat(const id, const msg[], any:...)
{
    new text[192]
    vformat(text, charsmax(text), msg, 3)
    ColorChat(id, GREEN, "%s^1 %s", Prefix, text)
}

devu4 · 07-28-2014 , 10:57 Re: [REQ] Creating a /heal menu and plugin

Quote:

Originally Posted by Flick3rR

Wasn't able to test it...

PHP Code:


			
/* Plugin generated by AMXX-Studio */



#include <amxmodx>

#include <colorchat>

#include <cstrike>

#include <fun>



#define PLUGIN "Heal Menu"

#define VERSION "1.0"

#define AUTHOR "Flicker"



new const Prefix[] = "[JB Heal]"

const PH = PLUGIN_HANDLED

const HEALHP = 100

const DENYACCESS = (1<<31)



public plugin_init()

{

    register_plugin(PLUGIN, VERSION, AUTHOR)

    

    register_clcmd("say /heal", "cmdHeal")

    register_clcmd("say_team /heal", "cmdHeal")

}



public cmdHeal(id)

{

    new CsTeams:team = cs_get_user_team(id)

    

    if(team != CS_TEAM_CT)

    {

        chat(id, "You have to be^3 CT^1 to use the command^4!")

        return PH

    }

    

    createPlayersMenu(id)

    

    return PH

}





public createPlayersMenu(id)

{

    new players[32], num, target

    get_players(players, num, "eh", "TERRORIST")

    

    new szTargetName[32], szTargetUserID[32], szPlayer[32]

    

    new szHasMaxHP[32]

    formatex(szHasMaxHP, charsmax(szHasMaxHP), "\d -\y [\rHAS %d HP\y]", HEALHP)

    

    new menu = menu_create("Terrorist Players Heal Menu", "handleHealMenu")

    

    for(new i; i < num; i++)

    {

        target = players[i]

        

        get_user_name(target, szTargetName, charsmax(szTargetName))

        

        formatex(szPlayer, charsmax(szPlayer), "%s%s", szTargetName, get_user_health(target) >= HEALHP ? szHasMaxHP : "")

        

        num_to_str(get_user_userid(target), szTargetUserID, charsmax(szTargetUserID))

        

        menu_additem(menu, szTargetName, szTargetUserID, get_user_health(target) == HEALHP ? DENYACCESS : 0)

    }

    

    menu_display(id, menu, 0)

}



public handleHealMenu(id, menu, item)

{

    if(item == MENU_EXIT)

    {

        menu_destroy(menu)

        return PLUGIN_HANDLED

    }

    

    new info[6], data[64], acc, callback

    menu_item_getinfo(menu, item, acc, info,charsmax(info), data, charsmax(data), callback)

    

    new target = find_player("k", str_to_num(info))

    

    new szTargetName[32], szIdName[32]

    get_user_name(target, szTargetName, charsmax(szTargetName))

    get_user_name(id, szIdName, charsmax(szIdName))

    

    if(!is_user_alive(target))

    {

        chat(id, "^3%s^1 has died meanwhile^4!", szTargetName)

        return PH

    }

    

    new CsTeams:IdTeam = cs_get_user_team(id)

    new CsTeams:TargetTeam = cs_get_user_team(target)

    

    if(IdTeam != CS_TEAM_CT)

    {

        chat(id, "Sorry, you are not^3 CT^1 anymore^4!")

        return PH

    }

    

    if(TargetTeam != CS_TEAM_T)

    {

        chat(id, "Sorry,^3 %s^1 is not^3 Terrorist^1 anymore^4!", szTargetName)

        return PH

    }

    

    set_user_health(target, HEALHP)

    

    chat(0, "^3%s^1 has been healed by^3 %s^4!", szTargetName, szIdName)

    

    return PH

}





stock chat(const id, const msg[], any:...)

{

    new text[192]

    vformat(text, charsmax(text), msg, 3)

    ColorChat(id, GREEN, "%s^1 %s", Prefix, text)

}

Thanks Great work. Works Perfectly!!