[nerevye]

Hey folks,

I am currently searching for an option showing ALL team attacks to all players on a server and not just to the own team. Did I just miss a normal cvar? Or is it possible to get this behaviour with SourceMod / an SM plugin?

Cheers,
nerevye

[Bacardi]

http://www.sourcemod.net/compiler.php

PHP Code:

public Plugin:myinfo = {
    name = "Print to chat all team attacker",
    author = "Bacardi",
    description = "Show rest of all players team attacker in chat",
    version = "0.1",
    url = "https://forums.alliedmods.net/showthread.php?t=161597"
};

public OnPluginStart()
{
    HookEvent("player_hurt", player_hurt);
}

public player_hurt(Handle:event, const String:name[], bool:dontBroadcast)
{
    decl attacker, victim, team;
    attacker = GetClientOfUserId(GetEventInt(event, "attacker"));
    victim = GetClientOfUserId(GetEventInt(event, "userid"));


    if(attacker > 0 && attacker != victim && (team = GetClientTeam(attacker)) == GetClientTeam(victim))
    {
        for(new i = 1; i <= MaxClients; i++)
        {
            if(IsClientInGame(i) && GetClientTeam(i) != team)
            {
                PrintToChat(i, "%N attacked a teammate", attacker);
            }
        }
    }
} 


This print to rest of all players in chat team attacker.

*edit
filter suicide out

[nerevye]

Hello Bacardi,

thank you very very much for your code! I'm going to test it this evening...

Cheers,
nerevye

[nerevye]

It works great! Big THX

[ASTFA]

As always, thank you Bacardiii

[Brooke]

Thank you very much Bacardi you give a good answer to the question and i really like your answer.

[Bacardi]

Maybe this is better version, not spam too much team attack message.

PHP Code:

public Plugin:myinfo = {
    name = "Print to chat all team attacker",
    author = "Bacardi",
    description = "Show all players team attacker in chat",
    version = "0.2",
    url = "https://forums.alliedmods.net/showthread.php?t=161597"
};

public OnPluginStart()
{
    HookUserMessage(GetUserMessageId("TextMsg"), TextMsg, true);
}

public Action:TextMsg(UserMsg:msg_id, Handle:bf, const players[], playersNum, bool:reliable, bool:init)
{
    decl String:buffer[MAX_NAME_LENGTH];
    buffer[0] = '\0';
    BfReadString(bf, buffer, sizeof(buffer), false); // Message

    if(StrContains(buffer, "Game_teammate_attack") != -1) // Message match
    {
        BfReadString(bf, buffer, sizeof(buffer), false); // Get name

        decl String:name[MAX_NAME_LENGTH];
        GetClientName(players[0], name, sizeof(name));

        if(StrEqual(buffer, name)) // Team attacker name match player name who get this message.
        {
            new Handle:pack;
            CreateDataTimer(0.1, msg, pack); // Need print new message after this usermessage
            WritePackCell(pack, players[0]);
        }
        return Plugin_Handled; // Stop show message
    }

    return Plugin_Continue;
}

public Action:msg(Handle:timer, Handle:pack)
{
    decl client, String:buffer[128];
    ResetPack(pack);
    client = ReadPackCell(pack);

    Format(buffer, sizeof(buffer), "\01[SM] \x03%N \x01attacked a teammate", client);

    new Handle:hBf;
    hBf = StartMessageAll("SayText2");
    if (hBf != INVALID_HANDLE)
    {
        BfWriteByte(hBf, client);
        BfWriteByte(hBf, 0);
        BfWriteString(hBf, buffer);
        EndMessage();
    }
} 


[ASTFA]

Originally Posted by Bacardi Maybe this is better version, not spam too much team attack message. PHP Code: public Plugin:myinfo = {     name = "Print to chat all team attacker",     author = "Bacardi",     description = "Show all players team attacker in chat",     version = "0.2",     url = "https://forums.alliedmods.net/showthread.php?t=161597" }; public OnPluginStart() {     HookUserMessage(GetUserMessageId("TextMsg"), TextMsg, true); } public Action:TextMsg(UserMsg:msg_id, Handle:bf, const players[], playersNum, bool:reliable, bool:init) {     decl String:buffer[MAX_NAME_LENGTH];     buffer[0] = '\0';     BfReadString(bf, buffer, sizeof(buffer), false); // Message     if(StrContains(buffer, "Game_teammate_attack") != -1) // Message match     {         BfReadString(bf, buffer, sizeof(buffer), false); // Get name         decl String:name[MAX_NAME_LENGTH];         GetClientName(players[0], name, sizeof(name));         if(StrEqual(buffer, name)) // Team attacker name match player name who get this message.         {             new Handle:pack;             CreateDataTimer(0.1, msg, pack); // Need print new message after this usermessage             WritePackCell(pack, players[0]);         }         return Plugin_Handled; // Stop show message     }     return Plugin_Continue; } public Action:msg(Handle:timer, Handle:pack) {     decl client, String:buffer[128];     ResetPack(pack);     client = ReadPackCell(pack);     Format(buffer, sizeof(buffer), "\01[SM] \x03%N \x01attacked a teammate", client);     new Handle:hBf;     hBf = StartMessageAll("SayText2");     if (hBf != INVALID_HANDLE)     {         BfWriteByte(hBf, client);         BfWriteByte(hBf, 0);         BfWriteString(hBf, buffer);         EndMessage();     } }

So if I were to make it show which team the team attack occurred on, how would you code it?

E.g.

if FF occurred on my team:

xxx attacked a teammate

( ^ which is default)

if FF occurred on the other team:

(CT) xxx attacked a teammate

or

(T) xxx attacked a teammate

[Bacardi]

Originally Posted by ASTFA So if I were to make it show which team the team attack occurred on, how would you code it? E.g. if FF occurred on my team: xxx attacked a teammate ( ^ which is default) if FF occurred on the other team: (CT) xxx attacked a teammate or (T) xxx attacked a teammate

I released plugin with translations. [Cs:s]Teammate attack show all
You get team color in chat announce (red, blue and maybe white if player join quicly in spec)

*ps
post #7 works same way, team colors