[wEight]

PHP Code:

#include <amxmodx>
#include <amxmisc>
#include <fun>

#define PLUGIN "nctest"
#define VERSION "1.0"
#define AUTHOR "wEight"

public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    register_clcmd("say /nc", "cmd_nc")
}

public cmd_nc(id)
{
    if(is_user_alive(id))
    {
        if(get_user_noclip(id) == 0)
        {
            set_user_noclip(id, 1)
            client_print(id, print_chat, "Noclip On")
            set_task(5.0, "expire_nc")
        }
        else
        {
            client_print(id, print_chat, "Already have noclip")
        }
    }
    return PLUGIN_HANDLED
}

public expire_nc(id)
{
    if(is_user_alive(id))
    {
        set_user_noclip(id, 0)
        client_print(id, print_chat, "Noclip Expired")
    }
    return PLUGIN_HANDLED
} 


expire_nc(id) wont work, when use set_user_noclip and client_print only without if(is_user_alive(id)) it gives me an error for set_user_noclip.

Translation: When i get noclip, it passes 5 seconds and i still have noclip, It's supposed to expire.

[Bugsy]

When you call set_task(), you are not passing the players id so expire_nc() does not know which player to remove noclip from. You also need to remove the task if a player disconnects within the 5 seconds after set_task() is called for that player.

PHP Code:

#include <amxmodx>
#include <amxmisc>
#include <fun>

#define PLUGIN "nctest"
#define VERSION "1.0"
#define AUTHOR "wEight"

const TASK_NC = 32143;

public plugin_init() 
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    register_clcmd("say /nc", "cmd_nc")
}

public client_disconnect( id )
{
    remove_task( id + TASK_NC );
}

public cmd_nc(id)
{
    if(is_user_alive(id))
    {
        if(get_user_noclip(id) == 0)
        {
            set_user_noclip(id, 1)
            client_print(id, print_chat, "Noclip On")
            set_task(5.0, "expire_nc" , TASK_NC + id )
        }
        else
        {
            client_print(id, print_chat, "Already have noclip")
        }
    }
    return PLUGIN_HANDLED
}

public expire_nc(id)
{
    id -= TASK_NC;
    
    if(is_user_alive(id))
    {
        set_user_noclip(id, 0)
        client_print(id, print_chat, "Noclip Expired")
    }
    return PLUGIN_HANDLED
} 


[wEight]

Thanks, i might understand this code now, but

PHP Code:

const TASK_NC = 32143; 


Is it supposed to be exactly 32143 or can it be any number?

[Bugsy]

Originally Posted by wEight Thanks, i might understand this code now, but PHP Code: const TASK_NC = 32143;  Is it supposed to be exactly 32143 or can it be any number?

32143 is just a random number.