[Zpoke]

hello, is this the best way to strip weapons and block buy commands ?

if it's not, please tell me how to do, THANKS !

[Hx7r]

use ham_spawn
..
https://forums.alliedmods.net/showthread.php?t=102611

[unnyquee]

You should include <engine> because the client_kill() forward requires it

[master4life]

Test this

PHP Code:

#include < amxmodx >
#include < fakemeta >
#include < cstrike >
#include < fun >
#include < hamsandwich >

static const g_szBuyCmds[ ][ ] = {
    "usp", "glock", "deagle", "p228", "elites", "fn57", "m3", "xm1014", "mp5", "tmp", "p90", "mac10", "ump45", "ak47", 
    "galil", "famas", "sg552", "m4a1", "aug", "scout", "awp", "g3sg1", "sg550", "m249", "vest", "vesthelm", "flash", "hegren",
    "sgren", "defuser", "nvgs", "shield", "primammo", "secammo", "km45", "9x19mm", "nighthawk", "228compact", "12gauge",
    "autoshotgun", "smg", "mp", "c90", "cv47", "defender", "clarion", "krieg552", "bullpup", "magnum", "d3au1", "krieg550",
    "buyammo1", "buyammo2"
} 

public plugin_init( ) {
    register_plugin( "Strip Weapons & Block Selfkill", "1.0", "master4life" );
    
    register_forward( FM_ClientKill, "FwdClientKill" );
    RegisterHam( Ham_Spawn, "player", "FwdHamSpawnPlayer_Post", 1 );    
    
    for( new i; i < sizeof g_szBuyCmds; i++ )
        register_clcmd( g_szBuyCmds[ i ], "BlockBuyCmd" ) 
}

public BlockBuyCmd( id ) return PLUGIN_HANDLED;

public FwdHamSpawnPlayer_Post( id ) {
    if( is_user_alive( id ) ) {
        strip_user_weapons( id );
        cs_set_user_money( id, 0 );
        give_item( id, "weapon_knife" );
    }
}

public FwdClientKill( id ) {
    client_print( id, print_chat, "You cannot kill yourself at this moment in time!" );
    client_print( id, print_console, "You cannot kill yourself at this moment in time!" );
        
    return FMRES_SUPERCEDE;
} 


[lazarev]

PHP Code:

#include < amxmodx >
#include < engine >
#include < fakemeta >
#include < fun >
#include < hamsandwich >
 
public plugin_init()
{
    register_plugin( "Strip weapons & block buying", "1.0" , "Juice" );
    
    RegisterHam( Ham_Spawn, "player", "HamPlayerSpawn", 1 );
    
    register_forward( FM_ClientKill, "FwdClientKill" );
    
    new iEnt = -1;
    while ( ( iEnt = find_ent_by_class( iEnt, "func_buyzone" ) ) )
                entity_set_int( iEnt, EV_INT_team, 3 );
}

public HamPlayerSpawn( id ) {
    if( is_user_connected( id ) && is_user_alive( id ) )
        strip_user_weapons( id );
}


public FwdClientKill( id ) {
    client_print( id, print_chat, "You can't use kill command!" );
    return FMRES_SUPERCEDE;
} 


[drumzplaya13]

you could just use the no buy zone plugin and find a plugin which strips weapons already.

maybe this plugin will work for you for striping all weapons, it works for me. Stewie created it. I didnt. I just did some research to find it on the forum.

PHP Code:

#include <amxmodx>
#include <hamsandwich>
#include <fun>

public plugin_init()
{
    register_plugin("hello", "1.0", "Stewie!");
    RegisterHam(Ham_Spawn, "player", "player_spawn", 1);
}

public player_spawn(id)
{
    if(is_user_alive(id))
    {
        strip_user_weapons(id);
    }
} 


[lazarev]

drumzplaya13 check my post -.-

[matsi]

If you don't want to block all those commands you could just 'hide' the buyzone entity.

[drumzplaya13]

Originally Posted by lazarev drumzplaya13 check my post -.-

Yes I know, I was just giving him another option.

Originally Posted by matsi If you don't want to block all those commands you could just 'hide' the buyzone entity.

There is a buyzone plugin which you can specify nowhere/specific/everywhere for buyzones.

[matsi]

Originally Posted by drumzplaya13 Yes I know, I was just giving him another option. There is a buyzone plugin which you can specify nowhere/specific/everywhere for buyzones.

The thing with buyzone is that you can't just remove it. If you remove buyzone the game would create buyzone for each spawn automaticly ( correct me if im wrong ). So one thing you can do is that you create new buyzone and set its size.

->

Requires fakemeta

new Float:g_buyzone_min[3] = { -8192.0, -8192.0, -8192.0 }
new Float:g_buyzone_max[3] = { -8191.0, -8191.0, -8191.0 }

public plugin_init()
{
    g_buyzone = engfunc( EngFunc_CreateNamedEntity, engfunc( EngFunc_AllocString, "func_buyzone" ) )
    dllfunc( DLLFunc_Spawn, g_buyzone )
    engfunc( EngFunc_SetSize, g_buyzone, g_buyzone_min, g_buyzone_max )
}

From VEN's Buyzone Range [Everywhere/Nowhere/Default] as you said there is existing plugin.