Country stats

ajvn · **Author**

Greetings. Is it hard to make plugin where it can show all dead and spectators top 5 visitors for each country in right bottom corner via HUD every 60 sec, something like this:

Visitors: Count:
1. Denmark 1024
2. Serbia 768
3. French 512
4. Macedonia 400
5. Other 312

Thanks in advance.

Strikerr · 12-13-2008 , 12:59 Re: Country stats

UP
it cool
who can make it?

Exolent[jNr] · 12-13-2008 , 13:48 Re: Country stats

PHP Code:


			
#include <amxmodx>
#include <amxmisc>
//#include <fvault>
#include <geoip>
#include <hamsandwich>

// INTERVAL is in seconds
// NOTE! Must have .0 at the end!
#define INTERVAL 60.0

new const g_vault_name[] = "country_counter";

new bool:g_connected[33];
new bool:g_alive[33];

new g_max_clients;

public plugin_init()
{
    register_plugin("Country Counter", "0.1", "Exolent");
    
    RegisterHam(Ham_Spawn, "player", "FwdPlayerSpawn", 1);
    RegisterHam(Ham_Killed, "player", "FwdPlayerDeath", 1);
    
    g_max_clients = get_maxplayers();
    
    set_task(INTERVAL, "TaskShowCount", _, _, _, "b");
}

public client_putinserver(client)
{
    g_connected[client] = true;
    g_alive[client] = false;
    
    new ip[64], country[46];
    get_user_ip(client, ip, sizeof(ip) - 1, 1);
    geoip_country(ip, country, sizeof(country) - 1);
    
    new count[10];
    fvault_get_data(g_vault_name, country, count, sizeof(count) - 1);
    
    num_to_str(str_to_num(count) + 1, count, sizeof(count) - 1);
    
    fvault_set_data(g_vault_name, country, count);
}

public client_disconnect(client)
{
    g_connected[client] = false;
    g_alive[client] = false;
}

public FwdPlayerSpawn(client)
{
    if( is_user_alive(client) )
    {
        g_alive[client] = true;
    }
}

public FwdPlayerDeath(client)
{
    g_alive[client] = false;
}

public TaskShowCount()
{
    new message[256];
    FormatCountryMessage(message, sizeof(message) - 1);
    
    if( message[0] )
    {
        for( new client = 1; client <= g_max_clients; client++ )
        {
            if( !g_connected[client] || g_alive[client] ) continue;
            
            ShowCountryMessage(client, message);
        }
    }
}

FormatCountryMessage(message[], len)
{
    new size = fvault_size(g_vault_name);
    
    new country[46], count[10];
    for( new i = 0; i < size; i++ )
    {
        fvault_get_keyname(g_vault_name, i, country, sizeof(country) - 1);
        if( equali(country, "error") ) continue;
        
        fvault_get_data(g_vault_name, country, count, sizeof(count) - 1);
        
        format(message, len, "%s^n%s: %s", message, country, count);
    }
}

ShowCountryMessage(client, const message[])
{
    set_hudmessage(0, 255, 0, 0.1, 0.7, 0, 0.0, INTERVAL + 0.1, 0.1, 0.1, -1);
    show_hudmessage(client, "Visitors Per Country:%s", message);
}

#define _vault_dir "addons/amxmodx/data/file_vault"

stock fvault_get_keyname(const vaultname[], const keynum, key[], len)
{
    new filename[128];
    _FormatVaultName(vaultname, filename, sizeof(filename) - 1);
    
    new vault = fopen(filename, "rt");
    
    new _data[64], _other[3];
    
    new line = -1;
    
    while( !feof(vault) )
    {
        fgets(vault, _data, sizeof(_data) - 1);
        
        if( ++line == keynum )
        {
            parse(_data, key, len, _other, sizeof(_other) - 1);
            
            fclose(vault);
            
            return 1;
        }
    }
    
    fclose(vault);
    
    return 0;
}

stock fvault_get_data(const vaultname[], const key[], data[], len)
{
    new filename[128];
    _FormatVaultName(vaultname, filename, sizeof(filename) - 1);
    
    new vault = fopen(filename, "rt");
    
    new _data[512], _key[64];
    
    while( !feof(vault) )
    {
        fgets(vault, _data, sizeof(_data) - 1);
        parse(_data, _key, sizeof(_key) - 1, data, len);
        
        if( equal(_key, key) )
        {
            fclose(vault);
            
            return 1;
        }
    }
    
    fclose(vault);
    
    copy(data, len, "");
    
    return 0;
}

stock fvault_set_data(const vaultname[], const key[], const data[])
{
    static const temp_vault_name[] = "fvault_set_data.txt";
    
    new file = fopen(temp_vault_name, "wt");
    
    new filename[128];
    _FormatVaultName(vaultname, filename, sizeof(filename) - 1);
    
    new vault = fopen(filename, "rt");
    
    new _data[512], _key[64], _other[3];
    
    new bool:replaced = false;
    
    while( !feof(vault) )
    {
        fgets(vault, _data, sizeof(_data) - 1);
        parse(_data, _key, sizeof(_key) - 1, _other, sizeof(_other) - 1);
        
        if( equal(_key, key) && !replaced )
        {
            fprintf(file, "^"%s^" ^"%s^"^n", key, data);
            
            replaced = true;
        }
        else
        {
            fputs(file, _data);
        }
    }
    
    if( !replaced )
    {
        fprintf(file, "^"%s^" ^"%s^"^n", key, data);
    }
    
    fclose(file);
    fclose(vault);
    
    delete_file(filename);
    
    while( !rename_file(temp_vault_name, filename, 1) ) { }
    
    //delete_file(temp_vault_name);
}

stock fvault_size(const vaultname[])
{
    new filename[128];
    _FormatVaultName(vaultname, filename, sizeof(filename) - 1);
    
    return file_size(filename, 1) - 1;
}

stock _FormatVaultName(const vaultname[], filename[], len)
{
    if( !dir_exists(_vault_dir) )
    {
        mkdir(_vault_dir);
    }
    
    formatex(filename, len, "%s/%s.txt", _vault_dir, vaultname);
}

Vorass24 · 12-13-2008 , 15:10 Re: Country stats

Can U give me mor information about your code?

SnoW · 12-13-2008 , 15:46 Re: Country stats

Quote:

Originally Posted by ajvn

Greetings. Is it hard to make plugin where it can show all dead and spectators top 5 visitors for each country in right bottom corner via HUD every 60 sec

Strikerr · 12-14-2008 , 04:01 Re: Country stats

not work for me
error log

Quote:

L 12/14/2008 - 08

6:59: Start of error session.
L 12/14/2008 - 08

6:59: Info (map "cs_italy") (file "addons/amxmodx/logs/error_20081214.log")
L 12/14/2008 - 08

6:59: No search string specified.
L 12/14/2008 - 08

6:59: [AMXX] Run time error 10 (plugin "country.amxx") (native "replace") - debug not enabled!
L 12/14/2008 - 08

6:59: [AMXX] To enable debug mode, add "debug" after the plugin name in plugins.ini (without quotes).
L 12/14/2008 - 08

7:00: No search string specified.
L 12/14/2008 - 08

7:00: [AMXX] Run time error 10 (plugin "country.amxx") (native "replace") - debug not enabled!
L 12/14/2008 - 08

7:00: [AMXX] To enable debug mode, add "debug" after the plugin name in plugins.ini (without quotes).
L 12/14/2008 - 08

7:00: No search string specified.
L 12/14/2008 - 08

7:00: [AMXX] Run time error 10 (plugin "country.amxx") (native "replace") - debug not enabled!
L 12/14/2008 - 08

7:00: [AMXX] To enable debug mode, add "debug" after the plugin name in plugins.ini (without quotes).
L 12/14/2008 - 08

7:00: No search string specified.
L 12/14/2008 - 08

7:00: [AMXX] Run time error 10 (plugin "country.amxx") (native "replace") - debug not enabled!
L 12/14/2008 - 08

7:00: [AMXX] To enable debug mode, add "debug" after the plugin name in plugins.ini (without quotes).
L 12/14/2008 - 08