[Toastt]

what is the plugin where dead can read alive messages and alive can read dead messages.
i used : ian.cammarata 's but i don't like the color chat.

[wrecked_]

sv_alltalk 1 ?

[Toastt]

Originally Posted by wrecked_ sv_alltalk 1 ?

that doesnt work o.O
im talking about chat messages not mic

[wrecked_]

If we're talking about CS 1.6, I don't see why it doesn't work.

Alltalk allows all players to see everything communicated (aside from say_team, of course). Dead terrorists are able to see alive CT chat, and the other way around.

[ConnorMcLeod]

PHP Code:

/*    Copyright © 2008, ConnorMcLeod

    Kz_All_Chat is free software;
    you can redistribute it and/or modify it under the terms of the
    GNU General Public License as published by the Free Software Foundation.

    This program is distributed in the hope that it will be useful,
    but WITHOUT ANY WARRANTY; without even the implied warranty of
    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
    GNU General Public License for more details.

    You should have received a copy of the GNU General Public License
    along with Kz_All_Chat; if not, write to the
    Free Software Foundation, Inc., 59 Temple Place - Suite 330,
    Boston, MA 02111-1307, USA.
*/

// comment this line if you want to show dead/spec/teamchat status in chat
// team color will always be shown
#define HIDE_STATUS

#include <amxmodx>

new const VERSION[]= "0.0.1"

new gmsgSayText

public plugin_init()
{
    register_plugin( "Kz_All_Chat", VERSION, "ConnorMcLeod" )
    register_message((gmsgSayText = get_user_msgid("SayText")), "Message_SayText")
}

public Message_SayText(iMsgId, MSG_DEST, id)
{
    if( !id )
    {
        return PLUGIN_CONTINUE
    }

    #if defined HIDE_STATUS
        static szChannel[11]
    #else
        static szChannel[24]
    #endif
    get_msg_arg_string(2, szChannel, charsmax(szChannel))
    if( szChannel[0] != '#' || szChannel[1] != 'C' || szChannel[8] != '_' || szChannel[9] != 'C' )
    {
        return PLUGIN_CONTINUE
    }

    if( id == get_msg_arg_int(1) )
    {
        static szString[192]
        get_msg_arg_string(4, szString, charsmax(szString))
        message_begin(MSG_BROADCAST, gmsgSayText)
        write_byte(id)
        #if defined HIDE_STATUS
            write_string("#Cstrike_Chat_All")
        #else
            write_string(szChannel)
        #endif
        write_string("")
        write_string(szString)
        message_end()
    }
    return PLUGIN_HANDLED
} 


[cs1.7]

An option to allow admins to see even team chats, would make this plugin pretty interesting.

[Toastt]

Originally Posted by cs1.7 An option to allow admins to see even team chats, would make this plugin pretty interesting.

i can already do that with amx super o.O

[YamiKaitou]

Originally Posted by wrecked_ If we're talking about CS 1.6, I don't see why it doesn't work. Alltalk allows all players to see everything communicated (aside from say_team, of course). Dead terrorists are able to see alive CT chat, and the other way around.

AFAIK sv_alltalk works only with Voice, not Say

[KadiR]

@ Connor:

What's better to use, yours or this one:

PHP Code:

#include <amxmodx>

new g_iMsgSayText;

public plugin_init( ) {
    register_plugin( "Allchat", "1.0", "ian" );
    
    g_iMsgSayText = get_user_msgid( "SayText" );
    
    register_event( "SayText", "EventSayText", "b", "2&#Cstrike_Chat_All" );
}

public EventSayText( const id ) {
    if( id != read_data( 1 ) )
        return;
    
    new szChannel[ 22 ], iPlayers[ 32 ], iNum;
    read_data( 2, szChannel, 21 );
    
    get_players( iPlayers, iNum, szChannel[ 17 ] ? "ach" : "bch" );
    
    if( !iNum )
        return;
    
    new szMessage[ 192 ];
    read_data( 4, szMessage, 191 );
    
    for( new i; i < iNum; i++ ) {
        message_begin( MSG_ONE_UNRELIABLE, g_iMsgSayText, _, iPlayers[ i ] );
        write_byte( id );
        write_string( szChannel );
        write_string( "" );
        write_string( szMessage );
        message_end( );
    }
} 


[xPaw]

@KadiR: It's actually mine plugin, it doesnt remove team chat as connor's does