[Phant]

I have Float coordinates (XYZ) on a map, lying on some physical plane of the map. How can I obtain the direction (vector?) of the plane on which this point is located? For example, if it's a regular flat floor, the direction is strictly vertical (90° upward). Thank you.

[DJEarthQuake]

Always null {0,0,0} since it is not moving.

[Natsheh]

You need to execute a traceline from a point in/to a wall/floor/ceiling/surface and then collect the required data from the tracehandler according to what you need which is TR_vecPlaneNormal

[fysiks]

Originally Posted by DJEarthQuake Always null {0,0,0} since it is not moving.

The question isn't related to velocity.

[Phant]

Originally Posted by Natsheh You need to execute a traceline from a point in/to a wall/floor/ceiling/surface and then collect the required data from the tracehandler according to what you need which is TR_vecPlaneNormal

Thanks for your reply.
I work with cannons (func_tankmortar) on the crossfire map (Half-Life). Specifically, I intercept env_explosion:

At the moment of its call, I can determine that it was produced from the cannon (func_tankmortar), the coordinates, and angles of the cannon (if I'm doing everything correctly). Therefore, having the final coordinates of env_explosion, I can call EngFunc_TraceLine (with subsequent TR_vecPlaneNormal), but this code doesn't work.

    new szClassname[32]
    pev(inflictor, pev_classname, szClassname, 31)
    client_print(0, print_chat, "CLASSNAME: %s", szClassname)

    new Float:originet[3]
    pev(inflictor, pev_origin, originet)
    client_print(0, print_chat, "ORIGIN OF CANNON: %f %f %f", originet[0], originet[1], originet[2])

    new Float:angles[3]
    pev(inflictor, pev_angles, angles)
    client_print(0, print_chat, "ANGLES OF CANNON: %f %f %f", angles[0], angles[1], angles[2])
    
    new Float:NormalVector[3]
    new trace = create_tr2()
    engfunc(EngFunc_TraceLine, originet, angles, IGNORE_MONSTERS, 0, trace)
    get_tr2(trace, TR_vecPlaneNormal, NormalVector)
    free_tr2(trace)
    client_print(0, print_chat, "NORMAL_VEC: %f %f %f", NormalVector[0], NormalVector[1], NormalVector[2])

I must be doing something wrong. There are plenty of examples on the forum, but most of them are related to the player's point of view.

[Natsheh]

Originally Posted by Phant Thanks for your reply. I work with cannons (func_tankmortar) on the crossfire map (Half-Life). Specifically, I intercept env_explosion: At the moment of its call, I can determine that it was produced from the cannon (func_tankmortar), the coordinates, and angles of the cannon (if I'm doing everything correctly). Therefore, having the final coordinates of env_explosion, I can call EngFunc_TraceLine (with subsequent TR_vecPlaneNormal), but this code doesn't work.     new szClassname[32]     pev(inflictor, pev_classname, szClassname, 31)     client_print(0, print_chat, "CLASSNAME: %s", szClassname)     new Float:originet[3]     pev(inflictor, pev_origin, originet)     client_print(0, print_chat, "ORIGIN OF CANNON: %f %f %f", originet[0], originet[1], originet[2])     new Float:angles[3]     pev(inflictor, pev_angles, angles)     client_print(0, print_chat, "ANGLES OF CANNON: %f %f %f", angles[0], angles[1], angles[2])         new Float:NormalVector[3]     new trace = create_tr2()     engfunc(EngFunc_TraceLine, originet, angles, IGNORE_MONSTERS, 0, trace)     get_tr2(trace, TR_vecPlaneNormal, NormalVector)     free_tr2(trace)     client_print(0, print_chat, "NORMAL_VEC: %f %f %f", NormalVector[0], NormalVector[1], NormalVector[2]) I must be doing something wrong. There are plenty of examples on the forum, but most of them are related to the player's point of view.

Indeed you are...

engfunc(EngFunc_TraceLine, originet, angles, IGNORE_MONSTERS, 0, trace)

The 2nd parameter here (angles) should be replaced with the end coords of where the Traceline should go AKA destination coordinates...

The 4th parameter here ( 0 ) should be replaced with the entity to ignore which in your case is inflictor since we don't need the traceline to stop at the begining...

[DJEarthQuake]

Ok when I saw (vector?) that got me. TR_vecPlaneNormal... looks like I need to brush up on my calculus. Never have I seen a need for that. What are you trying to accomplish by intercepting env_explosion? There are plugins that can make one view the course with cords by attaching view all the way to blocking the boom by having the crowbar drawn already as the shell approaches.

[Phant]

Originally Posted by Natsheh Indeed you are... engfunc(EngFunc_TraceLine, originet, angles, IGNORE_MONSTERS, 0, trace) The 2nd parameter here (angles) should be replaced with the end coords of where the Traceline should go AKA destination coordinates... The 4th parameter here ( 0 ) should be replaced with the entity to ignore which in your case is inflictor since we don't need the traceline to stop at the begining...

I made changes to the code, but NORMAL_VEC (NormalVector) are still equal to zero .

#include <amxmodx>
#include <amxmisc>
#include <fakemeta>
#include <hamsandwich>
#include <engine>

#define PLUGIN "Crossfire Cannons"
#define VERSION "1.0"
#define AUTHOR "Phant"

#define MODEL   "models/cindergibs.mdl"
#define TE_BREAKMODEL   108
#define VELOCITY    75
#define VELOCITY_RANDOM 10
#define SIZE    10
#define LIFE    50
#define THROWING_POWER  200

new g_model

public plugin_precache()
{
    g_model = precache_model(MODEL)
}

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
    RegisterHam(Ham_Spawn, "env_explosion", "explosion_spwn", 1)
}

public explosion_spwn(iEnt)
{
    new Float:origin[3]
    pev(iEnt, pev_origin, origin)

    new inflictor = pev(iEnt, pev_owner)
    client_print(0, print_chat, "OWNER: %i", inflictor)

    new szClassname[32]
    pev(inflictor, pev_classname, szClassname, 31)
    client_print(0, print_chat, "CLASSNAME: %s", szClassname)

    new Float:originet[3]
    pev(inflictor, pev_origin, originet)
    client_print(0, print_chat, "ORIGIN OF CANNON: %f %f %f", originet[0], originet[1], originet[2])

    new Float:angles[3]
    pev(inflictor, pev_angles, angles)
    client_print(0, print_chat, "ANGLES OF CANNON: %f %f %f", angles[0], angles[1], angles[2])
    
    new Float:NormalVector[3]
    new trace = create_tr2()
    engfunc(EngFunc_TraceLine, originet, origin, IGNORE_MONSTERS, inflictor, trace)
    get_tr2(trace, TR_vecPlaneNormal, NormalVector)
    client_print(0, print_chat, "NORMAL_VEC: %f %f %f", NormalVector[0], NormalVector[1], NormalVector[2])
    free_tr2(trace)
    
    toss_gibs(origin)
}

public toss_gibs(Float:origin[3])
{
    message_begin(MSG_BROADCAST, SVC_TEMPENTITY)
    write_byte(TE_BREAKMODEL)
    write_coord(floatround(origin[0]))
    write_coord(floatround(origin[1]))
    write_coord(floatround(origin[2]))
    write_coord(SIZE)
    write_coord(SIZE)
    write_coord(SIZE)
    write_coord(random_num(-VELOCITY, VELOCITY))
    write_coord(random_num(-VELOCITY, VELOCITY))
    write_coord(THROWING_POWER)
    write_byte(VELOCITY_RANDOM)
    write_short(g_model)
    write_byte(random_num(8, 16))
    write_byte(LIFE)
    write_byte(0)
    message_end()
}

OWNER: 277
CLASSNAME: func_tankmortar
ORIGIN OF CANNON: -368.000000 -1520.000000 -1360.000000
ANGLES OF CANNON: 21.164882 84.911384 0.000000
NORMAL_VEC: 0.000000 0.000000 0.000000

[DJEarthQuake]

Good luck!

[Natsheh]

There, this should give out the needed results...

Spoiler

PHP Code:

public explosion_spwn(iEnt)
{
    new Float:flvEnd[3];
    pev(iEnt, pev_origin, flvEnd);

    new inflictor = pev(iEnt, pev_owner);
    client_print(0, print_chat, "OWNER: %i", inflictor);

    new szClassname[32];
    pev(inflictor, pev_classname, szClassname, 31);
    client_print(0, print_chat, "CLASSNAME: %s", szClassname);

    new Float:flvStart[3];
    pev(inflictor, pev_origin, flvStart);
    client_print(0, print_chat, "ORIGIN OF CANNON: %f %f %f", flvStart[0], flvStart[1], flvStart[2]);

    new Float:angles[3], Float:flvForward[3];
    pev(inflictor, pev_angles, angles);
    angle_vector(angles, ANGLEVECTOR_FORWARD, flvForward);
    flvEnd[0] += (flvForward[0] * 100.0);
    flvEnd[1] += (flvForward[1] * 100.0);
    flvEnd[2] += (flvForward[2] * 100.0);
    client_print(0, print_chat, "ANGLES OF CANNON: %f %f %f", angles[0], angles[1], angles[2]);
    
    new Float:NormalVector[3];
    new trace = create_tr2();
    engfunc(EngFunc_TraceLine, flvStart, flvEnd, IGNORE_MONSTERS, inflictor, trace);
    get_tr2(trace, TR_vecPlaneNormal, NormalVector);
    client_print(0, print_chat, "NORMAL_VEC: %f %f %f", NormalVector[0], NormalVector[1], NormalVector[2]);
    free_tr2(trace);
    
    new Float:fvGibsOrigin[3];
    pev(iEnt, pev_origin, fvGibsOrigin);
    fvGibsOrigin[0] = fvGibsOrigin[0] + (NormalVector[0] * 10.0);
    fvGibsOrigin[1] = fvGibsOrigin[1] + (NormalVector[1] * 10.0);
    fvGibsOrigin[2] = fvGibsOrigin[2] + (NormalVector[2] * 10.0);
    toss_gibs(fvGibsOrigin);
}