[HeaDbIKBaT]

I was just wondering if there is any way I could have 2 or more zombies in the beginning of the game every time, instead of 1. Is there any way to do it?

[Kachoo!]

Multi Infection Mod ?

[HeaDbIKBaT]

Yeah, but how do I have that every round + still get to have the other modes?

[Kachoo!]

You can edit the zombieplague.cfg

zp_multi_chance 20 // Chance (1 in X)

You can also change this cvar while the server is running ...

The default number is 20, if you change it to 1. Every round will be that mode ... You can use that, and when you want to play another mode, use the console or the admin menu ... Or try changing it to 3 or 4 Chance maybe ..

[Stixsmaster]

Id change the multi round to 1 and the others to 2...

---Stixsmaster

[MeRcyLeZZ]

Originally Posted by HeaDbIKBaT I was just wondering if there is any way I could have 2 or more zombies in the beginning of the game every time, instead of 1. How do I have that every round + still get to have the other modes?

In that case, you can use a subplugin like this:

CVar: zp_additional_zombies <0 to 30>

#include <amxmodx>
#include <zombieplague>

new g_maxplayers, cvar_additionalzombies

public plugin_init()
{
    register_plugin("[ZP] Multi Infection", "0.1", "MeRcyLeZZ")
    
    g_maxplayers = get_maxplayers()
    
    // How many additional players should be infected at start
    cvar_additionalzombies = register_cvar("zp_additional_zombies", "1")
}

public zp_round_started(gamemode)
{
    // Normal infection modes only
    if (gamemode != MODE_INFECTION)
        return;
    
    // Figure out how many players should we infect (one human should be left alive!)
    new id, iZombies, iMaxZombies = min(get_pcvar_num(cvar_additionalzombies), fnGetAlive()-2)
    
    // Randomly turn iMaxZombies players into zombies
    while (iZombies < iMaxZombies)
    {
        // Keep looping through all players
        if (++id > g_maxplayers) id = 1
        
        // Dead or already a zombie
        if (!is_user_alive(id) || zp_get_user_zombie(id))
            continue;
        
        // Random chance
        if (random_num(0, 10) == 0)
        {
            // Turn into a zombie
            zp_infect_user(id)
            iZombies++
        }
    }
}

// Returns alive players count
fnGetAlive()
{
    new iAlive, id
    
    for (id = 1; id <= g_maxplayers; id++)
    {
        if (is_user_alive(id))
            iAlive++
    }
    
    return iAlive;
}

[PsYChOPaTiQuE]

how put this mod in the admin menu?

[InDepth]

Oh and how do i make it so that when the 2 people get infected, instead of "Blah is the first zombie!", I set that to "Blah and Blah2 are the first zombies!"?

[HeaDbIKBaT]

MeRcyLeZZ
Thanks man ) I appreciate everything you done, thanks for help. I'll try it

[zDemon]

MeRcyLeZZ, I owe you a beer. Thank you very much (: