[S.W.A.T Slix]

I've look everywhere for this plugin ( if it exists) It's a plugin when the Round begins and you can Pick a custom sound you can put for the T and CT's instead of saying "Prepare to Fight"

[PoSiTiOn Of PoWeR]

roundSound
"Prepare to fight Msg"
->

PHP Code:

#include <amxmodx>
#include <amxmisc>

public plugin_init()
{
   register_plugin("Prepare to fight MSG","0.1","P.Of.Pw")
   register_logevent("roundstart", 2, "1=Round_Start");
}
public roundstart() {

   set_hudmessage(255, 0, 0, 0.35, 0.08, 0, 6.0, 12.0)
   show_hudmessage(0, "Prepare to fight !!!!")
   
   return PLUGIN_HANDLED
} 


[Fry!]

But that round sound play sound when one of teams win . Would it work on round start ?

[PoSiTiOn Of PoWeR]

I mean, when the round begins to hear a sound?

PHP Code:

#include <amxmodx>
#include <amxmisc>

public plugin_init()
{
   register_plugin("Prepare to fight MSG","0.1","P.Of.Pw")
   register_logevent("roundstart", 2, "1=Round_Start");
}
public roundstart() {

   client_cmd(0,"spk misc/MySound")
   
   return PLUGIN_HANDLED
}

public plugin_precache() 
{
  precache_sound("misc/MySound.wav")
 
  return PLUGIN_CONTINUE
} 


Sorry for bad english

[atomen]

You ain't replacing the old sound... I don't know the sound file
name on the default file. But it should be like this :

PHP Code:

#include <amxmodx>
#include <amxmisc>
#include <fakemeta>

#define gPLUGIN "PTF Block"
#define gVERSION "1.0"
#define gAUTHOR "[A]tomen"

new g_soundlist[]    =    "The default sound here"
new g_replace[]        =    "Your Sound Here"

public plugin_precache() precache_sound(g_replace)

public plugin_init()
{
    register_plugin(gPLUGIN, gVERSION, gAUTHOR)
    register_forward(FM_EmitSound, "block_sound")
}

public block_sound(entity, channel, const sound[])
{
    if (equali(sound, g_soundlist))
    {
        emit_sound(0, CHAN_STATIC, g_replace, 0.6, ATTN_NORM, 0, PITCH_NORM)
        return FMRES_SUPERCEDE
    }

    else
        return FMRES_IGNORED
} 


[Arkshine]

'prepare to fight' sound/text is provided into miscstats plugin. If he want another sound, he has just to edit the miscstats plugin. There is nothing to do with the forward 'EmitSound'... -_-

[atomen]

Thought it was cs default sound, ain't playing it nowadays.

[S.W.A.T Slix]

At the start of the round, I want a diff sounds for the T's and diff one for the CT's. I looked through the codes I dont its in there.

Edit:

Is this the code? I found this in miscstats.sma

PHP Code:

}

public eNewRound()
{
    if (read_data(1) == floatround(get_cvar_float("mp_roundtime") * 60.0,floatround_floor))
    {
        g_firstBlood = 1
        g_C4Timer = 0
        ++g_roundCount
        
        if (RoundCounter)
        {
            set_hudmessage(200, 0, 0, -1.0, 0.30, 0, 6.0, 6.0, 0.5, 0.15, -1)
            ShowSyncHudMsg(0, g_announce_sync, "%L", LANG_PLAYER, "PREPARE_FIGHT", g_roundCount)
        }
        
        if (RoundCounterSound)
            play_sound("misc/prepare")
        
        if (KillingStreak)
        {
            new appl[32], ppl, i
            get_players(appl, ppl, "ac")
            
            for (new a = 0; a < ppl; ++a)
            {
                i = appl[a]
                
                if (g_streakKills[i][0] >= 2)
                    client_print(i, print_chat, "* %L", i, "KILLED_ROW", g_streakKills[i][0])
                else if (g_streakKills[i][1] >= 2)
                    client_print(i, print_chat, "* %L", i, "DIED_ROUNDS", g_streakKills[i][1])
            }
        }
    }
}

public eRestart() 


If yes, how do I make it so that when the round starts, the T and Ct's have diff sounds. Cause I want when round starts for CT, it will say "Assault" when round starts for T's it says "Defense" I have the sounds files.

[S.W.A.T Slix]

Originally Posted by PoSiTiOn Of PoWeR I mean, when the round begins to hear a sound? PHP Code: #include <amxmodx> #include <amxmisc> public plugin_init() {    register_plugin("Prepare to fight MSG","0.1","P.Of.Pw")    register_logevent("roundstart", 2, "1=Round_Start"); } public roundstart() {    client_cmd(0,"spk misc/MySound")        return PLUGIN_HANDLED } public plugin_precache()  {   precache_sound("misc/MySound.wav")     return PLUGIN_CONTINUE }  Sorry for bad english

Is it possible that you can have different Round sounds for the two teams?
Example:
CT round sound says: "Assault"
T round sound says: "Defense"

[fxfighter]

This might work it compiles at least.

PHP Code:

#include <amxmodx>
#include <amxmisc>

new max_players

#define Twin    "misc/MyTSound.wav"
#define CTwin    "misc/MyCTSound.wav"


public plugin_init()
{
   register_plugin("Prepare to fight MSG","0.1","Fx")
   register_logevent("roundstart", 2, "1=Round_Start")
   max_players= get_maxplayers()
}
public roundstart()
{
    new team
    for(new i=1;i<=max_players;i++)
        if(is_user_connected(i))
        {
            team = get_user_team(i)
            if(team == 1)client_cmd(i,"spk %s",Twin)
            else if(team == 2)client_cmd(i,"spk %s",CTwin)
            
        }
        
    set_hudmessage(255, 0, 0, 0.35, 0.08, 0, 6.0, 12.0)
    show_hudmessage(0, "Prepare to fight !!!!")
    return PLUGIN_HANDLED
}

public plugin_precache() 
{
  precache_sound(Twin)
  precache_sound(CTwin)
 
  return PLUGIN_CONTINUE
}