[Fabregas21]

Hi. I need plugin, which will be show on say, who for example destroyed func_breakable or used func_button.

[HamletEagle]

How do you want it ? When someone destroy a func_breakable ent it will show a message like "someone destroyed a func_breakable ent" ?

A direct way would be to hook with orpheu/okapi CBreakable:: Die() and to do stuffs there. For the func_button you can use Ham_Use

[Fabregas21]

Yes, as you wrote, I want to showed information about this in say.
How to look like the code that describes this feature?

[Fabregas21]

Bump. Can anyone help me ?

UP: Wtf ? I waited 14 days and I can bump, so... (Last post 4.11.2014r)

[Jhob94]

Originally Posted by Fabregas21 UP: Wtf ? I waited 14 days and I can bump, so... (Last post 4.11.2014r)

So? Rules are for everyone, as you waited, many also had to wait...

[HamletEagle]

Test it:

#include <amxmodx>
#include <hamsandwich>
#include <fakemeta>

new g_iMaxPlayers

public plugin_init()
{
    g_iMaxPlayers = get_maxplayers()
    
    RegisterHam(Ham_TakeDamage, "func_breakable", "CBaseEntity_TakeDamage", true)
    RegisterHam(Ham_Use, "func_button", "CBasePlayer_ButtonUsed", true)
}

public CBaseEntity_TakeDamage(iVictim, iInflictor, iAttacker, Float:fDamage)
{
    if(iInflictor == iAttacker && 1 <=iAttacker <= g_iMaxPlayers)
    {
        new Float: fEntHealth; pev(iVictim, pev_health, fEntHealth)
        if(!fEntHealth)
        {
            //a func_breakable has been destroyed there.
            new szAttackerName[ 32 ]; get_user_name(iAttacker, szAttackerName, charsmax(szAttackerName))
            client_print(0, print_chat, "%s destroyed a func_breakable entity", szAttackerName)
        }
    }
}

public CBasePlayer_ButtonUsed(iEnt, id, iCaller, useType, Float:flValue)
{
    if(1 <= id <= g_iMaxPlayers)
    {
        new szActivatorName[ 32 ]; get_user_name(id, szActivatorName, charsmax(szActivatorName))
        client_print(0, print_chat, "%s used a func_button", szActivatorName)
    }
}

[Fabregas21]

When I used func_button it showed up information in say, but when I destroyed func_breakable, an information didn't appear.

[csaba1998]

register_touch

[Fabregas21]

csaba1998, it must show information, when I destroyed func_breakable, not when I'm touching it.

HamletEagle, I saw that, once show information in say about destroyed func_breakable and once not.

[HamletEagle]

Fixed:

#include <amxmodx>
#include <hamsandwich>
#include <fakemeta>

new g_iMaxPlayers

public plugin_init()
{
    g_iMaxPlayers = get_maxplayers()
    
    RegisterHam(Ham_TakeDamage, "func_breakable", "CBaseEntity_TakeDamage", true)
    RegisterHam(Ham_Use, "func_button", "CBasePlayer_ButtonUsed", true)
}

public CBaseEntity_TakeDamage(iVictim, iInflictor, iAttacker, Float:fDamage)
{
    server_print("Damage found")
    if(iInflictor == iAttacker && 1 <=iAttacker <= g_iMaxPlayers)
    {
        new Float: fEntHealth; pev(iVictim, pev_health, fEntHealth)
        if(fEntHealth <= 0.0 )
        {
            //a func_breakable has been destroyed there.
            new szAttackerName[ 32 ]; get_user_name(iAttacker, szAttackerName, charsmax(szAttackerName))
            client_print(0, print_chat, "%s destroyed a func_breakable entity", szAttackerName)
        }
    }
}

public CBasePlayer_ButtonUsed(iEnt, id, iCaller, useType, Float:flValue)
{
    if(1 <= id <= g_iMaxPlayers)
    {
        new szActivatorName[ 32 ]; get_user_name(id, szActivatorName, charsmax(szActivatorName))
        client_print(0, print_chat, "%s used a func_button", szActivatorName)
    }
}