[lol37]

hi all,
is that possible to make a plugin that show a HUD "Server fps : FPS" ?
FPS should be accurately determinated, the plugin optimized ( not use much cpu ) and i can control refresh rate
thanks for help.
lol37.

[FragOwn]

I found this:

PHP Code:

#include <amxmodx>
#include <fakemeta>

#define PLUGIN "Server Frames"
#define VERSION "1.0"
#define AUTHOR "Alka"

new bool:ShowFramesStatus[33];

public plugin_init() {
    
    register_plugin(PLUGIN, VERSION, AUTHOR);
    
    register_forward(FM_StartFrame, "Fwd_StartFrame");
    
    register_clcmd("say /showfps", "CmdShowFps");
    register_clcmd("say /fps", "CmdShowFps");
}

public CmdShowFps(id)
{
    if(!ShowFramesStatus[id])
    {
        ShowFramesStatus[id] = true;
        client_print(id, print_chat, "From now, you will see server frames/sec.");
    }
    else
    {
        ShowFramesStatus[id] = false;
        client_print(id, print_chat, "You will no longer see server frames/sec.");
    }
}

public client_disconnect(id)
    ShowFramesStatus[id] = false;

public Fwd_StartFrame()
{
    static Float:GameTime, Float:FramesPer = 0.0;
    static Float:Fps;
    
    GameTime = get_gametime();
    
    if(FramesPer >= GameTime)
        Fps += 1.0;
    else
    {
        FramesPer = FramesPer + 1.0; //Frames per 1 sec.
        
        static Players[32], Num;
        get_players(Players, Num);
        
        for(new i = 0 ; i < Num ; i++)
        {
            if(!ShowFramesStatus[Players[i]])
                continue;
            
            set_hudmessage(255, 0, 0, -1.0, 0.9, 0, 1.0, 1.0, 0.1, 0.1, -1);
            show_hudmessage(Players[i], "Server Frames/Sec : %.1f", Fps);
        }
        Fps = 0.0;
    }
} 


[Exolent[jNr]]

#include < amxmodx >
#include < orpheu >

// RGB colors for the HUD message
#define HUD_RED     0
#define HUD_GREEN   255
#define HUD_BLUE    0

// position of the HUD message (0.0 -> 1.0, use -1.0 for center)
#define HUD_POS_X   -1.0
#define HUD_POS_Y   -1.0

// refresh rate time (in seconds)
#define HUD_TIME    1.0

new g_szStatsResult[ 100 ];

public plugin_init( )
{
    register_plugin( "Server FPS Display", "0.0.1", "Exolent/Arkshine" );
    
    set_task( HUD_TIME, "TaskShowFPS", .flags = "b" );
}

public TaskShowFPS( )
{
    new OrpheuHook:hHandlePrintf = OrpheuRegisterHook( OrpheuGetFunction( "Con_Printf" ), "Con_Printf" );
    
    server_cmd( "stats" );
    server_exec( );
    
    OrpheuUnregisterHook( hHandlePrintf );
    
    new szFPS[ 16 ];
    
    for( new i = 0; i <= 5; i++ )
    {
        trim( g_szStatsResult );
        strtok( g_szStatsResult, szFPS, charsmax( szFPS ), g_szStatsResult, charsmax( g_szStatsResult ), ' ' );
    }
    
    set_hudmessage( HUD_RED, HUD_GREEN, HUD_BLUE, HUD_POS_X, HUD_POS_Y, .holdtime = HUD_TIME, .channel = -1 );
    show_hudmessage( 0, "Server FPS: %s", szFPS );
}

public OrpheuHookReturn:Con_Printf( const a[ ], const szMessage[ ] )
{
    copy( g_szStatsResult, charsmax( g_szStatsResult ), szMessage );
    
    return OrpheuSupercede;
}

You need to install Orpheu.
Then, copy the contents below and save it in a file called ConPrintf (no extension) and place it in addons/amxmodx/configs/orpheu/functions.

{
    "name" : "Con_Printf",
    "library" : "engine",
    "arguments" :
    [
        {
            "type" : "char *"
        },
        {
            "type" : "char *"
        }
    ],
    "identifiers" :
    [
        {
            "os"    : "windows",
            "mod"   : "cstrike",
            "value" : [0x55,0x8B,0xEC,0xB8,0x00,0x10,0x00,0x00,0xE8,"*","*","*","*",0x8B,0x4D,"*",0x8D,0x45,0x0C,"*",0x51,0x8D,0x95,"*","*","*","*",0x68,0x00,0x10,0x00,0x00]
        },
        {
            "os"    : "linux",
            "mod"   : "cstrike",
            "value" : "Con_Printf"
        }
    ]
}

Credits to Arkshine for original code and signature here:
https://forums.alliedmods.net/showpo...&postcount=295

[lol37]

Hi exolent thanks !
i installed Orpheus and compiled / installed the plugin but the hud doesn't appear ( it looks running in amx_plugins and all modules are loaded )

[ancient1]

Did Excolents server plugin using Orpheo ever get updated or is it in the aproved plugins?

Since forum search is currently busted, im having to google to search these forums, and this was the only server fps plugin I could find.

Cheers,

Ancient

[fysiks]

Originally Posted by ancient1 Since forum search is currently busted, im having to google to search these forums,

The search works perfectly fine.

[pantheist]

Originally Posted by Exolent[jNr] #include < amxmodx > #include < orpheu > // RGB colors for the HUD message #define HUD_RED     0 #define HUD_GREEN   255 #define HUD_BLUE    0 // position of the HUD message (0.0 -> 1.0, use -1.0 for center) #define HUD_POS_X   -1.0 #define HUD_POS_Y   -1.0 // refresh rate time (in seconds) #define HUD_TIME    1.0 new g_szStatsResult[ 100 ]; public plugin_init( ) {     register_plugin( "Server FPS Display", "0.0.1", "Exolent/Arkshine" );         set_task( HUD_TIME, "TaskShowFPS", .flags = "b" ); } public TaskShowFPS( ) {     new OrpheuHook:hHandlePrintf = OrpheuRegisterHook( OrpheuGetFunction( "Con_Printf" ), "Con_Printf" );         server_cmd( "stats" );     server_exec( );         OrpheuUnregisterHook( hHandlePrintf );         new szFPS[ 16 ];         for( new i = 0; i <= 5; i++ )     {         trim( g_szStatsResult );         strtok( g_szStatsResult, szFPS, charsmax( szFPS ), g_szStatsResult, charsmax( g_szStatsResult ), ' ' );     }         set_hudmessage( HUD_RED, HUD_GREEN, HUD_BLUE, HUD_POS_X, HUD_POS_Y, .holdtime = HUD_TIME, .channel = -1 );     show_hudmessage( 0, "Server FPS: %s", szFPS ); } public OrpheuHookReturn:Con_Printf( const a[ ], const szMessage[ ] ) {     copy( g_szStatsResult, charsmax( g_szStatsResult ), szMessage );         return OrpheuSupercede; } You need to install Orpheu. Then, copy the contents below and save it in a file called ConPrintf (no extension) and place it in addons/amxmodx/configs/orpheu/functions. { "name" : "Con_Printf", "library" : "engine", "arguments" : [ { "type" : "char *" }, { "type" : "char *" } ], "identifiers" : [ { "os" : "windows", "mod" : "cstrike", "value" : [0x55,0x8B,0xEC,0xB8,0x00,0x10,0x00,0x00,0xE8,"*","*","*","*",0x8B,0x4D,"*",0x8D,0x45,0x0C,"*",0x51,0x8D,0x95,"*","*","*","*",0x68,0x00,0x10,0x00,0x00] }, { "os" : "linux", "mod" : "cstrike", "value" : "Con_Printf" } ] } Credits to Arkshine for original code and signature here: https://forums.alliedmods.net/showpo...&postcount=295

I think you meant to say make the file Con_Printf . You missed the underscore.

[Depresie]

what happened with net_graph ?

nobody wants to be oldschool anymore =[
sad

[Spirit_12]

What a necro bump to this thread. Anyway he wants to know server's fps, and net_graph shows client side fps.