[BaltaZar_Serbia]

i need auto respawn plugin for ZP 4.3 mod, when player enter the server automatic respawn him in zombie... i have DM in zp.cfg but it is only for players who are allready on server, i need plugin for players who just entered the server

[!Morte]

PHP Code:

// Respawning a player has never been so easy
    ExecuteHamB(Ham_CS_RoundRespawn, id) 


Maybe this can help you.

[BaltaZar_Serbia]

i cant understand what is that?

[H.RED.ZONE]

If he doesn't know how to code you can't help him with that...

Try using this code and compile locally plugin.

Spoiler

PHP Code:

#include <amxmodx> 
#include <zombieplague> 

const Float:AUTORESPAWN_DELAY = 5.0 
const TASK_AUTORESPAWN = 100 
#define ID_AUTORESPAWN (taskid - TASK_AUTORESPAWN) 
new cvar_deathmatch, g_maxplayers 

public plugin_init() 
{ 
    register_plugin("[ZP] Addon: Respawn Player", "0.1", "MeRcyLeZZ") 
    register_clcmd("joinclass","cmd_joinclass"); // new menus 
    register_menucmd(register_menuid("Terrorist_Select",1),511,"cmd_joinclass"); // old menus 
    register_menucmd(register_menuid("CT_Select",1),511,"cmd_joinclass"); // old menus 
    cvar_deathmatch = get_cvar_pointer("zp_deathmatch") 
    g_maxplayers = get_maxplayers() 
} 

// Player selects model 
public cmd_joinclass(id) 
{ 
    if (!get_pcvar_num(cvar_deathmatch)) 
        return; 
     
    set_task(AUTORESPAWN_DELAY, "auto_respawn_player", id+TASK_AUTORESPAWN) 
} 

public client_disconnect(id) 
{ 
    remove_task(id+TASK_AUTORESPAWN) 
} 

public auto_respawn_player(taskid) 
{ 
    // Already alive? 
    if (is_user_alive(ID_AUTORESPAWN)) 
        return; 
     
    // Nemesis/Survivor round overrides 
    if (zp_is_survivor_round()) 
    { 
        zp_respawn_user(ID_AUTORESPAWN, ZP_TEAM_ZOMBIE) 
        return; 
    } 
    if (zp_is_nemesis_round()) 
    { 
        zp_respawn_user(ID_AUTORESPAWN, ZP_TEAM_HUMAN) 
        return; 
    } 
     
    // Respawn as zombie? 
    if (get_pcvar_num(cvar_deathmatch) == 2 || (get_pcvar_num(cvar_deathmatch) == 3 && random_num(0, 1)) || (get_pcvar_num(cvar_deathmatch) == 4 && zp_get_zombie_count() < fnGetAlive()/2)) 
        zp_respawn_user(ID_AUTORESPAWN, ZP_TEAM_ZOMBIE) 
    else 
        zp_respawn_user(ID_AUTORESPAWN, ZP_TEAM_HUMAN) 
} 

// Get Alive -returns alive players number- 
fnGetAlive() 
{ 
    new iAlive, id 
     
    for (id = 1; id <= g_maxplayers; id++) 
    { 
        if (is_user_alive(id)) 
            iAlive++ 
    } 
     
    return iAlive; 
} 


[330812]

http://www.atlant-cs.ru/forum/viewtopic.php?f=14&t=621
Ваш плагин находиться здесь
1.Использует параметр zp_deatmatch На странице 1
2.Не использует параметры zp_deatmatch а использует параметры zombie plague тоесть в раунде выживший будете респаться за зомби, в раунде немезида, за людей находиться на странице 2 Nick name 330812

[330812]

Original

Originally Posted by 330812 http://www.atlant-cs.ru/forum/viewtopic.php?f=14&t=621 Ваш плагин находиться здесь 1.Использует параметр zp_deatmatch На странице 1 2.Не использует параметры zp_deatmatch а использует параметры zombie plague тоесть в раунде выживший будете респаться за зомби, в раунде немезида, за людей находиться на странице 2 Nick name 330812

Или https://cloud.mail.ru/public/VEAt/tU2yVqu47