[RelaxMazteR]

Hey! I want to know how I can make a delay for 2 seconds when calling a function. I has tried to make a task but I cant get it to work with my value.

PHP Code:

public handlemenu(id, menu, item){
    new szItem[33], _access, callback;
    menu_item_getinfo(menu, item, _access, "", 0, szItem, 32, callback);

    load(id, 1, szItem);
}

load(id, number, const szConfigsName[])
{    
    new szPath[129];
    format(szPath, 128, "%s.test", szConfigsName);
} 


NOTE! I has deleted some code so it will be easier to read!
Hope I have posted in the right forum.

[Honors]

Try to do a set_task with params id+1+szItem ?

Then you can do : id -= (1+szItem) ; szItem -= (id+1) ; number -= (id+szItem)

I don't know if that work.

[plowed]

I think you can do it here too http://forums.alliedmods.net/showthread.php?t=162085
look at fysiks last post

smth like this

PHP Code:

public function() 
    static iTimeCmdIsAllowed 
    if( get_systime() > iTimeCmdIsAllowed ) 
    { 
        //Your Code
    } 
    else 
    { 
        // 10 seconds has not passed since command was last used. 
    } 
} 


[Honors]

Originally Posted by plowed I think you can do it here too http://forums.alliedmods.net/showthread.php?t=162085 look at fysiks last post smth like this PHP Code: public function()      static iTimeCmdIsAllowed      if( get_systime() > iTimeCmdIsAllowed )      {          //Your Code     }      else      {          // 10 seconds has not passed since command was last used.      }  }

I think you are wrong. He doesn't want to do that.

[fysiks]

[QUOTE=RelaxMazteR;1515523]Hey! I want to know how I can make a delay for 2 seconds when calling a function. I has tried to make a task but I cant get it to work with my value.

PHP Code:

// Code removed.  See Bugsy's code below.
// I made a couple errors. 


Originally Posted by plowed I think you can do it here too http://forums.alliedmods.net/showthread.php?t=162085 look at fysiks last post

Nope, he just wants to delay the task. The code I presented there is to see if a command is allowed (depending on how long ago the last usage was).

[Bugsy]

Originally Posted by fysiks Using set_task() is the correct action to do what you want. Try this: PHP Code: public handlemenu(id, menu, item) {     new szItem[33], _access, callback;     menu_item_getinfo(menu, item, _access, "", 0, szItem, 32, callback);     load(id, 1, szItem);     set_task(2.0, "load", 12345, szItem, strlen(szItem)+1) } load(id, szConfigsName[]) {     new szPath[129];     format(szPath, 128, "%s.test", szConfigsName); }  Nope, he just wants to delay the task. The code I presented there is to see if a command is allowed (depending on how long ago the last usage was).

There are a few problems with that code.

1. Functions called by set_task() must be public.
2. The load() function params are in the wrong order. Data is passed first followed by task-id when called by set_task.
3. Use sizeof() instead of strlen(), and charsmax() instead of size - 1.
4. Use formatex() when you are not passing the destination string as a param.
5. If you need to pass multiple params through set_task(), you must pack them all into the same array. You needing only to pass a number and string is easy since you can use the first cell to store the number and the remainder for the string. You can pack a lot of different data if needed, though.
6. You are calling load() with 3 params while it only has 2 in the declaration.

Try this, let me know if you need any adjustments.

PHP Code:

public handlemenu( id , menu , item )
{
    new szItem[ 34 ] , _access , callback;
    menu_item_getinfo( menu , item , _access , "" , 0 , szItem[ 1 ] , charsmax( szItem ) - 1 , callback );

    //Passed as "number" to load function
    szItem[ 0 ] = 2468;
    copy( szItem[ 1 ] , charsmax( szItem ) - 1 , "Test String" );
    
    load( szItem ,  id );
    set_task( 2.0 , "load" , 12345 , szItem , sizeof( szItem ) );
} 

public load( const szData[ 34 ] , id )
{
    new szPath[ 129 ] , iNumber;
    
    iNumber = szData[ 0 ];
    formatex( szPath , charsmax( szPath ) , "%s.test" , szData[ 1 ] );

    //Check that the data made it correctly.
    server_print( "id=%d Number=%d String=%s Path=%s" , id , iNumber , szData[ 1 ] , szPath );
}