[wwzw]

Who wants to help me, teach me how to get Cvar String (num, float), And set Cvar String (num, float).
Thank you very much!

[11530]

PHP Code:

    //Get convar as string
    new String:buffer[128];
    GetConVarString(somehandle, buffer, sizeof(buffer));
    
    //Set convar as string
    SetConVarString(somehandle, "some string");

    //Get convar as int
    new value = GetConVarInt(somehandle);

    //Set convar as int (e.g. 100)
    SetConVarInt(somehandle, 100);

    //Get convar as float
    new Float:value2 = GetConVarFloat(somehandle);

    //Set convar as float, (e.g. 100.0)
    SetConVarFloat(somehandle, 100.0);

    //For completion's sake, get convar as boolean
    new bool:value3 = GetConVarBool(somehandle);

    //Set convar as boolean (e.g. true)
    SetConVarBool(somehandle, true); 


[wwzw]

I would like to ask how to obtain "somehandle"?
For example, I want to obtain and modify the "hostname", specifically, how to do it?

I would like to access or modify some Cvar in "core.cfg". For example: the value of the PassInfoVar, how can I do?

Please teach me in detail, the best is the complete code, thank you!

[RedSword]

FindConVar

[wwzw]

Thank's very much for 11530 and RedSword help me.
I think I can:

new Handle: H_PassInfoVar = FindConVar ("PassInfoVar");
new PassInfoVar [64];
GetConVarString (H_PassInfoVar, PassInfoVar, sizeof (PassInfoVar));

SetConVarString (H_PassInfoVar, "_siteuserpassword");

[RedSword]

Originally Posted by wwzw new PassInfoVar [64];

-->

new String:PassInfoVar [64];

(or decl, but devs will slaps your fingers)

[11530]

I didn't think PassInfoVar was a convar.

[wwzw]

Yes ! PassInfoVar is Invalid convar!
But , How can I get "PassInfoVal" value ?

[mcpan313]

Originally Posted by wwzw How can I get "PassInfoVal" value ?

I guess you need this

PHP Code:

/**
 * Get addons/sourcemod/configs/core.cfg "PassInfoVar" value.
 *
 * @param value            Buffer to store the value.
 * @param maxlength        Maximum length of string buffer.
 *
 * @return                True on success, false otherwise.
 */

#include <regex>
stock bool:GetPassInfoVar(String:value[], maxlength)
{
    new Handle:file = OpenFile("addons/sourcemod/configs/core.cfg", "rb");
    if (file == INVALID_HANDLE)
    {
        return false;
    }
    
    static Handle:re;
    if (re == INVALID_HANDLE)
    {
        re = CompileRegex("\\s+\"PassInfoVar\"\\s+\"(\\w+)\"");
    }
    
    decl String:buffer[256];
    while (ReadFileLine(file, buffer, sizeof(buffer)))
    {
        if (MatchRegex(re, buffer) > 0 && GetRegexSubString(re, 1, value, maxlength))
        {
            CloseHandle(file);
            return true;
        }
    }
    
    CloseHandle(file);
    return false;
} 


[wwzw]

Thank you very much!I tested this function is working properly!
But I look at this is to use regular expressions to get content from the text.
Is not the only way we can? SourceMod not the content loaded core.cfg for variables?