[GarbageBox]

When player say 'maps' then print out 5 random map's name from map.ini, anyone can help?

[Exolent[jNr]]

Try this:

Spoiler

#include < amxmodx >
#include < amxmisc >

#define NUM_MAPS 5

new g_szMapsFile[ 64 ];

public plugin_init( )
{
    register_plugin( "Random Maps Command", "0.0.1", "Exolent" );
    
    register_clcmd( "say maps", "CmdMaps" );
    
    get_configsdir( g_szMapsFile, charsmax( g_szMapsFile ) );
    add( g_szMapsFile, charsmax( g_szMapsFile ), "/maps.ini" );
}

public CmdMaps( iPlayer )
{
    new Array:aMaps = ArrayCreate( 64 );
    new iNumMaps;
    
    new szMap[ 64 ];
    
    new pFile = fopen( g_szMapsFile, "rt" );
    
    if( pFile )
    {
        new szLine[ 128 ];
        
        while( !feof( pFile ) )
        {
            fgets( pFile, szLine, charsmax( szLine ) );
            trim( szLine );
            
            if( !szLine[ 0 ] || szLine[ 0 ] == ';' || szLine[ 0 ] == '/' && szLine[ 1 ] == '/' )
            {
                continue;
            }
            
            parse( szLine, szMap, charsmax( szMap ) );
            
            if( is_map_valid( szMap ) )
            {
                ArrayPushString( aMaps, szMap );
                iNumMaps++;
            }
        }
        
        fclose( pFile );
    }
    
    if( iNumMaps )
    {
        new szMessage[ ( charsmax( szMap ) + 2 ) * NUM_MAPS ], iLen;
        
        new iFound, iRandom;
        
        while( iNumMaps && iFound < NUM_MAPS )
        {
            iRandom = random( iNumMaps-- );
            
            ArrayGetString( aMaps, iRandom, szMap, charsmax( szMap ) );
            
            ArrayDeleteItem( aMaps, iRandom );
            
            iLen += formatex( szMessage[ iLen ], charsmax( szMessage ) - iLen, "%s%s", iFound ? ", " : "", szMap );
            
            iFound++;
        }
        
        client_print( iPlayer, print_chat, "* %d random maps: %s", iFound, szMessage );
    }
    else
    {
        client_print( iPlayer, print_chat, "* Could not load any maps to display." );
    }
    
    ArrayDestroy( aMaps );
    
    return PLUGIN_HANDLED;
}

[GarbageBox]

It show couldn't load any maps but I have maps.ini in my configs dir.

[nikhilgupta345]

Untested:

PHP Code:


    #include <amxmodx>
    #include <amxmisc>
    
    // How many maps you want displayed to the player
    #define MAPS_TO_SHOW 5
    
    // Array to hold maps found in file
    new Array:g_aMapList:
    
    public plugin_init()
    {
        register_plugin( "Display 5 Maps", "1.0", "H3avY Ra1n" );
        
        // Register command for when they say 'maps'
        register_clcmd( "say maps", "cmdShowMaps" );
        
        // Initialize the array
        g_aMapList = ArrayCreate( 64 );
        
        // call function to read maps from the file
        readMapsFromFile();
    }
    
    public cmdShowMaps( id )
    {
        // if size of array is 0 either no maps were loaded or the map file couldn't be found
        if( ArraySize( g_aMapList ) == 0 )
        {
            client_print( id, print_chat, "No maps to show." );
        }
        
        else
        {
            // Create a temporary array with the same values that are in the global arra
            new Array:aTemp = g_aMapList;
            
            // String to hold what we're going to display to the user
            new szMapList[ 256 ];
            
            // String to hold individual maps pulled from the array
            new szMap[ 32 ];
            
            // Integer to hold a random number
            new iRand;
            
            // Loop from 0 to the amount of maps we want to show
            for( new i = 0; i < MAPS_TO_SHOW; i++ )
            {
                // Get a random index of the array
                iRand = random( ArraySize( aTemp ) );
                
                // Get the string that is in that index and put it in szMap
                ArrayGetString( aTemp, iRand, szMap, charsmax( szMap ) );
                
                // Add szMap to the szMapList, which we are going to show to the player
                // The last parameter decides whether or not to put a comma at the end.
                format( szMapList, charsmax( szMapList ), "%s %s%s ", szMapList, szMap, i == MAPS_TO_SHOW - 1 ? "" : "," );
                
                // Delete that item so it's not shown more than once.
                ArrayDeleteItem( aTemp, iRand );
                
            }
            
            // Show szMapList to the player
            client_print( id, print_chat, szMapList );
        }
        
    }
    
    readMapsFromFile()
    {
        // string for the directory of the maps file
        new szDirectory[ 128 ];
        // gets the configs/ directory
        get_configsdir( szDirectory, charsmax( szDirectory ) );
        
        // Find the maps.ini file
        add( szDirectory, charsmax( szDirectory ), "/maps.ini" );

        // Open the file with read text permissions
        new iFile = fopen( szDirectory, "rt" );
        
        // If file doesn't exist or couldn't open it
        if( !iFile )
        {
            // Stop the plugin
            set_fail_state( "Unable to read from file." );
            return;
        }
        
        // String holder to hold maps found in the file.
        new szMap[ 32 ];
        
        // While not at the end of the file
        while( !feof( iFile ) )
        {
            // Get string from the file
            fgets( iFile, szMap, charsmax( szMap ) );
            
            // Remove white space from the map name
            trim( szMap );
            
            // Put that string in the array
            ArrayPushString( g_aMapList, szMap );
        }

        fclose( iFile );
    } 


[Exolent[jNr]]

Originally Posted by GarbageBox It show couldn't load any maps but I have maps.ini in my configs dir.

Forgot to increase the total variable. Should work now.

Originally Posted by nikhilgupta345 Untested: PHP Code:             // Create a temporary array with the same values that are in the global arra             new Array:aTemp = g_aMapList;

You can't copy dynamic arrays like that. It is just a reference to the global one.

[GarbageBox]

Both of yours code are work too, thanks so much!
But nikhilgupta345's code will read ';' and the stuff at back and Exolent's code won't.

[nikhilgupta345]

Originally Posted by Exolent[jNr] Forgot to increase the total variable. Should work now. You can't copy dynamic arrays like that. It is just a reference to the global one.

I thought things in Pawn were copied by-value unless specifically told otherwise?

[Exolent[jNr]]

Originally Posted by nikhilgupta345 I thought things in Pawn were copied by-value unless specifically told otherwise?

Yes, but a value of a dynamic array is a handle.
All of the data is stored into the modules.
Therefore, you are copying the handle value, instead of referencing that handle variable you made.
Either way, it is the same exact dynamic array.

[nikhilgupta345]

Originally Posted by Exolent[jNr] Yes, but a value of a dynamic array is a handle. All of the data is stored into the modules. Therefore, you are copying the handle value, instead of referencing that handle variable you made. Either way, it is the same exact dynamic array.

Oh, makes sense. I couldn't find any ArrayCopy methods or anything, so is there another way to copy an array without looping through all the elements and putting it in a brand new array?

[Exolent[jNr]]

Originally Posted by nikhilgupta345 Oh, makes sense. I couldn't find any ArrayCopy methods or anything, so is there another way to copy an array without looping through all the elements and putting it in a brand new array?

Nothing that exists. Though it would be more efficient to do it in a module.