[Bugg]

I want count all players only from "TERRORIST" And "CT" Teams.

but with this --> count all players, i dont wanna count players from Spectator team and unassigned players.

PHP Code:

new players[32], count;    
    get_players(players, count); 


Im looking here http://www.amxmodx.org/doc/index.htm...et_players.htm

But no flags for that :S.

Ty.

[wickedd]

PHP Code:

get_players( players, count, "eh" "CT" ) 


That will get only the players on the CT team.

[Bugg]

Yeah, but i need CT and TT at the same time.

[wickedd]

PHP Code:

get_players( players, count_ct, "eh" "CT" )
get_players( players, count_t, "eh", "TERRORIST" ) 


Before you ask anymore question, search the forum.

[Bugg]

This looks good?

PHP Code:

new ts[32],cts[32], countT, countCT;        
    get_players(ts, countT, "e", "TERRORIST");
    get_players(cts, countCT, "e", "CT");
    
    if (countT && countCT)              
    {
        new iPlayer = ts && cts[random(countT && countCT)]; 


[wickedd]

No it doesn't. What are you trying to do?

[Black Rose]

It would probably be easier just to make your own loop in this case.
This seems pretty stupid:

    new players[33], playersnum;
    new players_t[32], players_ct[32], playersnum_t, playersnum_ct;
    get_players(players_t, playersnum_t, "eh", "TERRORIST");
    get_players(players_ct, playersnum_ct, "eh", "CT");
    
    copy(players, charsmax(players), players_t);
    copy(players[playersnum_t], charsmax(players) - playersnum_t, players_ct);
    playersnum = playersnum_t + playersnum_ct;
    
    new randomplayer = players[random(playersnum)];

[OnePL]

PHP Code:

stock ActivePlayers(team /*1 = TR | 2 = CT*/, bool:alive = false) {
    static players[32], num;
    get_players(players, num, alive ? "aceh" : "bce", team == 1 ? "TERRORIST" : "CT");

    return num;
} 


Example plugin:

PHP Code:

#include <amxmodx>

new all_tt, all_ct;
new alive_tt, alive_ct;

public plugin_init() register_clcmd("say /test", "TestCommand");

public TestCommand(id) {
    UpdatePlayers();

    client_print(id, 3, "On the server is:");
    client_print(id, 3, "%i terrorists (%i alive), %i cts (%i alive)", all_tt, alive_tt, all_ct, alive_ct);
}

stock UpdatePlayers() {
    all_tt = ActivePlayers(1);
    all_ct = ActivePlayers(2);
    alive_tt = ActivePlayers(1, true);
    alive_ct = ActivePlayers(2, true);
}

stock ActivePlayers(team, bool:alive = false) {
    static players[32], num;
    get_players(players, num, alive ? "aceh" : "bce", team == 1 ? "TERRORIST" : "CT");

    return num;
} 


Can also like this:

PHP Code:

stock ActivePlayers(CsTeams:team, bool:alive = false) {
    static gracze[32], ile, i, active;
    get_players(gracze, ile, alive ? "ach" : "bc");
    active = 0;
    for(i = 0; i < ile; ++i)
        if(cs_get_user_team(gracze[i]) == team) active++;

    return active;
} 


Example plugin:

PHP Code:

#include <amxmodx>
#include <cstrike>

new all_tt, all_ct;
new alive_tt, alive_ct;

public plugin_init() register_clcmd("say /test", "TestCommand");

public TestCommand(id) {
    UpdatePlayers();

    client_print(id, 3, "On the server is:");
    client_print(id, 3, "%i terrorists (%i alive), %i cts (%i alive)", all_tt, alive_tt, all_ct, alive_ct);
}

stock UpdatePlayers() {
    all_tt = ActivePlayers(CS_TEAM_T);
    all_ct = ActivePlayers(CS_TEAM_CT);
    alive_tt = ActivePlayers(CS_TEAM_T, true);
    alive_ct = ActivePlayers(CS_TEAM_CT, true);
}

stock ActivePlayers(CsTeams:team, bool:alive = false) {
    static players[32], num, i, active;
    get_players(players, num, alive ? "ach" : "bc");
    active = 0;
    for(i = 0; i < num; i++)
        if(cs_get_user_team(players[i]) == team) active++;

    return active;
}