[muffin89]

Hello,

Ive googled and i didnt find any plugin that could prevent HLTV from getting votekicked or kicked by admins.

It might be some plugin out there i missed, in that case please fill me in.

Else i would very much appriciate if somone could make a plugin for this.

[ecca]

Well not sure but try edit the standard kick plugin and put these lines somewhere. I think it would be on preform kick

new String:steamid[64];
GetClientAuthString(target, steamid, sizeof(steamid));
if ((StrEqual(steamid, "STEAM_ID_SERVER"))
return Plugin_Handled;

[muffin89]

Originally Posted by ecca Well not sure but try edit the standard kick plugin and put these lines somewhere. I think it would be on preform kick new String:steamid[64]; GetClientAuthString(target, steamid, sizeof(steamid)); if ((StrEqual(steamid, "STEAM_ID_SERVER")) return Plugin_Handled;

Would very much appriciate if you could post the original plugin with this fix

And ill test it

[ecca]

Well it didnt work my that solution. But try search logg who kicked out the sourcetv and give him an warning. But im trying to come on a solution to prevent it

[Powerlord]

A solution to prevent it would be to rewrite the kick/ban modules so that they cannot target bots (using IsFakeClient)... something like this:

if (IsFakeClient(target))
    return Plugin_Handled;

(or return Plugin_Continue;)

This would also prevent other bots from being kicked/votekicked, which would only be a problem if you were trying to kick a bot so someone could switch teams.

[psychonic]

You don't need to edit anything. You can give it immunity with a separate plugin.

#include <sourcemod>

new SourceTV = -1;
new Replay = -1;

#define IMMUNITY_LEVEL 98

/*
 * No late-load support since names can be changed,
 * and no other id is exposed to SM
 */

public OnClientConnected(client)
{
    if (!IsFakeClient(client))
        return;
    
    decl String:name[MAX_NAME_LENGTH];
    GetClientName(client, name, sizeof(name));
    
    // this will always be name at the time of initial connect.
    // if using tv_name or later var for replay name, it renames later in frame
    if (!strcmp(name, "SourceTV"))
        SourceTV = client;
    else if (!strcmp(name, "Replay"))
        Replay = client;
}

public Action:OnClientPreAdminCheck(client)
{
    if (client == SourceTV)
    {
        SetImmunity(client, "SourceTV");
        return Plugin_Handled;
    }
    else if (client == Replay)
    {
        SetImmunity(client, "Replay");
        return Plugin_Handled;
    }
    
    return Plugin_Continue;
    

}

public OnClientDisconnect(client)
{
    if (client == SourceTV)
        SourceTV = -1;
    else if (client == Replay)
        Replay = -1;
}

SetImmunity(client, const String:name[])
{
    new AdminId:admin = CreateAdmin(name);
    SetAdminImmunityLevel(admin, IMMUNITY_LEVEL);
    SetUserAdmin(client, admin);
}

[muffin89]

Thanks psychonic, ill try this later today and ill post the results.

[away000]

always psychonic saving brains º.°

[muffin89]

And it works like a charm. Thanks again =)!

[DarthNinja]

For anyone reading this later on:
https://forums.alliedmods.net/showthread.php?t=157485

Provides immunity and custom (re)naming for SourceTV and Replay bots.