[ElooKoN]

Hello,

I'm wondering how it is possible to count the length of an string with multi-characters in mind?

If I count the length of "Apple" it will result in 5 but when I count "Äpfel" the result will be 6 (because of the multi-byte "Ä").

Anyone has a solution for this problem?

Sincerely,
Lawrence

[Impact123]

This should do just fine.

PHP Code:

stock StrLenMB(const String:str[])
{
    
    new len = strlen(str);
    new count;
    
    for(new i; i < len; i++)
    {
        count += ((str[i] & 0xc0) != 0x80) ? 1 : 0;
    }
    
    
    return count;
} 


The logic was taken from here.

Here is an little bit slower example using the native IsCharMb function.

PHP Code:

stock StrLenMB2(const String:str[])
{
    
    new len = strlen(str);
    new count;
    new bytes;
    
    for(new i; i < len; i++)
    {
        bytes = IsCharMB(str[i]);
        
        if(bytes > 0)
        {
            i += (bytes - 1);
        } 
        
        count ++;
    }
    
    
    return count;
} 


Yours sincerely
Impact

[ElooKoN]

Thanks for your answer

Just tried:

PrintToAll("%d, %d, %d", StrLenMB("Blookoa"), StrLenMB("Blöökoa"), StrLenMB("Blooköa"));

This will result in

7, 6, 7

But

PrintToAll("%d, %d", StrLenMB("Apple"), StrLenMB("Äpfel"));

will (correctly) result in

5, 5

Curious : ))

[Impact123]

I've updated the stock i posted above, it should work now.

Yours sincerely
Impact

[ElooKoN]

Seems to work correctly, thank you!

[htcarnage]

For uneducated readers, can you explain what your code means? Particularly

count += ((str[i] & 0xc0) != 0x80) ? 1 : 0;

this part

[11530]

Variable-width encoding, as the name suggests, may use more than one byte to display a certain symbol. These multi-byte characters will typically consist of a lead byte and any number (up to five I think) of trailing bytes. Without going into too much detail, we can ignore the trailing bytes and only use the single lead byte when calculating the string's length.

So how do we know when we have a trailing byte to ignore? They should always take the form of 10******, i.e. a '10' in the high-order position. To extract whatever bits are in that high order we perform a bit-wise AND with the 11000000 bit-mask (0xc0 in hexadecimal). Once we have those two bits we'll compare it to the high '10' bits (10000000 or 0x80 in hexadecimal) we want to find. If those first two bits are not '10' it is not a trailing byte, so is either a lead byte or a singleton (a standard single-character byte) therefore we can add one to the length of our string so far.

e.g. Take the character Ä (U+00C4). This takes two bytes to encode and in hexadecimal should be:

11000011 10000100

Using the formula we would count the first eight bits (since it is a leading byte) and we wouldn't count the second set of eight which is a trailing byte (we know this because it begins with '10').

Hopefully all of this is correct and makes sense.

[ElooKoN]

+1

[berni]

Note that there is also a native sourcemod function "IsCharMB"

[Impact123]

I added another exampe using the native IsCharMB function, but it may not be perfect.

Yours sincerely
Impact