[kostov]

hi

How can, I set before you started the new round is to choose 2 or 3 terrorists? I had a few suggestions how to do but failed: (

P.S:
sorry for the two subjects I have little trouble browser!

[Exolent[jNr]]

Cvar:
random_terrorists <value>
- Set to an integer value for a constant amount of terrorists (Eg. "2" is 2 terrorists always)
- Set to a decimal percent for a percentage of the players should be terrorists (Eg. "0.5" is 50% of players will be terrorist)

#include < amxmodx >
#include < cstrike >
#include < hamsandwich >

new pCvar_Terrorists;

public plugin_init( )
{
    register_plugin( "Random Terrorists", "0.0.1", "Exolent" );
    
    register_event( "HLTV", "EventNewRound", "a", "1=0", "2=0" );
    
    pCvar_Terrorists = register_cvar( "random_terrorists", "2" );
}

public EventNewRound( )
{
    new iPlayers[ 32 ], iNum;
    get_players( iPlayers, iNum, "a" );
    
    for( new i = 0; i < iNum; i++ )
    {
        if( !( CS_TEAM_T <= cs_get_user_team( iPlayers[ i ] ) <= CS_TEAM_CT ) )
        {
            iPlayers[ i-- ] = iPlayers[ --iNum ];
        }
    }
    
    new szCount[ 16 ], iCount;
    get_pcvar_string( pCvar_Terrorists, szCount, 15 );
    
    if( contain( szCount, "." ) >= 0 )
    {
        iCount = floatround( str_to_float( szCount ) * iNum, floatround_ceil );
    }
    else
    {
        iCount = str_to_num( szCount );
    }
    
    if( iCount > iNum )
    {
        iCount = iNum;
    }
    
    SortCustom1D( iPlayers, iNum, "RandomizePlayers" );
    
    new iPlayer;
    for( new i = 0; i < iCount; i++ )
    {
        iPlayer = iPlayers[ i ];
        if( cs_get_user_team( iPlayer ) != CS_TEAM_T )
        {
            cs_set_user_team( iPlayer, CS_TEAM_T );
            ExecuteHamB( Ham_CS_RoundRespawn, iPlayer );
        }
    }
    
    for( new i = iCount; i < iNum; i++ )
    {
        iPlayer = iPlayers[ i ];
        if( cs_get_user_team( iPlayer ) != CS_TEAM_CT )
        {
            cs_set_user_team( iPlayer, CS_TEAM_CT );
            ExecuteHamB( Ham_CS_RoundRespawn, iPlayer );
        }
    }
}

public RandomizePlayers( iIndex1, iIndex2, iArray[ ], iData[ ], iDataSize )
{
    // Example: 50
    // 0-49 = return -1
    // 50-99 = return 1
    static const RANGE = 50;
    return ( random( RANGE * 2 ) / RANGE / 2 - 1 );
}

[kostov]

Thank you, but you doesn't compile giving error:

PHP Code:

cs_set_user_team( iPlayer, CS_TEAM_T ); 


54 row

[Exolent[jNr]]

Fixed.