[Mifuntm]

Anyone have plugin for (for example 5) random HeadShot sounds (only for Victim and Killer)?
or (one) Team Kill sound (for all players)
or (one) Suicide sound (for all players)
???
If plugin doesn't exist ill be appreciated if someone can write.
Thanks!

[hleV]

PHP Code:

#include <amxmodx>
#include <cstrike>
 
new const g_HeadShotSounds[][] =
{
        "misc/headshot1.wav",
        "misc/headshot2.wav",
        "misc/headshot3.wav",
        "misc/headshot4.wav",
        "misc/headshot5.wav"
};
 
new const g_TeamKillSound[] = "misc/teamkill.wav";
new const g_SuicideSound[] = "misc/suicide.wav";
 
public plugin_precache()
{
        for (new Item; Item < sizeof(g_HeadShotSounds); Item++)
                precache_sound(g_HeadShotSounds[Item]);
 
        precache_sound(g_TeamKillSound);
        precache_sound(g_SuicideSound);
}
 
public plugin_init()
{
        register_plugin("HS/TK/Suicide Sounds", "1.0", "hleV");
 
        register_event("DeathMsg", "DeathMsg", "a");
}
 
public DeathMsg(Killer, Victim, HeadShot)
{
        Killer = read_data(1);
        Victim = read_data(2);
        HeadShot = read_data(3);
 
        if (Killer == Victim || !Killer)
                client_cmd(0, "spk %s", g_SuicideSound);
        else if (cs_get_user_team(Killer) == cs_get_user_team(Victim))
                client_cmd(0, "spk %s", g_TeamKillSound);
        else if (HeadShot)
        {
                new Random = random(sizeof(g_HeadShotSounds));
 
                client_cmd(Killer, "spk %s", g_HeadShotSounds[Random]);
                client_cmd(Victim, "spk %s", g_HeadShotSounds[Random]);
        }
} 


[Mifuntm]

Work perfect

Thanks!

[Mifuntm]

another question about this plugin

How to remove "suicide" sound from here?

[wrecked_]

@ Mifuntm -

PHP Code:

if (Killer == Victim || !Killer)
                client_cmd(0, "spk %s", g_SuicideSound);
        else if (cs_get_user_team(Killer) == cs_get_user_team(Victim))
                client_cmd(0, "spk %s", g_TeamKillSound); 


PHP Code:

        if (cs_get_user_team(Killer) == cs_get_user_team(Victim))
                client_cmd(0, "spk %s", g_TeamKillSound); 


[hleV]

Should also check if Killer > 0 and Killer != Victim.