[Kihoru]

Bonjour j'utilise un plugins de classe, pour les ct, mais je voudrais supprimer deux classe.... comment faire?

classe a supprimmé : super sayen, awp

Mod_Furiens_class.amxx

il n'y a pas de fichier config ni de .sma =x

[Devil259]

Impossible sans le fichier .sma.

Refais-le.

[Kihoru]

Je ne sais absolument pas coder... quelqu'un connait peut etre un plugin dans le meme genre?

[Devil259]

Il y en a des dizaines, peut-être des centaines rien que dans la partie French.

Cherches-un peu, et si rien ne te convient, poste exactement ce que tu veux et peut-être qu'une âme charitable réalisera ce dont tu souhaites.

[Kihoru]

Je ne trouve pas ... =x je voudrais un choix d'arme simple, juste pour les ct, avec ak47, M4A1, M3, MP5.

et pendant que j'y suis je ne trouve plus le nom du plugin, qui fait disparaitre les armes quand un ct meurs... si quelqu'un connait.

Merci

je precise que j'ai chercher avant de venir demander...

[Devil259]

No weapon drop on death par VEN.

[Kihoru]

Merci beaucoup, ca m'a énormément aidez deja !

Apres comme tu le dit si il y a quelqun qui voudrait bien faire les classes (je ne les ai pas trouvé) ca serait sympa...

jute pour ct :

GIGN : M4 deagle He

Silence army : scout usp

Barbare : M3 Deagle, he

Resistant : ak47 elite he

Merci a celui qui le fera

si vous connaissez un plugin similaire que je n'aurais pas trouver, ca irait plus vite

[bboygrun]

PHP Code:

#include < amxmodx >
#include < fun >
#include < cstrike >
#include < fakemeta >
#include < hamsandwich >

#define VERSION "1.0"                            
#define set_user_weapons(%1,%2,%3,%4)    give_item( %1, %2 ); \
                    cs_set_user_bpammo( %1, %3, %4 )

new g_ctMenu, g_msgSayText;

public plugin_init( ) 
{
    register_plugin( "#Menu d'achat CT", VERSION, "Bboy Grun" );
    
    RegisterHam( Ham_Spawn, "player", "fwHamSpawn", true );
    
    g_msgSayText = get_user_msgid( "SayText" );
    
    g_ctMenu = menu_create( "# Menu d'Achat CT #", "fwHandler" );
    menu_additem( g_ctMenu, "\r[GIGN]\y M4A1\d |\y DEADLE\d |\y HE" );
    menu_additem( g_ctMenu, "\r[SILENCE ARMY]\y SCOUT\d |\y USP" );
    menu_additem( g_ctMenu, "\r[BARBARE]\y M3\d |\y DEADLE\d |\y HE" );
    menu_additem( g_ctMenu, "\r[RESISTANT]\y AK47\d |\y ELITE\d |\y HE" );
    
    menu_setprop( g_ctMenu, MPROP_PERPAGE, 0 );
}

public fwHamSpawn( id )
{
    if( is_user_alive( id ) && cs_get_user_team( id ) == CS_TEAM_CT )
    {
        strip_user_weapons( id );
        give_item( id, "weapon_knife" );
        
        menu_display( id, g_ctMenu );
        set_pev( id, pev_flags, pev( id, pev_flags ) | FL_FROZEN );
    }
}

public fwHandler( id, menu, item )
{
    if( cs_get_user_team( id ) == CS_TEAM_CT )
    {
        strip_user_weapons( id );
        give_item( id, "weapon_knife" );
        
        switch( item )
        {
            case 0:
            {
                set_user_weapons( id, "weapon_m4a1", CSW_M4A1, 90 );
                set_user_weapons( id, "weapon_deagle", CSW_DEAGLE, 35 );
                set_user_weapons( id, "weapon_hegrenade", CSW_HEGRENADE, 1 );
            }
            case 1:
            {
                set_user_weapons( id, "weapon_scout", CSW_SCOUT, 90 );
                set_user_weapons( id, "weapon_usp", CSW_USP, 100 );
            }
            case 2:
            {
                set_user_weapons( id, "weapon_m3", CSW_M3, 32 );
                set_user_weapons( id, "weapon_deagle", CSW_DEAGLE, 35 );
                set_user_weapons( id, "weapon_hegrenade", CSW_HEGRENADE, 1 );
            }
            case 3:
            {
                set_user_weapons( id, "weapon_ak47", CSW_AK47, 90 );
                set_user_weapons( id, "weapon_elite", CSW_ELITE, 120 );
                set_user_weapons( id, "weapon_hegrenade", CSW_HEGRENADE, 1 );
            }
        }
        
        set_pev( id, pev_flags, pev( id, pev_flags ) & ~FL_FROZEN );
        
        message_begin( MSG_ONE, g_msgSayText, .player = id );
        write_byte( id );
        write_string( "^x01[^x04 #Menu d'Achat CT#^x01 ]^x04 Voici tes armes !^x03 Bonne chance !" );
        message_end( );
    }
} 


[ConnorMcLeod]

write_string( "^x01[^x04 #Menu d'Achat CT#^x01 ]^x04 Voici tes armes !^x03 Bonne chance !" );

Lol tu formates pas ??

[bboygrun]

Pourquoi je devrais formater ? ( Alors là ça m'échappe )