[Obbin]

I want to pass my function called by set_task some additional data
like
myfunc(client_id, entity_id, Float:Origin[3])
and so on, how do I do?

[Silencer123]

As far as I know there is no way to do that - For now try this and hope st_test_b is triggered before st_test_c:

#include <amxmodx>
#include <amxmisc>

#define PLUGIN "Test set_task"
#define VERSION "1.0"
#define AUTHOR "Silencer"


new something=0

public plugin_init()
{
    register_plugin(PLUGIN,VERSION,AUTHOR)
    register_concmd("st_test","st_test_a",ADMIN_BAN,"- Set_task Test")
}

public st_test_b(id)
{
    something=123
}

public st_test_c(id,somethingelse)
{
    client_print(id,print_chat,"Something: %i",something)
    something=0
}

public st_test_a(id)
{
    set_task(3.0,"st_test_b",id)
    set_task(3.0,"st_test_c",id)
}

[MaximusBrood]

Silencer: No.

---

Just use the parameter function of set_task to transport data.
You only need to convert your Float: origin to an int.

new intOrigin[3];
FVecIVec(myOrigin, intOrigin);

set_task(5.0, "myFunc", 0, intOrigin, 3);

[p3tsin]

Originally Posted by Obbin I want to pass my function called by set_task some additional data like myfunc(client_id, entity_id, Float:Origin[3]) and so on, how do I do?

umm, no. u may only have one parameter on the target function.
u can do it like this:

blabla(id,ent) {
    static Float:origin[3], parm[5]
    pev(ent,pev_origin, origin)
    parm[0] = id
    parm[1] = ent
    parm[2] = _:origin[0]
    parm[3] = _:origin[1]
    parm[4] = _:origin[2]
    set_task(1.0,"myfunc",0, parm,5)
}

public myfunc(parms[]) {
    static Float:orig[3]
    new id = parms[0], ent = parms[1]
    orig[0] = Float:parms[2]
    orig[1] = Float:parms[3]
    orig[2] = Float:parms[4]

    ...
}

[MaximusBrood]

p3tsin: Thats exactly the same way I described.

[p3tsin]

ya, i just made it clear & showed how to do it without rounding the float values

[MaximusBrood]

Originally Posted by p3tsin ya, i just made it clear & showed how to do it without rounding the float values

My example isn't rounding the floats...

[teame06]

@ MaximusBrood

It does use floatround to convert it to an int. That how FVecIVec works as you can see it in the stock below.

/* Changes a float vec to an integer vec */
stock FVecIVec(Float:FVec[3], IVec[3])
{
    IVec[0] = floatround(FVec[0])
    IVec[1] = floatround(FVec[1])
    IVec[2] = floatround(FVec[2])

    return 1
}

[MaximusBrood]

Oh, my bad. I guess I'm just assuming things then without backing up with facts. My apologies.

[Emp`]

if you for some reason need to keep them floats, you can just make a global