[rodrigo286]

Is there any way to increase the life of a player to greater than 200, without it be decreasing?

I searched and did not find, I have tried timers but could not.

Thanks.

[pheadxdll]

Use TF2Items or TF2Attributes and apply an attribute such as "hidden maxhealth non buffed" or "max health additive bonus" on one of their weapons or the player.

[keyboard1333]

new currentHealth = GetEntProp(client, Prop_Data, "m_iMaxHealth");
        new newHealth = currentHealth + 200;
        TF2Attrib_SetByName(client, "max health additive bonus", float(newHealth) - currentHealth);
        SetEntProp(client, Prop_Data, "m_iMaxHealth", newHealth);
        SetEntityHealth(client, newHealth);

You can use that to increase their health. If you want to do it on spawn hook post_inventory_application and then call a timer of 0.0.

[Tylerst]

I use SDKHooks OnGetMaxHealth on my server. Haven't had any problems so far.

PHP Code:

#pragma semicolon 1

#include <sdkhooks>

public Plugin:myinfo =
{
    name = "TF2 Set Health",
    author = "Tylerst",
    description = "Set player Base HP",
    version = "1.0.2",
    url = "None"
}

new g_iHealth[MAXPLAYERS+1] = 0;

public OnPluginStart()
{
    RegAdminCmd("sm_sethealth", Command_SetHealth, ADMFLAG_SLAY, "Set Player Health");
}

public OnClientPutInServer(client)
{
    g_iHealth[client] = 0;
    SDKHook(client, SDKHook_GetMaxHealth, OnGetMaxHealth);
}

public Action:OnGetMaxHealth(entity, &maxhealth)
{
    new client = entity;
    if(!IsValidClient(client)) return Plugin_Continue;
    if(!g_iHealth[client]) return Plugin_Continue;
    maxhealth = g_iHealth[client];
    return Plugin_Changed;
}

public Action:Command_SetHealth(client, args)
{
    if(args != 2)
    {
        ReplyToCommand(client, "[SM] Usage: sm_sethealth \"target\" \"amount\"");
        return Plugin_Handled;
    }

    new String:strTarget[MAX_TARGET_LENGTH], String:strHealth[8], iHealth, String:target_name[MAX_TARGET_LENGTH],target_list[MAXPLAYERS], target_count, bool:tn_is_ml;
    GetCmdArg(1, strTarget, sizeof(strTarget));
    if((target_count = ProcessTargetString(strTarget, client, target_list, MAXPLAYERS, COMMAND_FILTER_CONNECTED, target_name, sizeof(target_name), tn_is_ml)) <= 0)
    {
        ReplyToTargetError(client, target_count);
        return Plugin_Handled;
    }

    GetCmdArg(2, strHealth, sizeof(strHealth));
    iHealth = StringToInt(strHealth);
    for(new i=0;i<target_count;i++)
    {
        g_iHealth[target_list[i]] = iHealth;
        SetEntityHealth(client, g_iHealth[client]);
    }

    ShowActivity2(client, "[SM] ","Set health of %s to %i", target_name);    

    return Plugin_Handled;
}

stock bool:IsValidClient(client, bool:bCheckAlive=true)
{
    if(client < 1 || client > MaxClients) return false;
    if(!IsClientInGame(client)) return false;
    if(IsClientSourceTV(client) || IsClientReplay(client)) return false;
    if(bCheckAlive) return IsPlayerAlive(client);
    return true;
} 


[rodrigo286]

Thanks for methods.

SOLVED =)

[Powerlord]

Originally Posted by keyboard1333 new currentHealth = GetEntProp(client, Prop_Data, "m_iMaxHealth"); new newHealth = currentHealth + 200; TF2Attrib_SetByName(client, "max health additive bonus", float(newHealth) - currentHealth); SetEntProp(client, Prop_Data, "m_iMaxHealth", newHealth); SetEntityHealth(client, newHealth); You can use that to increase their health. If you want to do it on spawn hook post_inventory_application and then call a timer of 0.0.

You only need to do the TF2Attrib_SetByName. The game does the rest for you when the item is refreshed (which SetByName does automatically).

The only exception is if you're adjusting weapon max ammo... it won't be fixed the first time.