[SpaWn2KiLl]

Hello, I'm searching for a plugin that only allows to spectate the CT team...

Dead CT: Spectate CT players in 1st person view mode only
Dead T: Spectate CT players in 1st person view mode only
Spectatores: Spectate CT players in 1st person view mode only

I searched a lot but i din't find the solution...

Thanks

[SpeeDeeR]

I have been working on this for some time now. Great timing.

Use cvar spec_force_team X where X is the team ( 1 - T, 2 - CT )

#include <amxmodx>
#include <orpheu>
#include <fakemeta>
#include <engine>

#define PLUGIN "Force Spectate"
#define VERSION "1.1"
#define AUTHOR "SpeeDeeR"

#define get_team(%0)    ( get_pdata_int( %0, m_iTeam ) )

#define MAXPLAYERS  32

const m_iTeam = 114; 

new pcvar_force_team;

new OrpheuFunction: Observer_IsValidTarget;

public plugin_init() 
{
    register_plugin( PLUGIN, VERSION, AUTHOR );
    
    Observer_IsValidTarget = OrpheuGetFunction( "Observer_IsValidTarget", "CBasePlayer" ); 
    
    OrpheuRegisterHook( Observer_IsValidTarget, "Observer_IsValidTarget_Pre", OrpheuHookPre  ); 
    
    pcvar_force_team = register_cvar("spec_force_team", "2");
}

public  Observer_IsValidTarget_Pre( const this, const iTarget, const bool:bOnlyTeam ) 
{
    if( is_user_alive( iTarget ) )
    {
        static ppcvar; ppcvar = get_pcvar_num( pcvar_force_team  ); 
        
        if( get_team( iTarget ) != ppcvar )
        {
            static id; id = iTarget;
            while ( ( id = find_ent_by_class( id, "player" ) ) != iTarget ) 
            {
                if(get_team( id ) != ppcvar ) 
                    continue;
                
                OrpheuSetParam( 2, id );
                
                break;
            }
        }
    }
}

[SpaWn2KiLl]

I'll test it later, thank you

EDIT: It's working! Thanks very much!!


You can lock this thread

[YoUrEnD]

Can please someone port this to Sourcemod and add the ability for admins to spec everything?

[WaLkMaN]

I've rewritten the logic with reapi.

#include <amxmodx>
#include <reapi>

#define PLUGIN "Force Spectate"
#define VERSION "1.1"
#define AUTHOR "SpeeDeeR"

new pcvar_force_team;

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR);
    
    RegisterHookChain(RG_CBasePlayer_Observer_IsValidTarget, "Observer_IsValidTarget_Pre", .post = false);
    
    pcvar_force_team = register_cvar("spec_force_team", "2");
}

public Observer_IsValidTarget_Pre(const this, const iTarget, const bool:bOnlyTeam)
{
    if (is_user_alive(iTarget))
    {
        static ppcvar; ppcvar = get_pcvar_num(pcvar_force_team);
        
        if (get_member(iTarget, m_iTeam) != ppcvar)
        {
            static id; id = iTarget;
            while ((id = rg_find_ent_by_class(id, "player")) != iTarget)
            {
                if (!is_user_alive(id) || get_member(id, m_iTeam) != ppcvar)
                    continue;
                
                SetHookChainArg(2, ATYPE_INTEGER, id);
                
                break;
            }
        }
    }
}

Another implementation: https://forums.alliedmods.net/showpo...95&postcount=8