[jppmarujo]

Hey there guys.

So, i pick this structure up, and i am trying to edit it, but keep it simple, because i'm learning how to script in Pawn and C, and i want to be able to fully understand the source code and what's the function of every piece.

So, this piece of code is supposed to make teams play 15 rounds (in total : for example CT: 8 and T: 7) and then swap them.

But, what's happening is that the values don't change. So, if i play for the Counter-Terrorist team in the first half, and i win 14 rounds and the Terrorists team only 1, what happens is that when teams swap i am in disavantadge, because the score don't swap to. So, i'm looking in the cstrike func wiki, and can't find a way to swap the scores when teams swap places.

PHP Code:

#include <amxmodx>
#include <cstrike>

new enable, half_rounds, rounds_count

public plugin_init() 
{
    register_plugin("Auto Swap Teams", "0.1", "#Kz.Tw | nobody")
    half_rounds = register_cvar("amx_half_rounds","15")
    enable = register_cvar("swap_teams", "1")
    register_event("HLTV", "event_round_start", "a", "1=0", "2=0")
    register_event("TextMsg", "Event_TextMsg", "a", "2&#Game_C")
}

public event_round_start()
{
    if(get_pcvar_num(enable))
    {
        rounds_count++
        if(rounds_count == get_pcvar_num(half_rounds))
            swap_teams()
    }
}

public Event_TextMsg()
    rounds_count = 0

public swap_teams()
{
    new CT[32],T[32]
    new chCT, chT
    new tround
    
    client_print(0,print_chat,"* [AST] Switching Teams ")
    get_players(CT,chCT,"e","CT")
    get_players(T,chT,"e","TERRORIST")

    for(new i = 0; i < chCT; i++)
    {
        cs_set_user_team(CT[i], CS_TEAM_T)

        client_print(CT[i],print_chat,"* [AST] You're Team is CT now")
    }

    for(new i = 0; i < chT; i++)
    {
        cs_set_user_team(T[i], CS_TEAM_CT)
        
        client_print(T[i], print_chat, "* [AST] You're Team is T now")
    }
} 


What i did was to put in my server.cfg win_limit 16 . So, if i reset rounds when teams swap instead of swaping the scores too, the scores stay stored? Meaning:

I am terrorist and i win the first half: 14 - 1;

When teams are swaped, scores are resetted to : 0 - 0;

When i am in CT (the second half), would it take only two rounds to win?

Sorry if this is confusing, and thanks for your help in advance.
</span></span>

[kotinha]

Don't use get_players() with "e" flag, it is has a bug (I believe it's explained in amxmodx.org), use instead only with flag h (skip HLTV) and in the loop check what's the players team.

To save the scores, I think that there is no function to retrieve team scores. So, you'll have to register TeamScore event and save the score to a global variable. Then you can check each round if a team has reached max wins.

[Xellath]

Originally Posted by kotinha Don't use get_players() with "e" flag, it is has a bug (I believe it's explained in amxmodx.org), use instead only with flag h (skip HLTV) and in the loop check what's the players team.

Note: "e" flag can return incorrect results (for cstrike/czero at least) when not used with the "a" flag. This is because when players change team, get_players() and get_user_team() will return their old team until they spawn again.

get_players with the "e" flag is perfectly fine to use if used with another flag that verifies their status (such as "a" - alive).

An update (of the last code I showed you - in this thread) to suite your current problem:

#include < amxmodx >
#include < cstrike >

// team names
// CS_TEAM_UNASSIGNED
// CS_TEAM_T
// CS_TEAM_CT
// CS_TEAM_SPECTATOR
new const TeamNames[ CsTeams ][ ] =
{
    "",
    "Terrorist",
    "Counter-Terrorist",
    ""
};

// variable holding the current round
new CurrentRound;

// bool whether it's the 15th round or not
new bool:LastRound;

// current team round count
new RoundsWon[ CsTeams ];

// holding get_maxplayers( ) value
new MaxPlayers;

public plugin_init( )
{
    // hook round start
    register_logevent( "LogEvent_RoundStart", 2, "1=Round_Start" );
    
    // hook round win
    register_event( "SendAudio", "Event_SendAudio_TWin", "a", "2&%!MRAD_terwin" );
    register_event( "SendAudio", "Event_SendAudio_CTWin", "a", "2&%!MRAD_ctwin" );
    
    // assign MaxPlayers the value of get_maxplayers( )
    MaxPlayers = get_maxplayers( );
}

public LogEvent_RoundStart( )
{
    // increment round counter
    CurrentRound++;
    
    // check if rounds == 15, if so, set last true (will be handled when round is won by a team)
    if( CurrentRound == 15 )
    {
        LastRound = true;
    }
}

public Event_SendAudio_TWin( )
{
    // increment the team round counter for T team
    RoundsWon[ CS_TEAM_T ]++;
    
    // check if they have 16 rounds in the bag
    CheckWinner( CS_TEAM_T );
    
    // if it's the 15th round, reset the round counter, and swap team scores
    if( LastRound )
    {
        Reset( );
        
        Swap( );
    }
}

public Event_SendAudio_CTWin()
{
    // increment the team round counter for CT team
    RoundsWon[ CS_TEAM_CT ]++;
    
    // check if they have 16 rounds in the bag
    CheckWinner( CS_TEAM_CT );
    
    // if it's the 15th round, reset the round counter, and swap team scores
    if( LastRound )
    {
        Reset( );
        
        Swap( );
    }
}

CheckWinner( CsTeams:Team )
{
    // check if team has won 16 rounds
    if( RoundsWon[ Team ] == 16 )
    {
        client_print( 0, print_chat, "%s team has won 16 rounds now, resetting!", TeamNames[ Team ] );
        
        // reset
        Reset( true );
    }
}

Reset( bool:TeamWon = false )
{
    // check if a teamwon is true (false by default), if so (see comment below)
    if( TeamWon )
    {
        // reset rounds for terrorists and cts
        for( new CsTeams:Team = CS_TEAM_T; Team <= CS_TEAM_CT; Team++ )
        {
            RoundsWon[ Team ] = 0;
        }
    }
    
    // set round counter to 0
    CurrentRound = 0;
    
    // restart round
    server_cmd( "sv_restartround 1" );
    
    // set last round false
    LastRound = false;
}

Swap( )
{
    // iterate through all players
    for( new PlayerIndex = 1; PlayerIndex <= MaxPlayers; PlayerIndex++ )
    {
        // check if connected
        if( is_user_connected( PlayerIndex ) )
        {
            // swap team
            switch( cs_get_user_team( PlayerIndex ) )
            {
                case CS_TEAM_T: cs_set_user_team( PlayerIndex, CS_TEAM_CT );
                case CS_TEAM_CT: cs_set_user_team( PlayerIndex, CS_TEAM_T );
            }
        }
    }
    
    // swap scores
    new TempScore = RoundsWon[ CS_TEAM_T ];
    RoundsWon[ CS_TEAM_T ] = RoundsWon[ CS_TEAM_CT ];
    RoundsWon[ CS_TEAM_CT ] = TempScore;
}

[bibu]

Cool how you did that with your comments Xellath!

[joshknifer]

I agree. That was super helpful!

[jppmarujo]

Xellath,

Working flawlessly this time. Thank you very much, once again!

Sorry to insist in this topic, but i think that you guys understand the difficulties of finding some workarounds when we are new to scripting.

Thanks again, and yes, the job with the comments it's perfect, because it helps me to understand what's the function of everything.

Cheers mate.


P.S. - By the way, is it possible to, just by executing a server command, change the map to the next one registered in the mapcycle? It was suppose to work that way with the mp_winlimit "16", but i don't know why, it's not.

[Xellath]

Saw a minor typo in the Swap() function. Forgot to increment the player index. Fixed.

Glad my comments are helping you guys!

[nikhilgupta345]

@Xellath: That code would work well if there aren't too many people on the server. I'd have some problems with switching everybody's teams when there are 32 people on the server (the server crashes). The only ways I know to fix them are to either delay the team switches (1-8 go 0.1 seconds after change, 9-17 go 0.2 seconds after, 18-24 go 0.3 seconds after, and 24-32 go 0.4 seconds after) OR you can use this module: http://forums.alliedmods.net/showthread.php?t=163555

[Xellath]

Originally Posted by nikhilgupta345 @Xellath: That code would work well if there aren't too many people on the server. I'd have some problems with switching everybody's teams when there are 32 people on the server (the server crashes). The only ways I know to fix them are to either delay the team switches (1-8 go 0.1 seconds after change, 9-17 go 0.2 seconds after, 18-24 go 0.3 seconds after, and 24-32 go 0.4 seconds after) OR you can use this module: http://forums.alliedmods.net/showthread.php?t=163555

Yes of course. Swapping the team of 32 players instantly is problematic. I think I stated that this was just the basic thought behind this concept in the other thread:

Originally Posted by Xellath From your post, I assume that you want it to restart after 15 rounds, but not reset the team score. However, if a team reaches 16 rounds - the team wins - and everything is reset. Below code is just the basic thought behind this to show you how; ...code....

[Xellath]

Nbanow requested a "live" - "warmup" version of the code I posted above - so here it is.

#include < amxmodx >
#include < cstrike >

// team names
// CS_TEAM_UNASSIGNED
// CS_TEAM_T
// CS_TEAM_CT
// CS_TEAM_SPECTATOR
new const TeamNames[ CsTeams ][ ] =
{
    "",
    "Terrorist",
    "Counter-Terrorist",
    ""
};

// variable holding the current round
new CurrentRound;

// bool whether it's the 15th round or not
new bool:LastRound;

// current team round count
new RoundsWon[ CsTeams ];

// holding get_maxplayers( ) value
new MaxPlayers;

public plugin_init( )
{
    register_clcmd( "say /score", "ClientCommand_Score" );
    
    register_clcmd( "live", "ClientCommand_Live" );
    register_clcmd( "warmup", "ClientCommand_Warmup" );
    
    // hook round start
    register_logevent( "LogEvent_RoundStart", 2, "1=Round_Start" );
    
    // hook round win
    register_event( "SendAudio", "Event_SendAudio_TWin", "a", "2&%!MRAD_terwin" );
    register_event( "SendAudio", "Event_SendAudio_CTWin", "a", "2&%!MRAD_ctwin" );

    // assign MaxPlayers the value of get_maxplayers( )
    MaxPlayers = get_maxplayers( );

    state warmup;
}

public ClientCommand_Score( Client ) <warmup>
{
    // print score (in this case warmup doesn't have any scores.. so print a message)
    client_print( Client, print_chat, "Game mode is currently in Warmup mode - no scores available!" );
}

public ClientCommand_Score( Client ) <live>
{
    // print score
    client_print( Client, print_chat, "CT Score: %i T Score: %i", RoundsWon[ CS_TEAM_CT ], RoundsWon[ CS_TEAM_T ] );
}

public ClientCommand_Live( Client )
{
    // switch state to live
    state live;
    
    RoundsWon[ CS_TEAM_CT ] = 0;
    RoundsWon[ CS_TEAM_T ] = 0;
    
    Reset( );
}

public ClientCommand_Warmup( Client )
{
    // switch state to warmup
    state warmup;
    
    Reset( );
}

public LogEvent_RoundStart( ) <warmup>
{
    // print every warmup round
    client_print( 0, print_chat, "Warmup Round", RoundsWon[ CS_TEAM_CT ], RoundsWon[ CS_TEAM_T ] );
}

public LogEvent_RoundStart( ) <live>
{
    // increment round counter
    CurrentRound++;

    client_print( 0, print_chat, "CT Score: %i T Score: %i", RoundsWon[ CS_TEAM_CT ], RoundsWon[ CS_TEAM_T ] );

    // check if rounds == 15, if so, set last true (will be handled when round is won by a team)
    if( CurrentRound == 15 )
    {
        client_print( 0, print_chat, "This is the last round before switching teams!" );
        
        LastRound = true;
    }
}

public Event_SendAudio_TWin( ) <warmup> { }
public Event_SendAudio_TWin( ) <live>
{
    // increment the team round counter for T team
    RoundsWon[ CS_TEAM_T ]++;
    
    // check if they have 16 rounds in the bag
    CheckWinner( CS_TEAM_T );
    
    // if it's the 15th round, reset the round counter, and swap team scores
    if( LastRound )
    {
        Reset( );
        
        Swap( );
    }
}

public Event_SendAudio_CTWin( ) <warmup> { }
public Event_SendAudio_CTWin( ) <live>
{
    // increment the team round counter for CT team
    RoundsWon[ CS_TEAM_CT ]++;
    
    // check if they have 16 rounds in the bag
    CheckWinner( CS_TEAM_CT );
    
    // if it's the 15th round, reset the round counter, and swap team scores
    if( LastRound )
    {
        Reset( );
        
        Swap( );
    }
}

CheckWinner( CsTeams:Team )
{
    // check if team has won 15 rounds
    if( RoundsWon[ Team ] == 15 )
    {
        client_print( 0, print_chat, "%s team has won 15 rounds now - they're only one away from winning!", TeamNames[ Team ] );
    }
    // check if team has won 16 rounds
    else if( RoundsWon[ Team ] == 16 )
    {
        client_print( 0, print_chat, "%s team has won 16 rounds now, resetting!", TeamNames[ Team ] );
        
        // reset
        Reset( true );
    }
}

Reset( bool:TeamWon = false )
{
    // check if a teamwon is true (false by default), if so (see comment below)
    if( TeamWon )
    {
        // reset rounds for terrorists and cts
        for( new CsTeams:Team = CS_TEAM_T; Team <= CS_TEAM_CT; Team++ )
        {
            RoundsWon[ Team ] = 0;
        }
    }
    
    // set round counter to 0
    CurrentRound = 0;
    
    // restart round
    server_cmd( "sv_restartround 1" );
    
    // set last round false
    LastRound = false;
}

Swap( )
{
    // iterate through all players
    for( new PlayerIndex = 1; PlayerIndex <= MaxPlayers; PlayerIndex++ )
    {
        // check if connected
        if( is_user_connected( PlayerIndex ) )
        {
            // swap team
            switch( cs_get_user_team( PlayerIndex ) )
            {
                case CS_TEAM_T: cs_set_user_team( PlayerIndex, CS_TEAM_CT );
                case CS_TEAM_CT: cs_set_user_team( PlayerIndex, CS_TEAM_T );
            }
        }
    }
    
    // swap scores
    new TempScore = RoundsWon[ CS_TEAM_T ];
    RoundsWon[ CS_TEAM_T ] = RoundsWon[ CS_TEAM_CT ];
    RoundsWon[ CS_TEAM_CT ] = TempScore;
}