[CrazY.]

Hello, I'm trying to set a custom sub-model in player view model, more specifically in the knife v_ model. My code it's working, but with a little bug in deploy event. Aparently is there a delay, so if I deploy, only after few seconds the body is changed.

I can share my model if you need it.

#include <amxmodx>
#include <reapi>
#include <hamsandwich>
#include <fakemeta>

public plugin_init()
{
    register_plugin("Cloak Test", "1.0", "Crazy");

    RegisterHam(Ham_Item_Deploy, "weapon_knife", "CKnife_Deploy"),
    
    register_forward(FM_CanSkipPlayer, "CBasePlayer_CanSkip");
}

public CBasePlayer_CanSkip(this)
{
    if (!is_user_alive(this))
        return FMRES_IGNORED;

    if (get_user_weapon(this) != CSW_KNIFE)
        return FMRES_IGNORED;

    forward_return(FMV_CELL, false);
    return FMRES_OVERRIDE;
}

public CKnife_Deploy(this)
{
    set_entvar(this, var_body, 1);
}

[HamletEagle]

What you see is most likely client prediction. For knife it happens only in Deploy.
You have to mess with UpdateClientData to fix it.

[OciXCrom]

Use CurWeapon rather than setting tasks.

[Celena Luna]

Check this one out
https://forums.alliedmods.net/showthread.php?t=305150

[CrazY.]

Thanks for the sharing @Celena Luna, now it's working perfectly.

Spoiler

#include <amxmodx>
#include <reapi>
#include <hamsandwich>
#include <fakemeta>

enum _:eWeaponAnim
{
    WEAPON_IDLE,
    WEAPON_DRAW = 3,
};

public plugin_init()
{
    register_plugin("Cloak Test", "1.0", "Crazy");

    RegisterHam(Ham_Item_Deploy, "weapon_knife", "CKnife_Deploy_Post", 1),

    register_forward(FM_CanSkipPlayer, "CBasePlayer_CanSkip");
    register_forward(FM_UpdateClientData, "CBasePlayer_UpdateData_Post", 1);
}

public CBasePlayer_CanSkip(this)
{
    if (!is_user_alive(this))
        return FMRES_IGNORED;

    if (get_user_weapon(this) != CSW_KNIFE)
        return FMRES_IGNORED;

    forward_return(FMV_CELL, false);
    return FMRES_OVERRIDE;
}

public CBasePlayer_UpdateData_Post(this, iSendWeapons, hClientData)
{
    if (!is_user_alive(this))
        return;

    static pevWeapon, Float:flLastEventCheck, Float:flGameTime;
    
    pevWeapon = get_member(this, m_pActiveItem);

    if (!is_entity(pevWeapon))
        return;

    if (get_member(pevWeapon, m_iId) != WEAPON_KNIFE)
        return;

    flGameTime = get_gametime();
    flLastEventCheck = get_member(pevWeapon, m_flLastEventCheck);

    if (!flLastEventCheck)
    {
        set_cd(hClientData, CD_flNextAttack, 2.0);
        set_cd(hClientData, CD_WeaponAnim, WEAPON_IDLE);
    }
    else if (flLastEventCheck <= flGameTime)
    {
        ExecuteHamB(Ham_CS_Weapon_SendWeaponAnim, pevWeapon, WEAPON_DRAW, false);
        set_member(pevWeapon, m_flLastEventCheck, 0.0);
    }
}

public CKnife_Deploy_Post(this)
{
    set_entvar(this, var_body, 1);
    ExecuteHamB(Ham_CS_Weapon_SendWeaponAnim, this, WEAPON_IDLE, false);
    set_member(this, m_flLastEventCheck, get_gametime() + 0.04);
}

[Ghosted]

Originally Posted by OciXCrom Use CurWeapon rather than setting tasks.

I though he wanted something about Delay.

[Celena Luna]

Sorry for bump this up.
Sometime I got freeze at IDLE ANIM with the first submodel while switching weapon. Just asking if you got the same problem and if you can fix it.

[CrazY.]

Yes I've seen this problem. To fix it I believe you just need to increase the time of m_flLastEventCheck.

// Test with values biggest than 0.04;
set_member(this, m_flLastEventCheck, get_gametime() + 0.04);