[micke1101]

Whats the best way of replacing a file with another?

Code example is appreciated

Thanks in advanced!

[johnjg75]

i would assume delete_file() http://www.amxmodx.org/funcwiki.php?go=func&id=89
then write_file() http://www.amxmodx.org/funcwiki.php?go=func&id=88

[Exolent[jNr]]

You can delete the file being replaced, then rename the file that is replacing it.

OR

You can delete the file being replaced, and copy the contents of the replacing file into a new file with the name of the file being replaced.

// method 1
ReplaceFile(const szFileReplacing[], const szFileReplaced[])
{
    delete_file(szFileReplaced);
    
    while( !rename_file(szFileReplacing, szFileReplaced, 1) ) { }
}

// method 2
ReplaceFile(const szFileReplacing[], const szFileReplaced[])
{
    new iFileReplaced = fopen(szFileReplaced, "wt");
    new iFileReplacing = fopen(szFileReplacing, "rt");
    
    static szData[1024];
    while( !feof(iFileReplacing) )
    {
        fgets(iFileReplacing, szData, 1023);
        fputs(iFileReplaced, szData);
    }
    
    fclose(iFileReplaced);
    fclose(iFileReplacing);
}

[micke1101]

Thank you

But im not so ised to this so of course it wont compile and i cant get why (though i will continue search)

PHP Code:

#include <amxmodx>

new motdyear, motdmonth, motdday;

new FileToReplaceWith;

public plugin_init(){
    register_plugin("Date based motd", "0.1", "Micke1101")

    register_cvar("motd_check", "2") //When to check the date 1 = at start 2 = end 3 = end and start
}
public round_start(){
    if(get_cvar_num("motd_check") == 1 || get_cvar_num("motd_check") == 3){
        date(motdyear, motdmonth, motdday)
        if(file_exists("motds/&s%s%s.txt",motdyear, motdmonth,motdday)){
            FileToReplaceWith = "motds/&s%s%s.txt",motdyear ,motdmonth ,motdday;
        } else {
            FileToReplaceWith = "motds/default.txt";
        }
        ReplaceFile();
    }
}
public round_end(get_cvar_num("sv_roundtime")){
    if(get_cvar_num("motd_check") == 2 || get_cvar_num("motd_check") == 3){
        date(motdyear, motdmonth, motdday)
        if(file_exists("motds/&s%s%s.txt",motdyear ,motdmonth ,motdday)){
            FileToReplaceWith = "motds/&s%s%s.txt",motdyear ,motdmonth ,motdday;
        } else {
            FileToReplaceWith = "motds/default.txt";
        }
        ReplaceFile();
    }
}
ReplaceFile(const szFileReplacing[], const szFileReplaced[])
{
    new iFileReplaced = fopen(szFileReplaced, "motd.txt");
    new iFileReplacing = fopen(szFileReplacing, "%s", FileToReplaceWith);

    static szData[1024];
    while( !feof(iFileReplacing) )
    {
        fgets(iFileReplacing, szData, 1023);
        fputs(iFileReplaced, szData);
    }

    fclose(iFileReplaced);
    fclose(iFileReplacing);
} 


[johnjg75]

FileToReplaceWith should be an array.
And you didn't pass any parameters to ReplaceFile(), but it looks like you changed it so just erase the parameters to look like this

PHP Code:

ReplaceFile()
{ 


[micke1101]

I thought it was a array

new FileToReplaceWith

[platzpatrone]

Originally Posted by micke1101 I thought it was a array new FileToReplaceWith

shouldnt it be like this:

new FileToReplaceWith[32]

to be an array ?

[Owyn]

PHP Code:

new FileToReplaceWith[32][32] 


to have a 32 demension array with max length of an item of 32 char

[Exolent[jNr]]

1. Pawn isn't a language that you can easily format variables like that.
You have to call specific functions to format the variable.

2. You should also use pcvars.

3. You could also reduce the redundant code.

4. You never registered the round_start and round_end events.

5. Instead of getting the cvar value twice, only get it once.

6. Don't modify the ReplaceFile() function.

#include <amxmodx>

new FileToReplaceWith[64];

new cvar_check;

public plugin_init(){
    register_plugin("Date based motd", "0.1", "Micke1101")
    
    register_logevent("round_start", 2, "1=Round_Start");
    register_logevent("round_end", 2, "1=Round_End");

    cvar_check = register_cvar("motd_check", "2") //When to check the date 1 = at start 2 = end 3 = end and start
}
public round_start(){
    new check = get_pcvar_num(cvar_check);
    if(check == 1 || check == 3){
        DoMotdFile();
    }
}
public round_end(){
    new check = get_pcvar_num(cvar_check);
    if(check == 2 || check == 3){
        DoMotdFile();
    }
}
DoMotdFile()
{
    new motdyear, motdmonth, motdday;
    date(motdyear, motdmonth, motdday)
    formatex(FileToReplaceWith, 63, "motds/%i%i%i.txt", motdyear, motdmonth, motdday);
    if(!file_exists(FileToReplaceWith)){
        copy(FileToReplaceWith, 63, "motds/default.txt");
    }
    ReplaceFile(FileToReplaceWith, "motd.txt");
}
ReplaceFile(const szFileReplacing[], const szFileReplaced[])
{
    if( !file_exists(szFileReplacing) ) return;
    
    new iFileReplaced = fopen(szFileReplaced, "wt");
    new iFileReplacing = fopen(szFileReplacing, "rt");

    static szData[1024];
    while( !feof(iFileReplacing) )
    {
        fgets(iFileReplacing, szData, 1023);
        fputs(iFileReplaced, szData);
    }

    fclose(iFileReplaced);
    fclose(iFileReplacing);
}