[sasske]

Hello AlliedModders!

First: Sorry for my english :/

I have problems changing the damage of weapon only for one player.

PHP Code:

public FwdTakeDamage(victim, inflictor, attacker, Float:damage, damage_bits)  
{    
    if(victim == attacker || !is_user_alive(victim) || !is_user_alive(attacker)) //Checks for no bugs
        return HAM_IGNORED; 
     
    if(g_PlayerClass[attacker] != 1) //Checks for the player can/can´t use the damage multiplier
        return HAM_IGNORED
    
    SetHamParamFloat( 4 , damage * 3.0  )  //Setting the damage
    return HAM_HANDLED  
} 


PD: I check the event with:

PHP Code:

RegisterHam(Ham_TakeDamage, "player", "FwdTakeDamage", 0) 


The problem is the player with g_PlayerClass = 1 no multiplier the damage, but if a bot/player attack the player with g_PlayerClass = 1, the bot/player multiplier the damage!

My idea is: if player has g_PlayerClass = 1 and attack other player, cause more damage to the other player.

Can help me?

Thanks for all!

[DavidJr]

Try to change:

PHP Code:

if(g_PlayerClass[attacker] != 1) //Checks for the player can/can´t use the damage multiplier 
        return HAM_IGNORED 


PHP Code:

if(g_PlayerClass[attacker] == 1) //Checks for the player can/can´t use the damage multiplier 
        return HAM_SUPERCEDE 


[ConnorMcLeod]

Correct code would be :

Spoiler

PHP Code:

#include < amxmodx >
#include < hamsandwich >

#pragma semicolon 1

#define PLUGIN ""
#define VERSION "0.0.1"

#define cm(%0)    ( sizeof(%0) - 1 )

new g_iMaxPlayers;
#define IsPlayer(%0)    ( 1 <= (%0) <= g_iMaxPlayers )

const DMG_HEGRENADE = 1<<24;

enum
{
    CLASS_NONE = 0,
    CLASS_RANDOM_NAME,
}

const Float:DAMAGE_MULTIPLY = 3.0;

new g_PlayerClass[33];

public plugin_init()
{
    register_plugin( PLUGIN, VERSION, "ConnorMcLeod" );

    RegisterHam(Ham_TraceAttack, "player", "OnCBasePlayer_TraceAttack", false);
    RegisterHam(Ham_TakeDamage, "player", "OnCBasePlayer_TakeDamage", false);

    g_iMaxPlayers = get_maxplayers();

    state Not_Registered;

    new modname[7];
    get_modname(modname, cm(modname));
    if( equal(modname, "czero") )
    {
        register_event("TextMsg", "Event_TextMsg_Game_connected", "a", "1=1", "2=#Game_connected");
    }
}

public Event_TextMsg_Game_connected() <Registered> {}
public Event_TextMsg_Game_connected() <Not_Registered>
{
    new szName[32];
    read_data(3, szName, cm(szName));
    new id = find_player("ai", szName);
    if( id && IsCzBot( id ) )
    {
        HandleCzBotsHamForwards(id);
        state Registered;
    }
}

IsCzBot( id )
{
#if defined Ham_CS_Player_IsBot
    static valid = -1;
    if( valid == -1 )
    {
        valid = IsHamValid( Ham_CS_Player_IsBot );
    }
    if( valid )
    {
        return ExecuteHam(Ham_CS_Player_IsBot, id);
    }
    return ExecuteHam(Ham_Weapon_ExtractClipAmmo, id, 0);
#else
    return ExecuteHam(Ham_Weapon_ExtractClipAmmo, id, 0);
#endif
}

HandleCzBotsHamForwards( id )
{
    RegisterHamFromEntity(Ham_TraceAttack, id, "OnCBasePlayer_TraceAttack", false);
    RegisterHamFromEntity(Ham_TakeDamage, id, "OnCBasePlayer_TakeDamage", false);
}

public client_putinserver(id)
{
    g_PlayerClass[id] = CLASS_NONE;
}

// void CBasePlayer :: TraceAttack( entvars_t *pevAttacker, float flDamage, Vector vecDir, TraceResult *ptr, int bitsDamageType)
public OnCBasePlayer_TraceAttack(id, iAttacker, Float:flDamage, Float:vecDir[3], ptr, bitsDamageType)
{
    if( id != iAttacker && IsPlayer(iAttacker) && g_PlayerClass[iAttacker] == CLASS_RANDOM_NAME )
    {
        SetHamParamFloat(3, flDamage * DAMAGE_MULTIPLY);
        return HAM_HANDLED;
    }
    return HAM_IGNORED;
}

// int CBasePlayer :: TakeDamage( entvars_t *pevInflictor, entvars_t *pevAttacker, float flDamage, int bitsDamageType )
public OnCBasePlayer_TakeDamage( id, iInflictor, iAttacker, Float:flDamage, bitsDamageType ) // return int
{
    if( bitsDamageType & DMG_HEGRENADE && id != iAttacker && IsPlayer(iAttacker) && g_PlayerClass[iAttacker] == CLASS_RANDOM_NAME )
    {
        SetHamParamFloat(3, flDamage * DAMAGE_MULTIPLY);
        return HAM_HANDLED;
    }
    return HAM_IGNORED;
} 


If this is not working, check where you set g_PlayerClass if it is correctly done (consider DavidJr post (not the supercede part since you don't want to block damage), you may have inversed what you wanted to do).

[GuskiS]

Also, ham doesn't work properly with bots.

[sasske]

Originally Posted by GuskiS Also, ham doesn't work properly with bots.

Oh, I testing with bots, Sorry for all problems, and Thanks for all codes!

See you later

[DavidJr]

But you can use Ham Bots API

[ConnorMcLeod]

I've added support for czero bots.

[GuskiS]

Originally Posted by ConnorMcLeod I've added support for czero bots.

Can't this be added into ham automatically? Like, in the newest amxx version?