[ot_207]

Originally Posted by joaquimandrade If someone is interested on knowing how to use bit storage for values bigger than 31: PHP Code: save(x) {     holder[x / 32] |= 1 << (x % 32); }   exists(x) {     return holder[x / 32] & 1 << (x % 32); }   remove(x) {     holder[x / 32] &= ~(1 << (x % 32)) }  It's a memory tradeoff.

Nice! I was thinking on adding this in the tutorial.

[joaquimandrade]

Originally Posted by ot_207 Nice! I was thinking on adding this in the tutorial.

You understood its purpose?

[Bugsy]

*Revised, fixed 'Loose Indentation' warnings*

I put a little plugin together just to test it out. Here it is for anyone interested.

PHP Code:

#include <amxmodx>
#include <amxmisc>

#define PLUGIN "> 32 Bit Flag Example"
#define VERSION "1.0"
#define AUTHOR "bugsy"

//Max bit we want to manipulate
#define MAX_BIT    515

//Allocate an array large enough to manipulate our MAX_BITS bit
new iBitsumArray[ ( MAX_BIT / 32 ) + 1 ];

//Macros to manipulate the bit
#define SetBit(%1,%2)       ( %1[%2/32] |= (1 << (%2 % 32)) )
#define ClearBit(%1,%2)    ( %1[%2/32] &= ~(1 << (%2 % 32)) )
#define CheckBit(%1,%2)     ( %1[%2/32] & (1 << (%2 % 32)) )

public plugin_init() 
{
    register_plugin( PLUGIN , VERSION , AUTHOR );
    register_concmd( "test" , "cmdTest" );
}

public cmdTest(id)
{
    //Show max bit we can manipulate
    server_print( "Max Bit = %d" , MAX_BIT );
    
    //Show the size of our bitsum array
    server_print( "Bitsum array size = %d" , sizeof iBitsumArray );
    
    //Check out if our max is ok (no errors)
    if ( !CheckBit( iBitsumArray , MAX_BIT ) ) server_print( "%d bit is not set" , MAX_BIT );
    
    //Check if 512 or 515 are set
    if ( !CheckBit( iBitsumArray , 512 ) ) server_print( "512 bit is not set" );
        
    if ( !CheckBit( iBitsumArray , 515 ) ) server_print( "515 bit is not set" );
    
    //Set 512 and 515
    SetBit( iBitsumArray , 512 );
    SetBit( iBitsumArray , 515 );
    
    //Check them again
    if ( CheckBit( iBitsumArray , 512 ) ) server_print( "512 bit is set" );
    if ( CheckBit( iBitsumArray , 515 ) ) server_print( "515 bit is set" );
    
    //Remove 512 and 515
    ClearBit( iBitsumArray , 512 );
    ClearBit( iBitsumArray , 515 );
    
    //Check again
    if ( !CheckBit( iBitsumArray , 512 ) ) server_print( "512 bit is not set" );
    if ( !CheckBit( iBitsumArray , 515 ) ) server_print( "515 bit is not set" );
} 


[joaquimandrade]

Nice. Connor is also using this storage way in a plugin:

http://forums.alliedmods.net/showthread.php?t=90242

In fact it was him who gave me the idea to do that.

[ot_207]

Originally Posted by joaquimandrade You understood its purpose?

When I did the tutorial I thought about that, I just forgot to post it .

Originally Posted by Bugsy I put a little plugin together just to test it out. Here it is for anyone interested.

Thanks Bugsy!

[Exolent[jNr]]

I found a use for the example on bits being pushed more than 32, and I used it to make my plugin.
This is a really handy tutorial!

[ConnorMcLeod]

Originally Posted by joaquimandrade In fact it was him who gave me the idea to do that.

In fact, you stole my ideas since the begining of the creation of the universe.

[joaquimandrade]

Originally Posted by ConnorMcLeod In fact, you stole my ideas since the begining of the creation of the universe.

traitor

[Damizean]

Actually, since 32 is a power of two value, you can use bit displacements and ands for doing those operations, it's way cheaper than doing divisions and modulos, and this rule always applies to power of two values:

PHP Code:

holder[x >> 5] |= 1 << (x & 31); 


[Bugsy]

Originally Posted by Damizean Actually, since 32 is a power of two value, you can use bit displacements and ands for doing those operations, it's way cheaper than doing divisions and modulos, and this rule always applies to power of two values: PHP Code: holder[x >> 5] |= 1 << (x & 31);

Tested and working, nice find Damizean.

Here are the macros, all tested with my above "> 32 Bit Flag Example" plugin

PHP Code:

#define SetBit(%1,%2)          ( %1[%2>>5] |= (1 << (%2 & 31)) )
#define ClearBit(%1,%2)        ( %1[%2>>5] &= ~(1 << (%2 & 31)) )
#define CheckBit(%1,%2)        ( %1[%2>>5] & (1 << (%2 & 31)) ) 


Max Bit = 515
Bitsum array size = 17
515 bit is not set
512 bit is not set
515 bit is not set
512 bit is set
515 bit is set
512 bit is not set
515 bit is not set